Zeichensatz UTF-8+Z1013()+CTRL()-ohne Umlaute(äöüß)
1 A1$="HEIMCOMPUTER robotron Z9001"
2 A2$="SPIEL"
4 A3$="R+WORTE"
6 A4$="WORT RATEN"
8 A5$="EIN LOGIK-SPIEL"
10 REM VERFASSER:KITTELMANN
12 REM ANSCHRIFT:MKD/1EKG
14 REM DATUM 17.09.1984 VERSION 3.2
16 REM INITIALWERTE =================IN
18 WINDOW:BORDER 2:INK 8:PAPER 1:CLS:PRINT AT(0,0);" "
20 DIM P$(13),L$(19),D$(19),N$(26),U(50):N=50:I=RND(-PEEK(31)-1)
90 GOSUB 100:GOTO 1000
96 REM UNTERPROGRAMME ===============UP
98 REM TITELBILD --------------------UP
100 PRINT AT(2,2);A1$:PRINT AT(4,2);"",STRING$(34,""),""
102 PRINT AT(5,2);"":PRINT AT(5,37);""
104 PRINT AT(6,2);"",STRING$(34,""),""
106 PRINT AT(5,3);A2$:PRINT INK 3;AT(5,29);A3$
108 INK 2:PRINT AT(8,2);STRING$(36,"")
110 FOR I=9 TO 13:PRINT AT(I,2);"":PRINT AT(I,37);"":NEXT I
112 PRINT AT(14,2);STRING$(36,"")
114 INK 8:PRINT AT(10,36-LEN(A4$));A4$:PRINT AT(12,36-LEN(A5$));A5$
116 INK 3:PRINT AT(18,2);"VEB ROBOTRON-MESSELEKTRONIK"
118 PRINT AT(20,2);">OTTO SCHOEN< DRESDEN":INK 8
119 REM >ENTER< ---------------------UP
120 PRINT INK 4;AT(22,31);">ENTER<"
122 T$=INKEY$:IF T$=""THEN 122
124 IF T$=CHR$(13)THEN PRINT AT(20,27);STRING$(11," "):RETURN
126 GOSUB 130:GOTO 122
129 REM WIE BITTE ? -----------------UP
130 PRINT INK 2;AT(20,27);"WIE BITTE ?":RETURN
149 REM J/N ABFRAGE -----------------UP
150 PRINT INK 4;AT(22,(38-LEN(KY$)));KY$
151 T$=INKEY$:IF T$=""THEN 151
152 PRINT INK 2;AT(22,37);T$
154 IF ASC(T$)=13 OR ASC(T$)=74 THEN T=1:RETURN
156 IF ASC(T$)=78 THEN T=2:RETURN
158 GOSUB 130:PAUSE 10:GOTO 150
159 REM GERATENE BUCHSTABEN ---------UP
160 WINDOW 4,8,20,38:CLS:FOR I=1 TO 26:IF N$(I)=""THEN 162
161 PRINT N$(I);" ";:IF I=10 OR I=20 THEN PRINT
162 NEXT I
163 WINDOW 18,19,1,38:PRINT AT(18,1);" "
164 ZK$="":FOR I=1 TO L:ZK$=ZK$+D$(I):NEXT I:PRINT PAPER 2;AT(12,20);ZK$
165 PRINT AT(22,0);STRING$(40," "):PRINT INK 6;AT(22,9);A1$:RETURN
998 REM HAUPTPROGRAMM ===============HP
1000 BORDER 7:CLS
1002 P$(1)=" ":P$(2)=" ":P$(3)=" "
1008 P$(4)=" ":P$(5)=" ":P$(6)=" "
1016 P$(7)=" ":P$(8)=" ":P$(9)=" "
1020 P$(10)=" ":P$(11)=" ":P$(12)=P$(11)
1026 P$(13)=" "
1028 PRINT AT(1,0);"",STRING$(17,""),""
1030 FOR I=2 TO 14:PRINT AT(I,0);"":PRINT AT(I,18);"":NEXT I
1032 PRINT AT(15,0);"",STRING$(17,""),""
1034 PRINT AT(2,20);"GERATENE BUCHSTABEN"
1036 PRINT AT(10,20);"DAS WORT HEISST"
1040 FOR I=1 TO 19:D$(I)="-":L$(I)="":NEXT I:FOR I=1 TO 26:N$(I)="":NEXT I
1044 Z1=INT(N*RND(5)+1):FOR I=Z1 TO N:IF U(I)=0 THEN T=I:I=N:NEXT I:GOTO 1048
1045 NEXT I:FOR I=1 TO Z1-1:IF U(I)=0 THEN T=I:I=Z1-1:NEXT I:GOTO 1048
1046 NEXT I:GOTO 1139
1048 U(T)=1:RESTORE 1142:FOR J=1 TO T:READ A$:NEXT J
1056 L=LEN(A$):FOR I=1 TO L:L$(I)=MID$(A$,I,1):NEXT I:ST=0:W=0
1060 A1$="BITTE EINEN BUCHSTABEN RATEN !":GOSUB 160
1068 G$=INKEY$:IF G$=""THEN 1068
1070 IF ASC(G$)<65 OR ASC(G$)>90 THEN GOSUB 130:GOTO 1068
1071 PRINT PAPER 5;AT(14,20);STRING$(L," ")
1072 PRINT AT(20,27);STRING$(11," "):PRINT INK 2;AT(22,38);G$:R=0
1076 FOR I=1 TO 26:IF N$(I)=""THEN T=I:I=26:NEXT I:GOTO 1082
1078 IF G$<>N$(I)THEN NEXT I
1080 CLS:PRINT " BUCHSTABE WURDE SCHON GERATEN":I=26:NEXT I:GOTO 1060
1082 N$(T)=G$:ST=ST+1
1086 FOR I=1 TO L:IF L$(I)=G$ THEN D$(I)=G$:R=1
1088 NEXT I
1092 IF R=0 THEN CLS:PRINT " BUCHSTABE IST NICHT IM WORT":W=W+1:GOTO 1124
1094 FOR I=1 TO L:IF D$(I)="-"THEN I=L:NEXT I:GOTO 1102
1100 NEXT I:PRINT PAPER 5;AT(14,20);A$:A1$="":GOSUB 160:GOTO 1115
1102 A1$="":GOSUB 160
1106 CLS:H$=STRING$(L," "):INK 6:INPUT "BITTE WORT RATEN :";H$:INK 8:CLS
1107 IF H$=STRING$(L," ")THEN PRINT PAPER 5;AT(14,20);H$:GOTO 1060
1108 IF LEN(H$)>L THEN H$=LEFT$(H$,L)
1110 PRINT PAPER 5;AT(14,20);H$:IF H$=A$ THEN 1115
1114 CLS:PRINT " DAS IST NICHT DAS RICHTIGE WORT!":GOTO 1060
1115 CLS:IF ST=1 THEN PRINT "WORT SOFORT ERRATEN !":GOTO 1117
1116 PRINT "WORT MIT";ST;"VERSUCHEN GEFUNDEN !"
1117 PRINT AT(19,1);" "
1118 PRINT AT(22,0);STRING$(40," "):KY$="WOLLEN SIE WEITER RATEN:(J)/N":GOSUB 150
1120 WINDOW:IF T=1 THEN 1000
1122 CLS:GOTO 1140
1124 IF W=8 THEN W=13
1130 FOR I=1 TO W:PRINT INK 3;AT(14-W+I,1);P$(I):NEXT I
1132 IF W<8 THEN 1060
1136 CLS:PRINT " NUN WAR DAS UNGEHEUER SCHNELLER !":PRINT AT(19,1);" "
1138 GOSUB 160:PRINT PAPER 5;AT(14,20);A$:GOTO 1118
1139 WINDOW:CLS:PRINT AT(8,2);"ALLE 50 WORTE SIND ERRATEN !"
1140 PRINT INK 3;AT(10,2);"AUF WIEDERSEHEN !":PAUSE 50:CLS:END
1142 DATA "PINSEL","AFFE","FERNSEHER","KALENDER","LEBERWURST"
1144 DATA "APFELMUS","HARLEKIN","EIER","TISCHDECKE","HEIMCOMPUTER"
1146 DATA "SENF","BOCKWURST","UNGEHEUER","SONNENSCHEIN","DRUCKFEHLER"
1148 DATA "MUNDHARMONIKA","FENSTER","ZWIEBEL","ABTEILUNGSLEITER"
1150 DATA "ZAHNARZT","BADEWANNE","PELZMANTEL","STAUBSAUGER","WASCHMASCHINE"
1152 DATA "PLATTENSPIELER","MESSER","TAPETENMUSTER","SAMT","SCHOKOLADE"
1154 DATA "PFEFFER","TREPPE","VEILCHEN","LAMPENSCHIRM","EI"
1156 DATA "GEWITTERWOLKE","FLECKENTFERNER","HOSENTASCHE","WASCHBECKEN"
1158 DATA "KARTOFFELMUS","SALZKARTOFFEL","FIEBERTHERMOMETER"
1160 DATA "KLEIDERSCHRANK","KULTURVERANSTALTUNG","VERKEHRSPOLIZIST"
1162 DATA "KINDERKRANKHEIT","PIONIERORGANISATION","BERUFSAUSBILDUNG"
1164 DATA "WOHNUNGSEINRICHTUNG","LEUCHTSTOFFLAMPE","WEIHNACHTSMANN"