Zeichensatz UTF-8+Z1013()+CTRL()-ohne Umlaute(äöüß)
1 A1$="HEIMCOMPUTER robotron Z9001"
2 A2$="SPIEL"
4 A3$="R+ZIELE"
6 A4$="ZIELE SUCHEN"
8 A5$="EIN LOGIK-SPIEL"
10 REM VERFASSER:KITTELMANN
12 REM ANSCHRIFT:MKD,1EKG
14 REM DATUM 17.09.1984 VERSION 2.3
16 REM INITIALWERTE =================IN
18 BORDER 2:INK 8:PAPER 1:WINDOW:CLS:PRINT AT(0,0);" "
20 B=-5120:DIM Z(4,2):I=RND(-PEEK(31)-1)
90 GOSUB 100:GOTO 1000
96 REM UNTERPROGRAMME ===============UP
98 REM TITELBILD --------------------UP
100 PRINT AT(2,2);A1$:PRINT AT(4,2);"",STRING$(34,""),""
102 PRINT AT(5,2);"":PRINT AT(5,37);""
104 PRINT AT(6,2);"",STRING$(34,""),""
106 PRINT AT(5,3);A2$:PRINT INK 3;AT(5,29);A3$
108 INK 2:PRINT AT(8,2);STRING$(36,"")
110 FOR I=9 TO 13:PRINT AT(I,2);"":PRINT AT(I,37);"":NEXT I
112 PRINT AT(14,2);STRING$(36,"")
114 INK 8:PRINT AT(10,36-LEN(A4$));A4$:PRINT AT(12,36-LEN(A5$));A5$
116 INK 3:PRINT AT(18,2);"VEB ROBOTRON-MESSELEKTRONIK"
118 PRINT AT(20,2);">OTTO SCHOEN< DRESDEN":INK 8
119 REM >ENTER< ---------------------UP
120 PRINT INK 4;AT(22,31);">ENTER<"
121 T$=INKEY$
122 T$=INKEY$:IF T$=""THEN 122
124 IF T$=CHR$(13)THEN PRINT AT(20,27);STRING$(11," "):RETURN
126 GOSUB 130:GOTO 122
129 REM WIE BITTE ? -----------------UP
130 PRINT INK 2;AT(20,27);"WIE BITTE ?":RETURN
149 REM J/N ABFRAGE -----------------UP
150 PRINT INK 4;AT(22,(39-LEN(KY$)));KY$
151 T$=INKEY$
153 T$=INKEY$:IF T$=""THEN 153
155 IF ASC(T$)=74 OR ASC(T$)=13 THEN T=1:PRINT AT(20,27);STRING$(11," "):RETURN
156 IF ASC(T$)=78 THEN T=2:PRINT AT(20,27);STRING$(11," "):RETURN
158 GOSUB 130:PAUSE 10:GOTO 150
199 REM TASTENABFRAGE ---------------UP
200 M$=INKEY$
202 M$=INKEY$:IF M$=""THEN 202
204 M=ASC(M$)-48:IF M<0 OR M>9 THEN 200
206 RETURN
209 REM BLINKEN ---------------------UP
210 Y=PEEK(BS):FOR I=1 TO 14:POKE BS,32:PAUSE 2:POKE BS,Y:PAUSE 4:NEXT I:RETURN
219 REM ZIELVERGLEICH ---------------UP
220 FOR I=1 TO 3:FOR J=I+1 TO 4:IF Z(I,1)=Z(J,1)AND Z(I,2)=Z(J,2)THEN T=3
222 NEXT J:NEXT I:RETURN
998 REM HAUPTPROGRAMM ===============HP
1000 WINDOW:CLS:INK 3:PAPER 1:BORDER 5
1002 A1$=""
1004 A2$=" "
1006 A3$=""
1008 A4$=""
1010 PRINT AT(1,3);"0 1 2 3 4 5 6 7 8 9"
1012 PRINT AT(2,2);A1$
1014 FOR I=4 TO 22 STEP 2:PRINT AT(I-1,0);I/2-2:PRINT AT(I-1,2);A2$:PRINT AT(I,2);A3$
1016 NEXT I
1018 PRINT AT(22,2);A4$
1020 FOR J=1 TO 2:FOR I=1 TO 4:Z(I,J)=INT(10*RND(5)):NEXT I:NEXT J
1021 T=0:GOSUB 220:IF T=3 THEN 1020
1022 N=0:X=0:INK 8
1024 N=N+1
1025 WINDOW 0,23,24,39:CLS:PRINT AT(0,24);" ":PRINT AT(1,25);"VERSUCH",N
1026 PRINT AT(3,25);"KOORDINATEN"
1028 PRINT INK 4;AT(5,26);"ZEILE :":GOSUB 200:POKE B+235,M+48:K1=M
1030 PRINT INK 4;AT(7,26);"SPALTE:":GOSUB 200:POKE B+315,M+48:K2=M
1032 BS=-4997+K1*80+K2*2:BF=BS-1024
1034 IF PEEK(BS)<>32 THEN PRINT INK 2;AT(20,33);"FEHLER":PAUSE 80:GOTO 1025
1036 POKE BS,42:POKE BF,48
1038 PRINT AT(10,25);"ZIEL ABSTAND"
1040 FOR I=1 TO 4
1042 IF Z(I,1)=-1 THEN 1054
1044 IF Z(I,1)<>K1 OR Z(I,2)<>K2 THEN 1052
1046 PRINT INK 6;AT(10+2*I,25);I," GEFUNDEN":Z(I,1)=-1:POKE BS,I+48:POKE BF,80
1048 X=X+1
1050 GOTO 1054
1052 PRINT AT(10+2*I,25);I," ",INT(SQR((Z(I,1)-K1)^2+(Z(I,2)-K2)^2)*100+.5)/100
1054 NEXT I
1056 GOSUB 210:CLS:PRINT AT(0,24);" "
1058 IF X=4 THEN 1064
1060 IF N=10 THEN 1070
1062 GOTO 1024
1064 PRINT AT(3,25);"ALLE ZIELE MIT"
1066 PRINT AT(5,24);N,"VERSUCHEN"
1068 PRINT AT(7,25);"GEFUNDEN !":GOTO 2000
1070 INK 2:PRINT AT(3,25);"DIESE ZIELE":IF X=3 THEN PRINT AT(3,25);"DIESES ZIEL"
1072 PRINT AT(5,25);"WURDEN NICHT":IF X=3 THEN PRINT AT(5,25);"WURDE NICHT "
1074 PRINT AT(7,25);"GEFUNDEN !":INK 8
1076 FOR J=1 TO 20:FOR I=1 TO 4
1078 BS=-4997+Z(I,1)*80+Z(I,2)*2:BF=BS-1024
1080 IF Z(I,1)<>-1 THEN POKE BF,16:POKE BS,32:PAUSE 2:POKE BS,I+48
1082 NEXT I
1084 NEXT J
2000 WINDOW:PRINT AT(0,0);" ":KY$="FORTSETZEN:(J)/N":GOSUB 150
2010 IF T=1 THEN 1000
8999 REM ENDE ======================HP8
9000 CLS:PRINT AT(0,0);" ":PRINT INK 3;AT(8,2);"AUF WIEDERSEHEN!":PAUSE 50:CLS:END