2bc0 390b 0000 B ... LEB-BILD.B
Zeichensatz UTF-8+Z1013()+CTRL()-ohne Umlaute(äöüß)

 1000 A=100:GOTO 20:REM * LEBENDE BILDER *
 1010 FR=1:GOSUB 280:Q=HG/2:FL=0:VT=VE:HT=HO:GOSUB 1490
 1020 DIM A(Q,1),B(Q,1)
 1030 HS=HG/20:VS=VG/20
 1040 GOSUB 600
 1050 FOR J=0 TO 1
 1060 GOSUB 260:A(0,J)=RV
 1070 GOSUB 260:B(0,J)=RV
 1080 NEXT J
 1090 A=(RV-.5)/HS:B=(RV-.5)/VS
 1100 FOR I=1 TO Q:GOSUB 200:IF IN=0 THEN 1150
 1110 IF IN<>80 THEN I=Q:GOTO 1150
 1120 REM-----------------------------------
 1130 GOSUB 20020:REM HARDCOPY
 1140 REM-----------------------------------
 1150 IF FL=0 THEN 1180
 1160 CN=1:HO=A(I,0):VE=B(I,0):GOSUB 620
 1170 HO=A(I,1):VE=B(I,1):GOSUB 630
 1180 FOR J=0 TO 1
 1190 X=A(I-1,J)+A
 1200 IF(X>=0)AND(X<1) THEN 1270
 1210 GOSUB 260:A=(RV-.5)/HS:GOSUB 260:X=A(I-1,J)+A
 1220 IF(X<0)OR(X>=1) THEN 1210
 1230 IF JX>1 THEN Y=X:GOTO 1350
 1240 IF JX>-1 THEN J=JX:GOTO 1350
 1250 IF JY>0 THEN GOSUB 260:Y=RV
 1260 IF MV=1 THEN GOSUB 260:JY=INT(RV*4)-1
 1270 Y=B(I-1,J)+B
 1280 IF(Y>=0)AND(Y<1) THEN 1350
 1290 GOSUB 260:B=(RV-.5)/VS:GOSUB 260:Y=B(I-1,J)+B
 1300 IF(Y<0)OR(Y>=1) THEN 1290
 1310 IF JY>1 THEN X=Y:GOTO 1350
 1320 IF JY>-1 THEN J=JY:GOTO 1350
 1330 IF JX>0 THEN GOSUB 260:X=RV
 1340 IF MV=1 THEN GOSUB 260:JX=INT(RV*4)-1
 1350 A(I,J)=X:B(I,J)=Y
 1360 NEXT J:CN=0
 1370 HO=X:VE=Y:GOSUB 620
 1380 HO=A(I,0):VE=B(I,0):GOSUB 630
 1390 NEXT I
 1400 IF IN=86 THEN 1050
 1410 IF IN THEN 1000
 1420 REM LINIEN ENTFERNEN
 1430 FL=1:CN=1:HO=A(0,0):VE=B(0,0):GOSUB 620
 1440 HO=A(0,1):VE=B(0,1):GOSUB 630
 1450 A(0,0)=A(Q,0):A(0,1)=A(Q,1)
 1460 B(0,0)=B(Q,0):B(0,1)=B(Q,1):GOTO 1100
 1470 REM
 1480 REM **BESCHREIBUNG**
 1490 HO=HT/2-9:VE=1:SR$="LEBENDE BILDER":GOSUB 110:GOSUB 150
 1500 PRINT:PRINT
 1510 PRINT "Dieses Programm erstellt unter Verwen-"
 1520 PRINT "dung einfachster Linien-Befehle inte- "
 1530 PRINT "ressante, zumindest aber abwechslungs-"
 1540 PRINT "reiche Darstellungen. Ihr Charakter   "
 1550 PRINT "kann durch die Auswahl (B-Z) teilweise"
 1560 PRINT "beeinflusst werden. Wird zwischenzeit-"
 1570 PRINT "lich die Taste 'S' gedrueckt, werden  "
 1580 PRINT "neue, zufaellige Startkoordinaten er- "
 1590 PRINT "mittelt. Gleichzeitig bleibt auch ein "
 1600 PRINT "Teil des  alten  Bildes etwas laenger "
 1610 PRINT "auf dem Bildschirm."
 1620 PRINT:PRINT "TASTE":GOSUB 210:GOSUB 100
 1630 PRINT "Mehrfaches Druecken der S-Taste"
 1640 PRINT "beeinflusst das Gedaechnis Ihres Rech-"
 1650 PRINT "ners schon erheblich! Ist ein Drucker "
 1660 PRINT "vorhanden, startet 'P' ein Hardcopy.  "
 1670 PRINT "Der dazu notwendige Befehl fuer Ihren "
 1680 PRINT "Computertyp ist ab  Zeile 20000 einzu-"
 1690 PRINT "tragen. Andere Tasten fuehren in die- "
 1700 PRINT "ses Menue zurueck."
 1710 PRINT
 1720 PRINT
 1730 PRINT "Eingabe von B...Z / (A=ENDE):";
 1740 GOSUB 210:IF(IN<65)OR(IN>90) THEN 1740
 1750 MV=91-IN:IF MV>18 THEN 1790
 1760 IF MV>9 THEN 1780
 1770 ON MV GOTO 1800,1810,1820,1830,1840,1850,1860,1870,1880
 1780 ON MV-9 GOTO 1890,1900,1910,1920,1930,1940,1950,1960,1970
 1790 ON MV-18 GOTO 1980,1990,2000,2010,2020,2030,2040,950
 1800 JX=-1:JY=-1:RETURN
 1810 JX=-1:JY=0:RETURN
 1820 JX=-1:JY=1:RETURN
 1830 JX=-1:JY=2:RETURN
 1840 JX=-1:JY=3:RETURN
 1850 JX=0:JY=-1:RETURN
 1860 JX=0:JY=0:RETURN
 1870 JX=0:JY=1:RETURN
 1880 JX=0:JY=2:RETURN
 1890 JX=0:JY=3:RETURN
 1900 JX=1:JY=-1:RETURN
 1910 JX=1:JY=0:RETURN
 1920 JX=1:JY=1:RETURN
 1930 JX=1:JY=2:RETURN
 1940 JX=1:JY=3:RETURN
 1950 JX=2:JY=-1:RETURN
 1960 JX=2:JY=0:RETURN
 1970 JX=2:JY=1:RETURN
 1980 JX=2:JY=2:RETURN
 1990 JX=2:JY=3:RETURN
 2000 JX=3:JY=-1:RETURN
 2010 JX=3:JY=0:RETURN
 2020 JX=3:JY=1:RETURN
 2030 JX=3:JY=2:RETURN
 2040 JX=3:JY=3:RETURN
20000 REM HARDCOPY FUER IHREN COMPUTER
20010 REM:PRINTCHR$(15):REM KC85
20020 RETURN
32000 REM******************************
32010 REM*      LEBENDE BILDER        *
32020 REM*         --------           *
32030 REM* PROGRAMMIERT AUF DEM KC85  *
32040 REM*                            *
32050 REM*   UWE ZIEROTT              *
32060 REM*   PAPPELALLE 1             *
32070 REM*   LEHNIN 1804              *
32080 REM*                            *
32090 REM*   10-01-90                 *
32100 REM*                            *
32110 REM******************************
32120 REM 
32130 REM ERSTAUSSTRAHLUNG RADIO DDR
32140 REM 900221