Zeichensatz UTF-8+Z1013()+CTRL()-ohne Umlaute(äöüß)

   10 A1$="HEIMCOMPUTER robotron Z9001"
   20 A2$="SPIEL":A9=2 
   30 A3$="R+MOND"  
   40 A4$="SIMULATION"
   50 A5$="EINER MONDLANDUNG"         
   60 REM VERFASSER:W. Poenisch /RED
   70 REM DATUM 13.08.1984 VERSION 1.0 
   80 WINDOW:BORDER A9:INK 8:PAPER 1:CLS
   90 PRINT INK 1;AT(0,0);" "
  100 PRINT AT(2,2);A1$:PRINT AT(4,2);"",STRING$(34,""),"" 
  110 PRINT AT(5,2);"":PRINT AT(5,37);"" 
  120 PRINT AT(6,2);"",STRING$(34,""),"" 
  130 PRINT AT(5,3);A2$:PRINT INK 3;AT(5,30);A3$ 
  140 INK A9:PRINT AT(8,2);STRING$(36,"") 
  150 FOR I=9 TO 13:PRINT AT(I,2);"":PRINT AT(I,37);"":NEXT I 
  160 PRINT AT(14,2);STRING$(36,"") 
  170 INK 8:PRINT AT(10,36-LEN(A4$));A4$:PRINT AT(12,36-LEN(A5$));A5$ 
  180 INK 3:PRINT AT(18,2);"VEB ROBOTRON-MESSELEKTRONIK ":INK 8
  190 PRINT INK 3;AT(19,8);">OTTO SCHOEN< DRESDEN"
  200 PRINT INK 4;AT(22,31);">ENTER<" 
  210 T$=INKEY$:IF T$=""THEN 210
  220 WINDOW:INK 3:PAPER 1:BORDER 1:CLS
  230 WIDTH 80:PRINT:PRINT:PRINT
  240 PRINT "      SIMULATION EINER MONDLANDUNG"
  250 PRINT TAB(6);STRING$(28,CHR$(160)):PRINT
  260 PRINT
  270 INK 4
  280 PRINT "Sie haben die Handsteuerung beim Lande-":PRINT
  290 PRINT "anflug auf dem Mond 5000m ueber einem":PRINT
  300 PRINT "geeigneten Landeplatz uebernommen."
  310 PRINT
  320 PRINT "Die Sinkgeschwindigkeit betraegt 500m/s."
  330 PRINT "Der Tank enthaelt noch 1200l Treibstoff."
  340 INK 3:A$="N"
  350 PRINT:PRINT:INPUT "Wuenschen Sie Instruktionen: J/(N) ";A$
  360 IF A$="J" GOTO 410
  370 IF A$="N" GOTO 630
  380 CLS:PRINT "Antworten Sie bitte nur mit J oder N !":PRINT:PRINT
  390 GOTO 350
  400 INK 2
  410 CLS:PRINT "  HIER DIE VORSCHRIFT FUER DIE LANDUNG:"
  420 PRINT TAB(2);STRING$(37,CHR$(160)):PRINT
  430 INK 7
  440 PRINT "(1) Nach jeder Sekunde werden die Hoehe,";
  450 PRINT SPC(4)"die Geschwindigkeit sowie der ver-"
  460 PRINT SPC(4)"bleibende Tankinhalt gemeldet."
  470 PRINT "(2) Auf Anfrage geben Sie die Menge "
  480 PRINT SPC(4)"Treibstoff ein, die Sie in der "
  490 PRINT SPC(4)"naechsten Sekunde verbrennen wollen.";
  500 PRINT "(3) Der max. Schub Ihrer Triebwerke be-"
  510 PRINT SPC(4)"traegt 50 m/s^2, das entspricht "
  520 PRINT SPC(4)"300l Treibstoff pro Sekunde."
  530 PRINT "(4) Beim Beruehren der Mondoberflaeche"
  540 PRINT SPC(4)"schaltet das Triebwerk automatisch"
  550 PRINT SPC(4)"aus, und Sie erhalten Angaben ueber"
  560 PRINT SPC(4)"die Landegeschwindigkeit und den" 
  570 PRINT SPC(4)"verbliebenen Treibstoff."
  580 PRINT "(5) Ist der Tank vor der Landung leer,"
  590 PRINT SPC(4)"wird der Rapport weitergefuehrt,
  600 PRINT SPC(4)"bis Sie den Mond erreicht haben."
  610 PRINT:INK 2
  620 INPUT "ENTER";A$
  630 WINDOW  
  640 CLS:INK 2:PRINT "Beginn der Landung...VOLLE KONZENTRATION"
  650 T=0:H=5000:V=500:F=1200
  660 INK 7
  670 PRINT TAB(10)"ZEIT";TAB(15)"HOEHE";TAB(21)"TEMPO";TAB(27)"TANK";
  680 PRINT TAB(32)"EINSATZ"
  690 PRINT TAB(11)"(s)";TAB(16)"(m)";TAB(21)"(m/s)";TAB(28)"(l)";
  700 PRINT TAB(34)"(l)"
  710 PRINT TAB(10);STRING$(29,CHR$(160))
  720 WINDOW 2,23,0,8:PAPER 5:INK 2:CLS
  730 PRINT AT(2,0);CHR$(193):FOR J=1 TO 7:PRINT AT(2,J);CHR$(158):NEXT
  740 PRINT AT(2,8);CHR$(137):FOR J=3 TO 22:PRINT AT(J,8);CHR$(192):NEXT
  750 PRINT AT(23,8);CHR$(200):FOR J=7 TO 1 STEP-1:PRINT AT(23,J);CHR$(248):NEXT
  760 PRINT AT(23,0);CHR$(136):FOR J=22 TO 3 STEP-1:PRINT AT(J,0);CHR$(159):NEXT
  770 INK 8:FOR J=1 TO 7:PRINT AT(22,J);CHR$(184):NEXT:INK 4:PRINT AT(3,4);CHR$(196) 
  780 WINDOW 5,21,11,39:PRINT INK 2;AT(2,0);CHR$(193):PAPER 1:INK 7:J=3
  790!PRINT
  800 PRINT T;TAB(4)INT(H);TAB(10)INT(V);
  810 PRINT TAB(15)INT(F);TAB(21)" ";
  820 PRINT INK 2;AT(23,10);"TREIBSTOFF FUER BREMSSTOSS ?":BEEP
  830 INK 2:INPUT "";B:INK 7
  840 PRINT AT(23,10);STRING$(28," ")
  850 IF B<0 THEN 980
  860 IF B>300 THEN B=300
  870 IF B>F THEN B=F
  880 V1=V-B+50:F=F-B:H=H-.5*(V+V1)
  890 IF H<=0 THEN 1010
  900 PAPER 5:PRINT INK 2;AT(J,4);CHR$(32-(J=2)*126)
  910 J=INT(22-19*H/5000):IF J>1 THEN:PRINT INK 4;AT(J,4);CHR$(196):ELSE J=2
  920 PAPER 1
  930 T=T+1:V=V1
  940 IF F>0 THEN 790
  950 IF B=0 THEN 970
  960 PRINT "***  TANK  LEER  ***"
  970 PRINT T;TAB(4)INT(H);TAB(10)INT(V);TAB(16)"0":PAUSE 5
  980 IF B<0 THEN PRINT:PRINT "NICHT SCHUMMELN !!":PRINT
  990 B=0
 1000 GOTO 880
 1010 WINDOW:CLS:PRINT:PRINT:PRINT:PRINT
 1020 PRINT SPC(9) "***  KONTAKT  ***"
 1030 H=H+.5*(V+V1)
 1040 IF B=50 THEN 1070
 1050 D=(-V+SQR(V*V+H*(100-2*B)))/(50-B)
 1060 GOTO 1080
 1070 D=H/V
 1080 V1=V+(50-B)*D
 1090 PRINT:PRINT:PRINT:PRINT "LANDUNG NACH         :";T+D;"s"
 1100 PRINT "LANDEGESCHWINDIGKEIT :";V1;"m/s"
 1110 IF F=0 THEN 1130
 1120 PRINT "TREIBSTOFF           :";F;"l":GOTO 1140
 1130 PRINT "TANK LEER !"
 1140 IF V1<>0 GOTO 1210
 1150 INK 4:PAPER 2:WINDOW 12,19,0,39:CLS
 1160 PRINT:PRINT STRING$(40,"+");
 1170 PRINT "GRATULATION   !!!   PERFEKTE LANDUNG  !!"
 1180 PRINT "Ihre Lizenz wird erneuert  !"
 1190 PRINT STRING$(40,"+")
 1200 WINDOW 20,23,0,39:INK 7:PAPER 1:PRINT:PRINT      
 1210 IF ABS(V1)<5 THEN 1280
 1220 PRINT:PRINT "****   BRUCHLANDUNG, SCHADE   ****":PRINT
 1230 PRINT "Ihre Verwandten werden benachrichtigt !"
 1240 IF V1>=80 GOTO 1330
 1250 IF V1>=15 GOTO 1420
 1260 IF V1>=9 GOTO 1480
 1270 PRINT:PRINT "Sie haben Ihren Landeapparat beschaedigt":PRINT:PRINT
 1280 A$="J":PRINT:INPUT "Wuenschen Sie noch einen Versuch: (J)/N";A$
 1290 IF A$<>"N" GOTO 630
 1300 WINDOW
 1310 CLS:PRINT:PRINT TAB(10)" Auf Wiedersehen !"
 1320 END
 1330 PRINT
 1340 INK 8
 1350 PRINT "****************************************"
 1360 INK 6
 1370 PRINT "SIE HABEN EIN NEUES MONDMEER GESCHAFFEN!"
 1380 INK 8
 1390 PRINT "****************************************"
 1400 INK 7
 1410 GOTO 1280
 1420 Q=V1*V1/100*14
 1430 PRINT
 1440 PRINT "Sie haben einen Krater von "
 1450 PRINT Q;"m Tiefe geschaffen !"
 1460 PRINT "========================================"
 1470 GOTO 1280
 1480 PRINT 
 1490 PRINT "Sie haben Ihr Raumschiff in einen Berg"
 1500 INK 4
 1510 PRINT "Schrott verwandelt":PRINT
 1520 INK 7
 1530 GOTO 1280