Steuerung: M ⇦ O ⇨ F ⇧ V ⇩ SIE WOLLN DAS GOLDENE HERZ ! DAZU MUESSEN SIE DEN ZAUBERWALD DURCHQUEREN. IM WALD LADEN SIE SICH ELEKTRISCH AUF DIE LADUNG ADDIERT SICH! ES GIBT ABER KEINE UEBERTRAEGE Z.B. 9+5=4 UND NICHT 14 NUR MIT 0-POTENTIAL KOENNEN SIE WIEDER ENTRINNEN !

Zeichensatz UTF-8+Z1013()+CTRL()-ohne Umlaute(äöüß)

   10 OUTC.12
   15 U=HEX(ED7F)
   20 P."  D E R  Z A U B E R W A L D"
   25 V=HEX(ED60)
   30 P.;P."SIE WOLLN DAS GOLDENE HERZ !"
   40 P.;P."DAZU MUESSEN SIE DEN"
   50 P.;P."ZAUBERWALD DURCHQUEREN."
   55 P.;P."IM WALD LADEN SIE SICH"
   60 P.;P."ELEKTRISCH AUF"
   70 P.;P."DIE LADUNG ADDIERT SICH!"
   80 P.;P."ES GIBT ABER KEINE UEBERTRAEGE"
   90 P.;P."Z.B. 9+5=4 UND NICHT 14"
  100 P.;P."NUR MIT 0-POTENTIAL KOENNEN"
  110 P.;P."SIE WIEDER ENTRINNEN !"
  120 P.;P."LENKEN SIE IHR PFERD MIT:"
  130 P.;P."M NACH LINKS   O NACH RECHTS"
  140 P.;P."F NACH OBEN    V NACH UNTEN"
  150 P.;P."KOENNEN WIR BEGINNEN?   >ENT<"
  160 W=INC.
  170 IF W#13 GOTO 10
  171 OUTC.12
  172 P."WIE HEISST DER KUEHNE RECKE"
  173 P.;P."WELCHER ES WAGT DEM ZAUBERWALD"
  174 P.;P."ZU TROTZEN ?"
  175 P.;P.;I$(TOP)
  180 OUTC.12
  183 T=HEX(EC62);R=HEX(EEA2)
  190 U=HEX(ED7F);V=HEX(ED60)
  195 X=HEX(211F)
  200 P."       Z A U B E R W A L D"
  210 F.K=1 TO 10
  220 P.;P.
  230 FOR I=1 TO 10
  240 TAB(2)
  250 P.#1,RND(9),
  260 N.I
  270 N.K
  280 P.
  290 POKE HEX(1B),HEX(E0);POKE HEX(1C),HEX(EE)
  300 POKE HEX(1D),HEX(00);POKE HEX(1E),HEX(F0)
  310 CALL HEX(F6D1)
  320 POKE U,16;POKE V,203
  365 S=0;N=0
  368 B=U
  370 OUTC.12
  380 P.;P."IHR ERSTER SPRUNG?"
  390 K=INC.;S=S+1
  400 IF K=77 U=U-2;X=X-2
  410 IF K#77 GOTO 370
  420 N=N+(PEEK(U)-48)
  450 POKE U,16
  460 POKE B,32
  480 B=U
  483 IF N>9 N=N-10
  485 OUTC.12
  490 P.S," VERSUCHE",
  500 P."   LADUNG=",#1,N
  510 P.;P."NAECHSTER SPRUNG ?"
  520 K=INC.;S=S+1
  530 IF K=79 U=U+3;X=X+3
  540 IF K=77 U=U-3;X=X-3
  560 IF K=70 U=U-64;X=X-64
  570 IF K=86 U=U+64;X=X+64
  571 IF K=79 GOTO 576
  572 IF K=77 GOTO 576
  573 IF K=70 GOTO 576
  574 IF K=86 GOTO 576
  575 GOTO 480
  576 N=N+(PEEK(U)-48)
  577 IF N>9 N=N-10
  580 F.I=T TO R STEP 64
  590 IF I=U GOTO 607
  600 N.I
  601 POKE U,16
  602 POKE B,(RND(9)+48)
  605 GOTO 480
  607 REM
  610 IF N=0 GOTO 660
  611 POKE U,(RND(9)+48)
  612 IF K=79 U=U-3; X=X-3
  614 IF K=77 U=U+3;X=X+3
  616 IF K=70 U=U+64;X=X+64
  618 IF K=86 U=U-64;X=X-64
  620 OUTC.12
  625 P."MIT DIESER LADUNG KOENNEN"
  630 P.;P."SIE NICHT ENTFLIEHEN"
  645 POKE U,16
  646 F.I=1 TO 4000
  647 N.I
  650 GOTO 485
  660 POKE HEX(1B),0;POKE HEX(1C),HEX(EC)
  670 POKE HEX(1D),0;POKE HEX(1E),HEX(F0)
  680 CALL HEX(F6D1)
  690 OUTC.12
  700 IF S<15 GOTO 860
  710 IF S<23 GOTO 940
  720 GOTO 1010
  730 P.;P.;P.;P.;P.
  740 P."MOECHTEN SIE WEITERSPIELEN?(J/N)"
  750 W=INC.;OUTC.W
  760 IF W=74 GOTO 10
  770 OUTC.12
  780 FOR I=1 TO 13
  790 P.
  800 N.I
  810 P."     AUFWIEDERSEH'N"
  820 P.
  840 P.;P.;P.;P.
  850 STOP
  860 P."GLUEKWUNSCH !"
  870 P.;P."SIE HABEN SICH TAPFER GESCHLAGEN"
  890 P.;P."UND ERHALTEN DEN NAMEN :"
  900 P.;P."SIR ",
  910 O$(TOP)
  920 P.;P.;P."-RITTER VOM GOLDENEN HERZ"
  930 GOTO 730
  940 P."DAS GEHT GERADE NOCH"
  950 P.;P."SIE KONNTEN MIT",S
  960 P.;P."SCHRITTEN ENTKOMMEN."
  970 P.;P."SIE ERHALTEN DEN EHRENTITEL :"
  980 P.;P."RECKE ",
  990 O$(TOP)
 1000 P.;GOTO 730
 1010 P."MAN ",
 1020 O$(TOP)
 1030 P.;P.;P.S," SCHRITTE SIND ZUVIEL!"
 1040 P.;P."DEIN NAME SOLL LAUTEN :"
 1050 P.;P."KNAPPE ",
 1060 O$(TOP)
 1070 P.;P.;P."MEHR UEBEN !!!"
 1080 GOTO 730