Zeichensatz UTF-8+Z1013()+CTRL()-ohne Umlaute(äöüß)
99!*** HAUPTPROGRAMM ***
100 WINDOW:PAPER 1:POKE 862,1:GOSUB 15000:GOSUB 14000
105 CLEAR 1024:WINDOW:PAPER 1:INK 3:CLS:OUT 136,4
110 GOSUB 10032
500 Y=1
515 GOSUB 5000
520 FOR H=1 TO SP:IF Y=1 THEN 530
525 GOSUB 1000
530 CLS:PRINT INK 2;MID$(X$(SP(H)),2);" ":PRINT "SPIELTAG";Y
540 IF Y=34 THEN PRINT INK 2;AT(1,0);"LETZTER BUNDESLIGASPIELTAG !!!"
550 PRINT:PRINT:PRINT:PRINT " 1 - MANNSCHAFTSAUFSTELLUNG"
554 PRINT " 2 - TRANSFERMARKT"
558 PRINT " 3 - BUNDESLIGATABELLE"
562 PRINT " 4 - SPIELERREPORT"
566 PRINT " 5 - ALLGEMEINES"
570 PRINT " 6 - VEREINSUEBERSICHT"
573 PRINT " 7 - SPIELPAARUNGEN"
575 PRINT " 8 - WEITER"
576 PRINT " * - SPIELABBRUCH MIT ABRECHNUNG":PRINT STRING$(11,CHR$(11));
577 GOSUB 1100
580 INPUT "IHRE ENTSCHEIDUNG ? : ";E$
581 IF E$="*"THEN 7000
582 IF VAL(E$)<1 OR VAL(E$)>8 THEN PRINT CHR$(11);:GOTO 580
585 ES=VAL(E$)
600 ON ES GOTO 2000,2700,3580,4000,8000,6000,3000,645
645 QQ=0:TR=0:F=0:C=0:FOR I=1 TO 5:T5(I)=0:NEXT I
650 NEXT H:GOSUB 3000
700 Y=Y+1:IF Y<=34 THEN 515
701 Y=34
710 GOTO 7000
750!*** ENDE ***
800 CLS:IF Y>30 THEN FOR H=1 TO SP:PRINT MID$(X$(SP(H)),2);" - MANAGER,":GOSUB 9500:PRINT:NEXT
820 WINDOW 17,23,4,39:PRINT "W A G E N S I E E I N E"
825 PRINT:INPUT " N E U E S A I S O N ? ? ? ";A$
830 IF A$="J"THEN RUN
840 WINDOW:CLS:PRINT AT(0,0);" ":PRINT AT(8,1);"O.K. BIS ZUM NAECHSTEN MAL! TSCHUESS!"
850 PAUSE 50:CLS:END
999!*** SPIELERSTATUS ***
1000 CLS:FOR I=1 TO 19:PRINT AT(I,39);"":NEXT
1010 PRINT AT(0,0);" ":PRINT AT(8,1);"SPIELTAG",Y:PRINT AT(10,1);MID$(X$(SP(H)),2)
1040 FOR I=1 TO 20:IF MA(H,I,1)=0 THEN 1075
1041 MA(H,I,1)=MA(H,I,1)+RND(1)-RND(1)
1042 IF MA(H,I,1)>=6 THEN MA(H,I,1)=5.999
1043 IF MA(H,I,1)<1 THEN MA(H,I,1)=1
1051 IF MA(H,I,2)<0 THEN MA(H,I,2)=MA(H,I,2)+1:GOTO 1075
1052 IF RND(1)>.98 THEN MA(H,I,2)=MA(H,I,2)-RND(1)*RND(0)*10:GOTO 1070
1060 MA(H,I,2)=MA(H,I,2)-RND(1)+RND(1)
1070 IF MA(H,I,2)>5 THEN MA(H,I,2)=5
1074 IF MA(H,I,3)>99 THEN MA(H,I,3)=MA(H,I,3)-100
1075 NEXT I
1076!*** GELBE KARTEN ***
1077 FOR I=1 TO 11:IF RND(1)>.9 THEN MA(H,EL(I,H),3)=MA(H,EL(I,H),3)+1:ELSE 1079
1078 XG=MA(H,EL(I,H),3):IF XG=4 OR XG=7 OR XG=10 THEN MA(H,EL(I,H),3)=XG+100
1079 NEXT
1080 EF(H)=0:FOR I=1 TO 11
1081 IF EL(I,H)=0 THEN 1086
1082 IF MA(H,EL(I,H),2)<0 OR MA(H,EL(I,H),3)>99 THEN 1086
1083 Q=I:R=EL(I,H):GOSUB 2171:IF XG=1 THEN 1086
1085 EF(H)=EF(H)+INT(MA(H,EL(I,H),1))
1086 NEXT
1090 IF EF(H)>=45 THEN A=5:GOTO 1095
1091 IF EF(H)>=36 THEN A=4:GOTO 1095
1092 IF EF(H)>=27 THEN A=3:GOTO 1095
1093 IF EF(H)>=18 THEN A=2:GOTO 1095
1094 A=1
1095 X$(SP(H))=MID$(STR$(A),2,1)+MID$(X$(SP(H)),2,LEN(X$(SP(H)))-1)
1099 RETURN
1100!*** GEHAELTER ***
1110 IF(Y+2)/4<>INT((Y+2)/4)THEN RETURN
1120 IF QQ=1 THEN RETURN
1125 IF DM(H)>=0 THEN 1140
1130 ZI=-INT(DM(H)*.02+1):DM(H)=DM(H)-ZI
1131 A$="SCHULDZINSEN: "+RIGHT$(" "+STR$(ZI)+"000",8)
1132 PRINT INK 2;AT(16,4);LEFT$(A$+" ",25)
1140 GH(H)=0:FOR J=1 TO 20:GH(H)=GH(H)+MA(H,J,0):NEXT J
1150 A$="GEHALTSZAHLUNG:"+RIGHT$(" "+STR$(GH(H))+"000",8)
1151 PRINT AT(17,4);LEFT$(A$+" ",25):DM(H)=DM(H)-GH(H)
1160 A$="KAPITAL: "+RIGHT$(" "+STR$(DM(H))+"000",8)
1161 PRINT AT(18,4);LEFT$(A$+" ",25)
1190 QQ=1
1999 RETURN
2000!*** MANNSCHAFT ***
2010 CLS:PRINT INK 2;AT(0,23);" SPIELERFORM":PRINT INK 6;AT(2,23);"AUFSTELLUNG"
2100 FOR I=1 TO 20:PRINT RIGHT$(STR$(I),2);" ";:GOSUB 8500:PRINT G$;INT(MA(H,I,1)*100)/100
2110 IF MA(H,I,2)<0 THEN PRINT INK 7;AT(I-1,14);"VERLETZT":GOTO 2115
2112 IF MA(H,I,3)>99 THEN PRINT INK 4;AT(I-1,14);"GESPERRT"
2115 NEXT
2148 WINDOW 3,23,23,39:CLS:PRINT "NR POS. SP ST"
2149 PRINT:FOR J=1 TO 11:PRINT RIGHT$(STR$(J),2);" ";:I=EL(J,H):R=I:GOSUB 8500:PRINT G$;EL(J,H)
2150 IF EL(J,H)<>0 THEN PRINT INK 2;AT(I-1,2);""
2151 Q=J:GOSUB 2171:IF XG=1 THEN PRINT AT(J+4,35);"":GOTO 2154
2152 IF MA(H,EL(J,H),2)<0 OR MA(H,EL(J,H),3)>99 THEN PRINT INK 2;AT(J+4,35);"":GOTO 2154
2153 PRINT AT(J+4,35);RIGHT$(STR$(INT(MA(H,EL(J,H),1))),1)
2154 NEXT:PRINT
2155 PRINT "SPIELSTAERKE:";STR$(EF(H)):PRINT "STAERKEGRAD:";VAL(LEFT$(X$(SP(H)),1))
2160 INPUT "AENDERUNGEN?";Q$
2162 IF Q$<>"J"THEN WINDOW:GOTO 530
2163 WINDOW 17,23,23,39:CLS
2164 INPUT "WELCHE NR.?";Q$:Q=VAL(Q$):IF Q<1 OR Q>11 THEN PRINT "NUR 1 - 11 !!!";:PAUSE 20:CLS:GOTO 2164
2165 IF EL(Q,H)=0 THEN 2168
2166 IF MA(H,EL(Q,H),2)>=0 AND MA(H,EL(Q,H),3)<100 THEN EF(H)=EF(H)-INT(MA(H,EL(Q,H),1))
2167 V(EL(Q,H),H)=0:PRINT AT(Q+4,31);" ":PRINT AT(EL(Q,H)-1,2);" ":EL(Q,H)=0
2168 CLS:INPUT "NEUE NR.?";Q$:R=VAL(Q$):IF R=0 THEN CLS:GOTO 2160
2169 IF R<1 OR R>20 THEN PRINT "NUR 1 - 20 !!!":PAUSE 20:GOTO 2168
2170 GOSUB 2171:IF XG=1 THEN 2179:ELSE 2180
2171 ON Q GOTO 2172,2174,2174,2174,2176,2176,2176,2176,2178,2178,2178
2172 IF MA(H,R,4)=1 THEN XG=0:RETURN
2173 XG=1:RETURN
2174 IF MA(H,R,4)=2 THEN XG=0:RETURN
2175 XG=1:RETURN
2176 IF MA(H,R,4)=3 THEN XG=0:RETURN
2177 XG=1:RETURN
2178 IF MA(H,R,4)=4 THEN XG=0:RETURN:ELSE XG=1:RETURN
2179 PRINT "FALSCHE POS.!!!":PAUSE 50:GOTO 2168
2180 IF V(R,H)>0 THEN PRINT "IST BEREITS AUFGESTELLT !!!":PAUSE 50:GOTO 2168
2181 V(R,H)=1:I=R:GOSUB 8500:PRINT AT(Q+4,26);G$,R
2182 IF MA(H,R,2)>=0 AND MA(H,R,3)<100 THEN I=INT(MA(H,R,1)):PRINT AT(Q+4,34);I:EF(H)=EF(H)+I
2183 EL(Q,H)=R:PRINT INK 2;AT(R-1,2);""
2185 GOSUB 1080:CLS
2190 GOTO 2155
2400!*** AUTO-AUFSTELLUNG ***
2410 EL(1,H)=1:V(1,H)=1:FOR J=3 TO 5:EL(J-1,H)=J:V(J,H)=1:NEXT
2420 FOR J=7 TO 10:EL(J-2,H)=J:V(J,H)=1:NEXT:FOR J=12 TO 14:EL(J-3,H)=J:V(J,H)=1:NEXT
2440 GOSUB 1080:RETURN
2600!*** VERKAUFSPRUEFUNG ***
2610 I=1
2620 IF T5(I)<>0 THEN 2650
2630 T5(I)=Q:RETURN
2650 I=I+1:IF I<=5 THEN 2620
2660 IF K$="K"THEN RETURN
2670 XG=1:RETURN
2700!*** TRANSFERMARKT ***
2701 CLS:PRINT "NR POS FORM GEH. NR POS FORM GEH.":PRINT:FOR I=1 TO 20
2702 A$=STR$(MA(H,I,1)):IF MA(H,I,0)=0 THEN PRINT RIGHT$(STR$(I),2);" ";:GOTO 2705
2703 PRINT RIGHT$(STR$(I),2);" ";:GOSUB 8500:PRINT G$;LEFT$(A$,2);".";LEFT$(MID$(A$,4,2)+"00",2);
2704 XG=32-54*(MA(H,I,2)<0):PRINT CHR$(XG);RIGHT$(STR$(MA(H,I,0))+"000",5);" ";
2705 NEXT I:FOR I=1 TO 11:IF EL(I,H)=0 THEN 2707
2706 PRINT INK 2;AT(INT((EL(I,H)+3)/2),2-20*(EL(I,H)/2=INT(EL(I,H)/2)));""
2707 NEXT I
2708 TR=TR+1:IF TR>3 THEN PRINT:PRINT:PRINT INK 2;" TRANSFERLISTE GESCHLOSSEN ! >ENTER<":INPUT A$:GOTO 530
2709 PRINT:PRINT INK 2;" TRANSFERLISTE "
2710 PRINT "NR POS ST PREIS"
2711 FOR I=1 TO 5
2712 IF C=1 THEN 2718
2713 TS(I)=INT(RND(1)*5+1)
2714 TK(I)=INT(PR(TS(I))+(RND(1)-RND(1))*TS(I)*20)
2716 TA(I)=INT(RND(1)*4+1)
2718 GOSUB 8512:PRINT I;G$;TS(I);:IF TK(I)=0 THEN G$="0":ELSE G$=STR$(TK(I))+"000"
2719 PRINT RIGHT$(" "+G$,6)
2720 NEXT I:C=1
2722 PRINT AT(13,20);"KAPITAL:",RIGHT$(" "+STR$(DM(H))+"000",8)," DM"
2730 WINDOW 15,23,20,39:PRINT "KAUF/VERKAUF/ENDE":INPUT "(K,V,E): ";K$
2731 CLS
2733 IF K$="K"THEN 2740
2734 IF K$="V"THEN 2770
2735 IF K$="E"THEN WINDOW:GOSUB 1080:GOTO 530
2736 GOTO 2730
2740 IF DM(H)<-999 THEN PRINT INK 2;AT(18,20);"NICHT FINANZIERBAR !":GOTO 2730
2742 CLS:INPUT "KAUF VON NR.?: ";Q$:L=VAL(Q$):IF L<0 OR L>5 THEN PRINT "NUR 1 - 5 !!":PAUSE 20:GOTO 2742
2743 IF L=0 THEN 2795
2745 J=1:IF TK(L)=0 THEN PRINT:PRINT "BEREITS VERKAUFT":PAUSE 50:GOTO 2742
2747 IF MA(H,J,1)<>0 THEN 2760
2750 MA(H,J,1)=TS(L)+RND(1):MA(H,J,4)=TA(L)
2752 MA(H,J,2)=5:DM(H)=DM(H)-TK(L):MA(H,J,0)=INT(MA(H,J,1)*6)
2753 Q=J:XG=0:GOSUB 2610:IF XG=1 THEN 2777
2754 XG=3-20*(J/2=INT(J/2)):XH=INT((J+3)/2):I=J:GOSUB 8510:A$=STR$(MA(H,J,1))
2755 PRINT AT(XH,XG);G$,LEFT$(A$,2),".",LEFT$(MID$(A$,4,2)+"00",2),RIGHT$(STR$(MA(H,J,0))+"000",6)
2756 TS(L)=0:TK(L)=0:TA(L)=0:PRINT AT(L+14,0);" "
2759 GOTO 2795
2760 J=J+1:IF J<=20 THEN 2747
2762 PRINT:PRINT INK 2;"PLAETZE BESETZT !":PAUSE 50:GOTO 2730
2770 CLS:INPUT "VERKAUF NR.?:";Q$:Q=VAL(Q$):IF Q<0 OR Q>20 THEN PRINT "NUR 1 - 20 !!":PAUSE 50:GOTO 2770
2771 IF Q=0 THEN 2795
2773 IF MA(H,Q,1)=0 THEN PRINT "NICHT VORHANDEN!":PAUSE 50:GOTO 2770
2774 IF MA(H,Q,2)<0 THEN PRINT "SPIELER VERLETZT!":PAUSE 50:GOTO 2770
2775 J=1
2776 IF T5(J)<>Q THEN 2778
2777 WINDOW:CLS:PRINT AT(8,1);"WEITERE VERHANDLUNGEN NAECHSTE WOCHE !":PAUSE 30:TR=3:GOTO 530
2778 J=J+1:IF J<=5 THEN 2776
2780 XG=0:GOSUB 2610:IF XG=1 THEN 2777
2782 R=INT(MA(H,Q,1)):VV=INT(PR(R)+(RND(1)-RND(1))*MA(H,Q,1)*20)
2783 PRINT:PRINT "ANGEBOT:";RIGHT$(STR$(VV)+"000",8);" DM"
2784 PRINT:INPUT "VERKAUFEN SIE?";A$:IF A$<>"J"THEN 2795
2785 FOR I=0 TO 4:MA(H,Q,I)=0:NEXT I:X=Q:GOSUB 1080:Q=X
2790 PRINT AT(INT((Q+3)/2),2-20*(Q/2=INT(Q/2)));STRING$(18," "):DM(H)=DM(H)+VV
2795 CLS
2799 GOTO 2722
3000!*** SPIELERGEBNISSE ***
3010 CLS:IF ES=7 THEN PRINT "ANSETZUNGEN";
3020 PRINT STR$(Y);".BUNDESLIGASPIELTAG"
3030 IF ES=7 THEN PRINT:PRINT:PRINT
3100 FOR J=1 TO 9
3105 IF Y<18 THEN 3110
3106 Z=Y-17:Z(1)=VAL(MID$(M$(Z),(J-1)*4+3,2)):Z(2)=VAL(MID$(M$(Z),(J-1)*4+1,2))
3107 GOTO 3112
3110 Z(1)=VAL(MID$(M$(Y),(J-1)*4+1,2)):Z(2)=VAL(MID$(M$(Y),(J-1)*4+3,2))
3112 FOR K=1 TO SP:IF Z(1)=SP(K)THEN TB(K)=VAL(LEFT$(X$(Z(2)),1))
3113 IF Z(2)=SP(K)THEN TB(K)=-1
3115 NEXT K
3120 PRINT MID$(X$(Z(1)),2);TAB(17);": ";MID$(X$(Z(2)),2);:IF ES=7 THEN PRINT:GOTO 3300
3200 WA=INT(RND(1)*6+1):WB=INT(RND(1)*6+1):WC=WA+WB
3210 S1(1)=VAL(LEFT$(X$(Z(1)),1))
3212 S1(2)=VAL(LEFT$(X$(Z(2)),1))
3240 S=INT(RND(1)*5):N=INT(RND(1)*4):IF S<=N THEN 3240
3250 WF=VAL(MID$(H$(S1(1),S1(2)),WC,1))
3255 PRINT TAB(36);
3260 ON WF+1 GOTO 3270,3280,3290
3270 N(Z(1))=N(Z(1))+1:NP(Z(1))=NP(Z(1))+2
3272 S(Z(2))=S(Z(2))+1:PP(Z(2))=PP(Z(2))+2
3274 PT(Z(1))=PT(Z(1))+N:NT(Z(1))=NT(Z(1))+S:PT(Z(2))=PT(Z(2))+S
3276 NT(Z(2))=NT(Z(2))+N:PRINT RIGHT$(STR$(N),1);":";RIGHT$(STR$(S),1):GOTO 3300
3280 U=INT(RND(1)*3):FOR K=1 TO 2:U(Z(K))=U(Z(K))+1:PP(Z(K))=PP(Z(K))+1
3281 NP(Z(K))=NP(Z(K))+1:PT(Z(K))=PT(Z(K))+U:NT(Z(K))=NT(Z(K))+U:NEXT K
3282 PRINT RIGHT$(STR$(U),1);":";RIGHT$(STR$(U),1):GOTO 3300
3290 S(Z(1))=S(Z(1))+1:PP(Z(1))=PP(Z(1))+2
3292 N(Z(2))=N(Z(2))+1:NP(Z(2))=NP(Z(2))+2
3294 PT(Z(1))=PT(Z(1))+S:NT(Z(1))=NT(Z(1))+N:PT(Z(2))=PT(Z(2))+N
3296 NT(Z(2))=NT(Z(2))+S:PRINT RIGHT$(STR$(S),1);":";RIGHT$(STR$(N),1)
3300 NEXT J
3315 IF ES=7 THEN PRINT:PRINT:PRINT:PRINT TAB(30);">ENTER<":PRINT:PRINT:PRINT:INPUT A$:GOTO 530
3320 PRINT:FOR I=1 TO SP
3321 PRINT INK 2;MID$(X$(SP(I)),2);:IF TB(I)<0 THEN 3328
3322 IF Y=1 THEN PL(I)=10
3323 ZU=INT((22-PL(I))*600*TB(I)+(RND(1)-RND(1))*2000*TB(I))
3324 NE=INT(ZU*.01+(RND(1)-RND(1))*5*TB(I)+.5):AZ(H)=AZ(H)+1
3325 PRINT TAB(19);"ZUSCHAUER:";TAB(33);RIGHT$(" "+STR$(ZU),6):PRINT TAB(19);
3326 PRINT "EINNAHMEN:";TAB(33);RIGHT$(" "+STR$(NE)+"000",6):PRINT TAB(19);
3327 PRINT "KAPITAL:";TAB(31);:DM(I)=DM(I)+NE:ZU(I)=ZU(I)+ZU:AZ(I)=AZ(I)+1:GOTO 3330
3328 PRINT TAB(19);"REISEKOSTEN:";TAB(33);:Q=EF(I):DM(I)=DM(I)-Q
3329 PRINT RIGHT$(" "+STR$(Q)+"000",6):PRINT TAB(19);"KAPITAL:";TAB(31);
3330 PRINT RIGHT$(" "+STR$(DM(I))+"000",8):NEXT I
3340 PRINT INK 8,PAPER 6;AT(10,1);">>>>>>>>TABELLE WIRD ERMITTELT<<<<<<<<"
3350 GOSUB 3400
3360 PRINT INK 8,PAPER 5;AT(10,1);"TABELLE ERRECHNET/BITTE ENTER DRUECKEN":INPUT A$
3370 IF Y<>34 THEN GOSUB 3580
3399 RETURN
3400!*** TABELLE SORTIERT ***
3450 FOR I=1 TO 18:PA(I)=PP(I):VA(I)=I:NEXT I
3500 REM
3502 M=18
3503 M=INT(M/2)
3505 IF M=0 THEN RETURN
3506 J=1:K=18-M
3507 I=J
3508 L=I+M
3510 IF PA(I)>PA(L)THEN 3540
3512 IF PA(I)=PA(L)THEN 3700
3520 T1=PA(I):PA(I)=PA(L):PA(L)=T1
3530 X1=VA(I):VA(I)=VA(L):VA(L)=X1
3532 I=I-M
3535 IF I<1 THEN 3540
3537 GOTO 3508
3540 J=J+1
3550 IF J>K THEN 3503
3560 GOTO 3507
3580 CLS
3590 PRINT " SPIELTAG";:IF ES=3 THEN PRINT Y-1;:GOTO 3592
3591 PRINT Y;
3592 PRINT TAB(20);"S U N PKTE. TORE"
3600 FOR I=1 TO 18:PRINT RIGHT$(STR$(I)+" ",3);MID$(X$(VA(I)),2);
3603 IF ES=3 THEN 3610
3604 FOR K=1 TO SP:IF VA(I)=SP(K)THEN PL(K)=I
3605 NEXT
3610 PRINT TAB(19);RIGHT$(STR$(S(VA(I)))+" ",3);RIGHT$(STR$(U(VA(I)))+" ",3);
3612 PRINT RIGHT$(STR$(N(VA(I))),2);
3615 IF PP(VA(I))<10 THEN PRINT CHR$(9);
3617 PRINT PP(VA(I));CHR$(8);":";RIGHT$(STR$(NP(VA(I))),2);
3620 IF PT(VA(I))<10 THEN PRINT CHR$(9);
3621 PRINT PT(VA(I));CHR$(8);":";RIGHT$(STR$(NT(VA(I))),2):NEXT I
3630 PRINT:PRINT:PRINT INK 4;AT(19,30);">ENTER<":INPUT A$
3650 IF ES=3 THEN 530
3680 RETURN
3690!*** TORDIFFERENZ-SORT ***
3700 XG=PT(VA(I))-NT(VA(I)):XH=PT(VA(L))-NT(VA(L)):IF XG>XH THEN 3540
3710 IF XG<XH OR(XG=XH AND PT(VA(I))<PT(VA(L)))THEN 3520
3720 GOTO 3540
4000!*** SPIELERREPORT ***
4010 CLS:PRINT AT(1,19);"SPIELERREPORT":PRINT AT(3,18);"GEHALT/GESUNDHEIT"
4020 PRINT AT(4,18);"/GELBE KARTEN":J=0:FOR I=1 TO 20
4025 IF MA(H,I,0)=0 THEN PRINT RIGHT$(STR$(I),2):GOTO 4032
4030 PRINT RIGHT$(STR$(I),2);RIGHT$(" "+STR$(MA(H,I,0))+"000",6);:J=J+MA(H,I,0)
4031 A$=STR$(MA(H,I,2)):PRINT LEFT$(A$,2);".";LEFT$(MID$(A$,4,2)+"00",2);MA(H,I,3)
4032 NEXT
4035 PRINT AT(15,19);"GEHALTSSUMME:":PRINT AT(16,22);RIGHT$(" "+STR$(J)+"000",8)
4037 PRINT AT(19,30);">ENTER<":INPUT A$
4040 GOTO 530
5000!*** UEFA-/DFB-POKAL ***
5001 EU=0:FU=0:L=0:EE=0
5005 IF Y=4 OR Y=6 OR Y=10 OR Y=12 OR Y=17 OR Y=19 OR Y=22 OR Y=24 OR Y=26 OR Y=28 OR Y=31 OR Y=33 THEN 5040
5010 IF Y=3 OR Y=9 OR Y=15 OR Y=21 OR Y=25 OR Y=32 THEN 5200
5015 RETURN
5040!*** UEFA-CUP ***
5042 GOSUB 15000:GOSUB 16000:T3=0
5043 FOR I=1 TO SP:PRINT AT(20+I,1);UP$(I)," :":PRINT AT(20+I,24);MID$(X$(SP(I)),2)
5044 IF LEFT$(UP$(I),3)<>"AUS"THEN T3=T3+1
5045 NEXT
5046 PRINT INK 4;AT(20,32);">ENTER<":IF PEEK(36)<>0 AND PEEK(36)<>127 THEN 5046
5047 IF PEEK(36)<>13 THEN 5047
5048 WINDOW:CLS:OUT 136,4:A$=INKEY$
5049 IF T3=0 THEN RETURN
5050 FOR K=1 TO SP:CLS:N=0:IF LEFT$(UP$(K),3)="AUS"THEN 5190
5051 IF GU(K)<>1 THEN 5054
5052 GU(K)=2:PRINT INK 4;"AUSWAERTSSPIEL";
5053 PRINT INK 2;AT(18,22);"HINSPIEL: ",JU(K,2),":",JU(K,1):GOTO 5062
5054 IF GU(K)<>2 THEN 5060
5055 GU(K)=1:PRINT INK 4;"HEIMSPIEL";
5056 PRINT INK 2;AT(18,22);"HINSPIEL: ",JU(K,3),":",JU(K,4):GOTO 5062
5060 IF RND(1)>.5 THEN PRINT INK 4;"HEIMSPIEL";:GU(K)=1:GOTO 5062
5061 GU(K)=2:PRINT INK 4;"AUSWAERTSSPIEL";
5062 GU=GU(K):BU=6+RND(1):CU=4-RND(1)*2:PRINT INK 6;TAB(20);MID$(X$(SP(K)),2)
5063 IF GU=2 THEN 5076
5064 ZU=12000*CU+(RND(1)-RND(1))*2000*CU+5000
5065 IF UP$(K)="IM HALBFINALE"THEN ZU=INT(ZU*1.65):GOTO 5072
5066 IF UP$(K)="IM FINALE"THEN ZU=INT(ZU*2.1):GOTO 5072
5067 ZU=INT(ZU/3*VAL(MID$(UP$(K),8,1)))
5072 NE=INT(ZU*.009+(RND(1)-RND(1))*5*CU):DM(K)=DM(K)+NE
5074 PRINT STRING$(9,CHR$(10));TAB(10);"ZUSCHAUER:";:IG=ZU:GOSUB 6110
5075 PRINT TAB(10);"EINNAHME:";:IG=NE:GOSUB 6100:GOTO 5077
5076 PRINT STRING$(9,CHR$(10));TAB(10);"KOSTEN:";:IG=EF(K):DM(K)=DM(K)-IG:GOSUB 6100
5077 PRINT TAB(10);"KAPITAL:";:IG=DM(K):GOSUB 6100
5080 GOSUB 5500
5081 IF GU(K)=1 THEN JU(K,1)=EU:JU(K,2)=FU:GOTO 5083
5082 IF GU(K)=2 THEN JU(K,3)=EU:JU(K,4)=FU
5083 JU(K,0)=JU(K,0)+1:IF JU(K,0)<2 THEN 5189
5100!*** ABRECHNUNG UEFA-CUP ***
5104 IF GU=1 THEN XG=EU:XH=FU:ELSE XG=FU:XH=EU
5105 PRINT INK 2;AT(19,22);"RUECKSPIEL:",XG,":",XH
5110 IF JU(K,1)+JU(K,3)>JU(K,2)+JU(K,4)THEN 5150
5112 IF JU(K,1)+JU(K,3)=JU(K,2)+JU(K,4)AND JU(K,3)>JU(K,2)THEN 5150
5113 IF JU(K,1)+JU(K,3)=JU(K,2)+JU(K,4)AND JU(K,3)=JU(K,2)THEN AU=5:ELSE 5115
5114 IF L<>1 THEN I=91:J=120:INPUT "VERLAENGERUNG! >ENTER<";A$:D=200:GOSUB 5520:L=1:D=255:GOTO 5110
5115 IF L=0 THEN PRINT INK 6;"LEIDER AUSGESCHIEDEN ";UP$(K):UP$(K)="AUS "+UP$(K):GOTO 5160
5117 IF L=1 THEN GOSUB 5300
5125 IF EU>FU THEN 5150
5127 IF FU>EU THEN L=0:GOTO 5115
5130 GOSUB 5350:GOTO 5125
5150 IF UP$(K)="IN DER 1.RUNDE"THEN UP$(K)="IN DER 2.RUNDE":UP(K)=5:GOTO 5156
5151 IF UP$(K)="IN DER 2.RUNDE"THEN UP$(K)="IN DER 3.RUNDE":UP(K)=8:GOTO 5156
5152 IF UP$(K)="IN DER 3.RUNDE"THEN UP$(K)="IN DER 4.RUNDE":UP(K)=12:GOTO 5156
5153 IF UP$(K)="IN DER 4.RUNDE"THEN UP$(K)="IM HALBFINALE":UP(K)=16:GOTO 5156
5154 IF UP$(K)="IM HALBFINALE"THEN UP$(K)="IM FINALE":UP(K)=20:GOTO 5156
5155 IF UP$(K)="IM FINALE"THEN UP$(K)="UEFA-CUP-SIEGER":UP(K)=25
5156 PRINT:PRINT INK 6;"GRATULATION! SIE SIND ";UP$(K);"!"
5160 GU(K)=0:JU(K,0)=0
5189 INPUT A$
5190 NEXT K:RETURN
5200!*** DFB-POKAL ***
5201 GOSUB 15000:GOSUB 16100:T3=0
5202 FOR I=1 TO SP:PRINT AT(20+I,1);DP$(I),":":PRINT AT(20+I,24);MID$(X$(SP(I)),2)
5203 IF LEFT$(DP$(I),3)<>"AUS"THEN T3=T3+1
5205 NEXT
5206 PRINT INK 4;AT(20,32);">ENTER<":IF PEEK(36)<>0 AND PEEK(36)<>127 THEN 5206
5207 IF PEEK(36)<>13 THEN 5207
5208 WINDOW:CLS:OUT 136,4:A$=INKEY$
5210 FOR K=1 TO SP:CLS:N=0:IF LEFT$(DP$(K),3)="AUS"THEN 5280
5214 IF RND(1)>.5 THEN PRINT INK 4;"HEIMSPIEL";:GU=1:GOTO 5220
5216 PRINT INK 4;"AUSWAERTSSPIEL";:GU=2
5220 PRINT INK 6;TAB(23);MID$(X$(SP(K)),2)
5224 BU=5.8+RND(1):CU=3.8-RND(1)*2
5225 ZU=INT(10000*CU+(RND(1)-RND(1))*2000*CU+5000)
5226 IF DP$(K)="IM HALBFINALE"THEN ZU=ZU*2:GOTO 5232
5227 IF DP$(K)="IM FINALE"THEN ZU=ZU*3:GOTO 5232
5230 ZU=INT(ZU/3.5*VAL(MID$(DP$(K),8,1)))
5232 NE=INT((ZU*.009+(RND(1)-RND(1))*5*CU)/2):DM(K)=DM(K)+NE
5233 PRINT STRING$(9,CHR$(10));TAB(10);"ZUSCHAUER:";:IG=ZU:GOSUB 6110
5234 PRINT TAB(10);"EINNAHME:";:IG=NE:GOSUB 6100:PRINT TAB(10);"KAPITAL:";:IG=DM(K):GOSUB 6100
5235 GOSUB 5500
5237 IF EU>FU THEN 5250
5238 IF EU<FU THEN L=0:GOTO 5241
5240 AU=5:IF L<>1 THEN INPUT "VERLAENGERUNG!";A$:I=91:J=120:D=200:GOSUB 5520:L=1:GOTO 5237
5241 IF L=0 THEN PRINT INK 6;"LEIDER VERLOREN ";DP$(K):DP$(K)="AUS "+DP$(K):GOTO 5279
5242 IF L=1 AND EE=0 THEN 5247
5243 IF L=1 THEN GOSUB 5300
5244 IF EU>FU THEN 5250
5245 IF FU>EU THEN L=0:GOTO 5241
5246 GOSUB 5350:GOTO 5244
5247 IF L=1 THEN L=0:EE=1:INPUT "WIEDERHOLUNGSSPIEL!";A$:N=0:EU=0:FU=0:L=0
5248 CLS:IF GU=1 THEN GU=2:PRINT INK 4;"AUSWAERTSSPIEL";:GOTO 5220
5249 GU=1:PRINT INK 4;"HEIMSPIEL";:GOTO 5220
5250 IF DP$(K)="IN DER 1.RUNDE"THEN DP$(K)="IN DER 2.RUNDE":DP(K)=3:GOTO 5260
5251 IF DP$(K)="IN DER 2.RUNDE"THEN DP$(K)="IN DER 3.RUNDE":DP(K)=6:GOTO 5260
5252 IF DP$(K)="IN DER 3.RUNDE"THEN DP$(K)="IN DER 4.RUNDE":DP(K)=9:GOTO 5260
5253 IF DP$(K)="IN DER 4.RUNDE"THEN DP$(K)="IM HALBFINALE":DP(K)=12:GOTO 5260
5255 IF DP$(K)="IM HALBFINALE"THEN DP$(K)="IM FINALE":DP(K)=16:GOTO 5260
5256 IF DP$(K)="IM FINALE"THEN DP$(K)="DFB-POKAL-SIEGER":DP(K)=20
5260 PRINT INK 6;"GRATULATION! SIE SIND ";DP$(K);"!"
5279 INPUT A$
5280 NEXT:RETURN
5300!*** ELFMETERSCHIESSEN ***
5310 INK 2:INPUT "ELFMETERSCHIESSEN! ";A$:L=2:EU=0:FU=0:INK 3:X=0
5320 FOR J=1 TO 5:FOR I=1 TO 2:X=X+1
5330 IF I=1 THEN IF RND(1)<.85 THEN EU=EU+1:GOTO 5340
5335 IF I=1 THEN 5340
5338 IF RND(1)<.85 THEN FU=FU+1
5340 GOSUB 5750:NEXT I:NEXT J:RETURN
5350 FOR I=1 TO 2:X=X+1:IF I=1 THEN IF RND(1)<.85 THEN EU=EU+1:GOTO 5370
5355 IF I=1 THEN 5370
5360 IF RND(1)<.85 THEN FU=FU+1
5370 GOSUB 5750:NEXT:RETURN
5500!*** POKALERGEBNISSE ***
5505 AU=5:FU=0:EU=0:PRINT AT(4,23);"SPIELZEIT:":XG=0:XH=0
5506 GC=30/(BU-CU):OC=AU
5509 D=200
5510 I=1:J=90
5520 AU=AU+RND(1)-RND(1)
5530 NC=(AU-CU)*GC+5:IF NC<6 THEN NC=6
5531 IF NC>35 THEN NC=35
5532 PRINT INK 4;AT(16,1);" - >":PRINT AT(16,OC);" ":PRINT INK 8;AT(16,NC);""
5533 PRINT INK 4;AT(16,36);"< + ":OC=NC
5535 PRINT AT(4,34);I
5540 IF AU>BU THEN EU=EU+1:GOSUB 5700:N=N+1:AU=5:OC=NC:PAUSE 10:GOTO 5580
5550 IF AU<CU THEN FU=FU+1:GOSUB 5700:N=N+1:AU=5:OC=NC:PAUSE 10
5580 IF I=45 THEN PRINT AT(18,1);"HALBZEITSTAND:",XG,":",XH:AU=5:GOTO 5591
5590 IF I=105 THEN PRINT AT(18,1);"HALBZEITSTAND DER VERLAENGERUNG",XG,":",XH:AU=5
5591 I=I+1:IF I<=J THEN 5520
5592 D=255
5595 PRINT AT(19,1);"ENDERGEBNIS: ",XG,":",XH:RETURN
5700 IF GU=1 THEN XG=EU:XH=FU:ELSE XG=FU:XH=EU
5710 PRINT AT(N+3,0);RIGHT$(" "+STR$(I),3),".MINUTE ",XG,":",XH:RETURN
5750 IF GU=1 THEN XG=EU:XH=FU:ELSE XG=FU:XH=EU
5760 PRINT AT(7,21);RIGHT$(STR$(X),2),".SPIELER",XG,":",XH
5770 PAUSE 20:RETURN
6000!*** VEREINSUEBERSICHT ***
6018 IF F=2 THEN 6030
6019 IF Y=1 THEN VV(H)=SK(H):GOTO 6030
6020 VV(H)=0:FOR I=1 TO 20:R=INT(MA(H,I,1)):VV=PR(R)+(RND(1)-RND(1))*MA(H,I,1)*20
6025 VV(H)=VV(H)+INT(VV):NEXT:VV(H)=VV(H)+DM(H):F=2
6030 CLS:PRINT " VEREINS-UEBERSICHT ";MID$(X$(SP(H)),2):PRINT
6040 PRINT " STARTVERMOEGEN:";:IG=SK(H):GOSUB 6100
6048 PRINT " VEREINSVERMOEGEN:";:IG=VV(H):GOSUB 6100:PRINT
6050 PRINT " SPIELTAG:";:IG=Y:GOSUB 6110
6052 PRINT " KAPITAL:";:IG=DM(H):GOSUB 6100
6054 PRINT " TABELLENPLATZ:";:IG=PL(H):GOSUB 6110
6056 PRINT " DFB-POKAL:";TAB(20);DP$(H)
6058 PRINT " UEFA-CUP:";TAB(20);UP$(H)
6059 PRINT
6060 PRINT " GES.-ZUSCHAUER:";:IG=ZU(H):GOSUB 6110
6063 PRINT " HEIMSPIELE:";:IG=AZ(H):GOSUB 6110
6064 IF AZ(H)=0 THEN IG=0:ELSE IG=INT(ZU(H)/AZ(H)+.5)
6065 PRINT " ZUSCHAUERSCHNITT:";:GOSUB 6110
6070 PRINT:PRINT " GEHAELTER:";:IG=GH(H):GOSUB 6100
6090 PRINT:PRINT TAB(30);">ENTER<":PRINT:PRINT:PRINT
6099 INPUT A$:GOTO 530
6100 PRINT TAB(22);RIGHT$(" "+STR$(IG)+"000",8):RETURN
6110 PRINT TAB(22);RIGHT$(" "+STR$(IG),8):RETURN
6140 PRINT AT(17,3);" "
7000!*** ABSCHLUSSUEBERSICHT ***
7050 CLS:PRINT INK 2;">ABSCHLUSSTABELLE<";:GOSUB 3592
7051 FOR H=1 TO SP
7053 CLS:PRINT "ABSCHLUSSUEBERSICHT ";MID$(X$(SP(H)),2):PRINT
7055 VV(H)=0:FOR I=1 TO 20:R=INT(MA(H,I,1)):VV=PR(R)+(RND(1)-RND(1))*MA(H,I,1)*20
7056 VV(H)=VV(H)+INT(VV):NEXT
7062 PRINT " MANNSCHAFTSWERT:";:IG=VV(H):GOSUB 6100
7064 PRINT " BARKAPITAL:";:IG=DM(H):GOSUB 6100
7072 PRINT " ENDVERMOEGEN:";:IG=VV(H)+DM(H):GOSUB 6100
7073 PRINT " STARTVERMOEGEN:";:IG=SK(H):GOSUB 6100
7074 PRINT
7075 PRINT " GEWINN/VERLUST:";:VV(H)=VV(H)+DM(H):IG=VV(H)-SK(H):GOSUB 6100
7076 PRINT " TABELLENPLATZ:";:IG=PL(H):GOSUB 6110
7077 PRINT " PUNKTE: ";RIGHT$(STR$(PP(SP(H))),2);":";RIGHT$(STR$(NP(SP(H))),2);" TORE: ";
7078 PRINT RIGHT$(STR$(PT(SP(H))),2);":";RIGHT$(STR$(NT(SP(H))),2)
7079 PRINT " DFB-POKAL:";TAB(20);DP$(H)
7080 PRINT " UEFA-POKAL:";TAB(20);UP$(H)
7200 PRINT
7210 PRINT " BUNDESLIGAPUNKTE:";:IF PL(H)<4 THEN IG=60+(4-PL(H))*5:ELSE IG=(19-PL(H))*4
7228 G1=IG:GOSUB 6110
7230 PRINT " VERMOEGENSPUNKTE:";:G2=INT((VV(H)-SK(H))/150+.5):IG=G2:GOSUB 6110
7240 PRINT " UEFA-CUP-PUNKTE:";:IG=UP(H):GOSUB 6110
7250 PRINT " DFB-POKAL-PUNKTE:";:IG=DP(H):GOSUB 6110
7260 PRINT " TOR-PUNKTE:";
7262 G3=INT(PT(SP(H))/10+.5)
7263 IF PT(SP(H))>NT(SP(H))THEN G3=G3+INT((PT(SP(H))-NT(SP(H)))/10+.5)
7265 IG=G3:GOSUB 6110
7270 IF O<>1 OR SP=2 THEN PRINT " "
7290 G5(H)=G1+G2+G3+DP(H)+UP(H)
7295 PRINT " G E S A M T :";:IG=G5(H):GOSUB 6110
7296 IF O<>1 THEN PRINT AT(19,32);">ENTER<":INPUT A$:GOTO 7299
7298 RETURN
7299 NEXT
7300 IF SP=1 THEN 750
7310 CLS:PRINT " G E S A M T - UEBERSICHT "
7315 O=1
7320 FOR H=1 TO SP
7330 GOSUB 7210
7340 PRINT CHR$(11);" ";MID$(X$(SP(H)),2);TAB(18);" ":IF SP=2 THEN PRINT
7350 NEXT:PRINT AT(19,32);">ENTER<":INPUT A$
7999 GOTO 750
8000!*** ALLGEMEINES ***
8010 CLS:PRINT "ALLG. UEBERSICHT":PRINT ""
8050 FOR I=5 TO 1 STEP-1:FOR J=1 TO 18
8060 IF VAL(LEFT$(X$(J),1))=I THEN PRINT RIGHT$(STR$(I),2);" ";MID$(X$(J),2)
8070 NEXT:NEXT
8080 FOR I=0 TO 19:PRINT AT(I,20);"":NEXT:WINDOW 0,23,22,39
8100 PRINT "TRAUM-MANNSCHAFT:":PRINT " STAERKE 5":PRINT " 45 - 55 PUNKTE":PRINT
8110 PRINT "CUP-ANWAERTER:":PRINT " STAERKE 4":PRINT " 36 - 44 PUNKTE":PRINT
8120 PRINT "MITTELFELD:":PRINT " STAERKE 3":PRINT " 27 - 35 PUNKTE":PRINT
8130 PRINT "UNTERES DRITTEL:":PRINT " STAERKE 2":PRINT " 18 - 26 PUNKTE":PRINT
8140 PRINT "ABSTIEGSKANDIDAT:":PRINT " STAERKE 1":PRINT " 11 - 17 PUNKTE"
8190 PRINT " >ENTER<":INPUT A$
8499 WINDOW:GOTO 530
8500!*** MA-ART ***
8510 ON MA(H,I,4)+1 GOTO 8519,8520,8521,8522,8523
8512 ON TA(I)GOTO 8520,8521,8522,8523
8519 G$=" ":RETURN
8520 G$="TORW.":RETURN
8521 G$="VERT.":RETURN
8522 G$="MITT.":RETURN
8523 G$="ANGR.":RETURN
9000!*** MANNSCHAFTEN ***
9010 DATA "BAYERN MUENCHEN","HAMBURGER SV","VFB STUTTGART","1.FC K'LAUTERN"
9020 DATA "EINTR.FRANKFURT","BOR.M'GLADBACH","BOR.DORTMUND","1.FC KOELN"
9030 DATA "VFL BOCHUM","KARLSRUHER SC","BAYER LEVERKUSEN","HERTHA BSC"
9040 DATA "FORT.D'DORF","1.FC NUERNBERG","ARM.BIELEFELD","WERDER BREMEN"
9050 DATA "EINTR.BRAUNSCHW.","SCHALKE 04"
9100!*** SPIELPAARUNGEN ***
9110 DATA "011115180616031312100217050408070914"
9112 DATA "140804021712100313061615180111090705"
9114 DATA "011615130610031712040207051411180908"
9116 DATA "140204031706101513011611180908050712"
9118 DATA "151706040307121402081816111309050110"
9120 DATA "140304151701101113181609050208120706"
9122 DATA "010415070614030812051613181011170902"
9124 DATA "141504111718101602120503080607011309"
9126 DATA "011415080605030213101617180411070912"
9128 DATA "141104161713100912030206051508010718"
9130 DATA "010515020612101713041607181411080903"
9132 DATA "141604101709030612150201051108180713"
9134 DATA "011215031704100713141608180511020906"
9136 DATA "141004090615030112110218051608130717"
9138 DATA "010615091714100813051602181211030704"
9140 DATA "140415010611031812160213051008170907"
9142 DATA "010904081705100213121603180611150714"
9200!*** ERGEBNISSE ***
9211 DATA "00011222222"
9212 DATA "00001122222"
9213 DATA "00000112222"
9214 DATA "00000111222"
9215 DATA "00000011222"
9221 DATA "00112222222"
9222 DATA "00011222222"
9223 DATA "00001122222"
9224 DATA "00000112222"
9225 DATA "00000111222"
9231 DATA "00122222222"
9232 DATA "00112222222"
9233 DATA "00011222222"
9234 DATA "00001122222"
9235 DATA "00000112222"
9241 DATA "01122222222"
9242 DATA "00112222222"
9243 DATA "00111222222"
9244 DATA "00011122222"
9245 DATA "00001122222"
9251 DATA "01222222222"
9252 DATA "01122222222"
9253 DATA "00112222222"
9254 DATA "00011222222"
9255 DATA "00011122222"
9500!*** ERGEBNIS ***
9505 IF G5(H)<100 THEN 9520
9510 PRINT "DAS WAR EIN EXZELLENTES ERGEBNIS !!!"
9511 PRINT "SIND SIE SCHON BEI EINEM BUNDESLIGA-"
9512 PRINT "CLUB ANGESTELLT ???":RETURN
9520 IF G5(H)<80 THEN 9530
9521 PRINT "SIE ERREICHTEN EIN SEHR GUTES ERGEBNIS!"
9522 PRINT "VIELLEICHT SIND SIE NAECHSTES MAL TOP?":RETURN
9530 IF G5(H)<60 THEN 9540
9531 PRINT "SIE WAREN SCHON GANZ GUT. MIT ETWAS"
9532 PRINT "UEBUNG WIRD AUS IHNEN NOCH WAS!":RETURN
9540 IF G5(H)<50 THEN 9550
9541 PRINT "DAS WAR WOHL NICHT SO BESONDERS !"
9542 PRINT "SIE MUESSEN NOCH KRAEFTIG UEBEN !":RETURN
9550 PRINT "SIE WAREN DER GLATTE AUSFALL !!!"
9551 PRINT "SO WIRTSCHAFTEN SIE JEDEN CLUB PLEITE !":RETURN
10000!*** START ***
10032 DIM X$(18),H$(5,5),U(18),S(18),N(18),PP(18),NP(18),PT(18),NT(18)
10033 DIM PA(18),VA(18),M$(17)
10034 PR(1)=100:PR(2)=200:PR(3)=350:PR(4)=550:PR(5)=800
10036 FOR I=1 TO 18:READ X$(I):VA(I)=I
10038 D=INT(RND(1)*5+1):W(D)=W(D)+1:IF W(D)>4 OR(D=5 AND W(5)>2)THEN 10038
10040 X$(I)=MID$(STR$(D),2,1)+X$(I)
10042 NEXT I
10044!*** SPIELSTEUERUNG ***
10045 CLS:PRINT STRING$(7,CHR$(10)):INPUT " ANZAHL DER MITSPIELER (MAX.3)";A$
10046 SP=VAL(A$):IF SP<1 OR SP>3 THEN 10045
10048 CLS
10050 PRINT "WAEHLEN SIE BITTE IHRE MANNSCHAFT AUS!"
10052 FOR I=1 TO 18:PRINT I;TAB(4);MID$(X$(I),2,LEN(X$(I))-1):NEXT I
10054 FOR I=1 TO SP
10055 PRINT TAB(18);:PRINT AT(19,30);" "
10056 PRINT " SPIELER";I;:INPUT Q$:PRINT CHR$(11);:IF VAL(Q$)<1 OR VAL(Q$)>18 THEN 10055
10058 SP(I)=VAL(Q$):PRINT INK 2;AT(SP(I),21);"":NEXT I
10059 IF SP=1 OR(SP(1)<>SP(2)AND SP(1)<>SP(3)AND SP(2)<>SP(3))THEN 10061
10060 CLS:PRINT AT(8,2);"BITTE VERSCHIEDENE MANNSCHAFTEN !!!":PAUSE 50:GOTO 10048
10061 PRINT AT(19,18);" ":PRINT AT(8,30);"MOMENT":PRINT AT(9,30);"BITTE"
10062 FOR I=1 TO 17:READ M$(I):NEXT
10064 FOR I=1 TO 5:FOR J=1 TO 5
10066 READ H$(I,J):NEXT J:NEXT I
10068!*** STAERKE MA ***
10070 DIM MA(SP,20,4),EL(11,SP),V(20,SP),JU(SP,4)
10072 FOR H=1 TO SP
10074 FOR J=1 TO 2:MA(H,J,1)=2.2+RND(1):MA(H,J,4)=1:MA(H,J,0)=INT(MA(H,J,1)*6):NEXT
10076 FOR J=3 TO 6:MA(H,J,1)=2.2+RND(1):MA(H,J,4)=2:MA(H,J,0)=INT(MA(H,J,1)*6):NEXT
10078 FOR J=7 TO 11:MA(H,J,1)=2.2+RND(1):MA(H,J,4)=3:MA(H,J,0)=INT(MA(H,J,1)*6):NEXT
10080 FOR J=12 TO 15:MA(H,J,1)=2.2+RND(1):MA(H,J,4)=4:MA(H,J,0)=INT(MA(H,J,1)*6):NEXT
10082 DM(H)=2000:UP$(H)="IN DER 1.RUNDE":DP$(H)="IN DER 1.RUNDE"
10084 FOR J=1 TO 15:R=INT(MA(H,J,1)):VV=INT(PR(R)+(RND(1)-RND(1))*MA(H,J,1)*20)
10085 SK(H)=SK(H)+VV:MA(H,J,2)=5:NEXT:SK(H)=SK(H)+2000
10086 GOSUB 2400
10088 NEXT H
10100 RETURN
14000 A$=CHR$(191):B$=CHR$(142):FOR I=0 TO 5
14010 PRINT INK 2,PAPER 3;AT(I,13-I);""
14020 PRINT INK 5,PAPER 2;AT(I,14-I);""
14030 PRINT INK 5,PAPER 8;AT(I,15-I);B$
14040 PRINT INK 5,PAPER 8;AT(I,24+I);A$
14050 PRINT INK 5,PAPER 2;AT(I,25+I);""
14060 PRINT INK 2,PAPER 3;AT(I,26+I);""
14070 PRINT INK 2,PAPER 3;AT(19-I,13-I);A$
14080 PRINT INK 5,PAPER 2;AT(19-I,14-I);A$
14090 PRINT INK 5,PAPER 8;AT(19-I,15-I);""
14100 PRINT INK 5,PAPER 8;AT(19-I,24+I);""
14110 PRINT INK 5,PAPER 2;AT(19-I,25+I);B$
14120 PRINT INK 2,PAPER 3;AT(19-I,26+I);B$
14130 NEXT:FOR I=6 TO 13
14140 PRINT INK 2;AT(I,8);"":PRINT INK 2;AT(I,31);""
14150 PRINT INK 5;AT(I,9);"":PRINT INK 5;AT(I,30);""
14160 NEXT:PAPER 8:INK 1
14170 PRINT AT(0,16);" ":PRINT AT(1,15);" "
14180 PRINT AT(2,14);" ":PRINT AT(3,13);" "
14190 PRINT AT(4,12);" ":PRINT AT(5,11);" "
14200 PRINT AT(6,10);" ",A$," "
14210 PRINT AT(7,10);" ",A$,"",B$," "
14220 PRINT AT(8,10);" ",A$,"",B$," "
14230 PRINT AT(9,10);" "
14240 PRINT AT(10,10);" ",B$," "
14250 PRINT AT(11,10);"",A$,"",B$," "
14260 PRINT AT(12,10);" ",A$,B$," "
14270 PRINT AT(13,10);" "
14280 PRINT AT(14,11);" ",B$," "
14290 PRINT AT(15,12);" "
14300 PRINT AT(16,13);" ",A$," "
14310 PRINT AT(17,14);" ",A$,"",B$," "
14320 PRINT AT(18,15);" ",A$,"",B$," "
14330 PRINT AT(19,16);" "
14340 PAPER 1:INK 2:PRINT AT(21,1);" "
14350 PRINT AT(22,1);" "
14360 PRINT AT(23,1);" "
14370 A$=INKEY$
14380 IF INKEY$<>CHR$(13)THEN 14380
14390 RETURN
15000 CLS:BORDER 1:WINDOW 0,19,1,39:PAPER 3:INK 7:CLS
15002 FOR I=1 TO 18:PRINT AT(I,1);"":PRINT AT(I,20);"":PRINT AT(I,39);"":NEXT
15010 PRINT AT(0,1);""
15020 PRINT AT(19,1);""
15030 PRINT AT(3,1);"":PRINT AT(3,33);"":PRINT AT(5,1);"":PRINT AT(5,37);""
15040 PRINT AT(16,1);"":PRINT AT(16,33);"":PRINT AT(14,1);"":PRINT AT(14,37);""
15050 FOR I=6 TO 13:PRINT AT(I,3);"":PRINT AT(I,37);"":NEXT
15060 FOR I=4 TO 15:PRINT AT(I,7);"":PRINT AT(I,33);"":NEXT
15070 INK 2:PRINT AT(10,5);"":PRINT AT(10,35);"":INK 3:PAPER 1:RETURN
16000 INK 1:PAPER 3:PRINT AT(15,2);" "
16010 PRINT AT(16,2);"":PRINT AT(16,5);"":PRINT AT(16,7);" "
16020 PRINT AT(16,35);""
16030 PRINT AT(17,2);" "
16040 PRINT AT(18,2);" "
16050 PAPER 1:INK 3:RETURN
16100 INK 1:PAPER 3
16110 PRINT AT(15,2);" "
16120 PRINT AT(16,3);"":PRINT AT(16,5);""
16130 PRINT AT(16,7);" ":PRINT AT(16,36);""
16140 PRINT AT(17,3);" "
16150 PRINT AT(18,2);" "
16160 PAPER 1:INK 3:RETURN