Zeichensatz UTF-8+Z1013()+CTRL()-ohne Umlaute(äöüß)
5 WINDOW:LINES 0:POKE 862,25
10 REM HANDELSFAHRT =====PLUS4
20 REM (P) 7/87 COMMODORE WELT
30 REM =======================
40 REM (C) 1986 BY
50 REM CLAUS-D. HEINECK
60 REM PLUS4 (C16/116 + 64KB)
70 REM BASIC V3.5=============
80 REM PLUS4 (C16/116 + 64KB)
90 REM =======================
95 CLEAR 500
100 GOSUB 5750
110 FOR I=1 TO 20:QQ$=QQ$+C4$:NEXT:QQ$=QQ$+"":QL$=""
120 FOR I=1 TO 7:QL$=QL$+C1$:NEXT
130 CLS:!PSET0,15,3:PSET4,15,3:PSET1,8
140 PRINT AT(3,8);"DIE GROSSE HANDELSFAHRT
150 XX$=ZN$:ZZ=25:GOSUB 5720
160 PRINT AT(6,15);"WRITTEN BY"
170 PRINT AT(7,12);"KLAUS-D. HEINECK"
171 PRINT AT(9,6);"Overwork from COMMODORE +4"
172 PRINT AT(11,2);"to KC 87 from R.WERMKE and M.KNOKE"
173 BEEP:BEEP:PAUSE 1:BEEP
180 PRINT AT(15,0);"DEIN NAME":WINDOW 16,17,0,39
190!?
200 INPUT NE$:WINDOW:IF LEN(NE$)>10 THEN NE$=LEFT$(NE$,10)
210 FOR X=1 TO 1000:NEXT
220 GOSUB 5540
230 RU=0
240 G=10*INT(RND(1)*90)
260 SC=100*INT(RND(1)*100)
270 IF SC<4000 OR SC>9000 THEN 260
280 A=0:W=0:K=0:R=0:E=0:RU=0:LP=50:KE=0:XG=0:SE$="1"
290 GOSUB 5450
300 GOSUB 5340
310 WINDOW
320 WINDOW 15,22,1,15:CLS
330 PRINT AT(15,2);"DRUECKE":PRINT AT(15,19);"PREISE:"
340 PRINT AT(16,2);" "
350 PRINT AT(17,2);"1 :KAUFEN":PRINT AT(17,19);"ALLGEMEINES $"
360 PRINT AT(18,2);"2 :VERKAUF":PRINT AT(18,19);"WAFFEN $"
370 PRINT AT(19,2);"3 :SEGELN":PRINT AT(19,19);"KOHLE $"
380 PRINT AT(20,2);"4 :BANK":PRINT AT(20,19);"RUM $"
390 PRINT AT(21,19);"EDELSTEINE $"
400!PRINTTAB(80)CHR$(27)"Q"
410 WINDOW
420 PRINT AT(5,13);S$
430 PRINT AT(7,13);LEFT$(STR$(G)+" ",7)
440 PRINT AT(9,13);LEFT$(STR$(SC)+" ",7)
450 PRINT AT(11,13);LP," "
460 WINDOW
470 PRINT AT(7,34);A," "
480 PRINT AT(8,34);W," "
490 PRINT AT(9,34);K," "
500 PRINT AT(10,34);R," "
510 PRINT AT(11,34);E," "
520 PRINT AT(17,32);P(1)
530 PRINT AT(18,32);P(2)
540 PRINT AT(19,32);P(3)
550 PRINT AT(20,32);P(4)
560 PRINT AT(21,32);P(5)
570 WINDOW
580!PRINTSTRING$(12,CHR$(10))
590 PRINT AT(15,2);"DRUECKE"
600 PRINT AT(17,2);"1 :KAUFEN "
610 PRINT AT(18,2);"2 :VERKAUF "
620 PRINT AT(19,2);"3 :SEGELN "
630 IF SE$>"1"THEN GOTO 5510
640 PRINT AT(20,2);"4 :BANK "
650!PRINTAT(21,2);" BESUCH "
660 REM PRINTTAB(80)" "
670 D$=INKEY$
680 IF SE$>"1"AND D$>"3"THEN 670
690 IF D$="1"AND LP>0 THEN 740
700 IF D$="2"AND LP<50 THEN 1200
710 IF D$="3"THEN 1660
720 IF D$="4"THEN 1920
730 GOTO 670
740 WINDOW
750 WINDOW 15,21,1,15:CLS
760 PRINT "WAS WILLST DU "
770 PRINT "KAUFEN ?"
780 PRINT
790 PRINT "(A/W/K/R/E)"
800 PRINT
820 K$=INKEY$
830 IF K$<>"A"AND K$<>"W"AND K$<>"K"AND K$<>"R"AND K$<>"E"THEN 820
840 IF K$="A"THEN P=P(1)
850 IF K$="W"THEN P=P(2)
860 IF K$="K"THEN P=P(3)
870 IF K$="R"THEN P=P(4)
880 IF K$="E"THEN P=P(5)
890 WINDOW
900 WINDOW 15,21,1,15:CLS
910 PRINT "WIEVIEL WILLST"
920 PRINT "DU KAUFEN ?"
930 PRINT
950 INPUT KA
960 IF KA>50 THEN 890
970 IF KA>LP THEN GOSUB 1130
980 IF(KA*P)>G THEN 1070
990 G=G-(KA*P)
1000 LP=LP-KA
1010 IF K$="A"THEN A=A+KA
1020 IF K$="W"THEN W=W+KA
1030 IF K$="K"THEN K=K+KA
1040 IF K$="R"THEN R=R+KA
1050 IF K$="E"THEN E=E+KA
1060 GOTO 310
1070 WINDOW
1080 WINDOW 15,21,1,15:CLS
1090 PRINT "DU HAST NICHT "
1100 PRINT "GENUG GELD ! "
1110 FOR X=1 TO 1500:NEXT
1120 GOTO 890
1130 WINDOW
1140 WINDOW 15,21,1,15:CLS
1150 PRINT "DU HAST KEINEN"
1160 PRINT "PLATZ FUER";KA;"!"
1170 PRINT
1180 FOR X=0 TO 1500:NEXT
1190 GOTO 890
1200 WINDOW
1210 WINDOW 15,21,1,15:CLS
1220 PRINT "WAS WILLST DU "
1230 PRINT "VERKAUFEN ? "
1240 PRINT
1250 PRINT "(A/W/K/R/E)"
1260 PRINT
1280 V$=INKEY$
1290 IF V$<>"A"AND V$<>"W"AND V$<>"K"AND V$<>"R"AND V$<>"E"THEN 1280
1300 IF V$="A"THEN P=P(1)
1310 IF V$="W"THEN P=P(2)
1320 IF V$="K"THEN P=P(3)
1330 IF V$="R"THEN P=P(4)
1340 IF V$="E"THEN P=P(5)
1350 WINDOW
1360 WINDOW 15,21,1,15:CLS
1370 PRINT "WIEVIEL WILLST"
1380 PRINT "DU VERKAUFEN ?"
1390 PRINT
1410 INPUT VN
1420 IF VN>50 THEN 1350
1430 IF V$="A"AND VN>A THEN 1570
1440 IF V$="W"AND VN>W THEN 1570
1450 IF V$="K"AND VN>K THEN 1570
1460 IF V$="R"AND VN>R THEN 1570
1470 IF V$="E"AND VN>E THEN 1570
1480 LET G=G+(P*VN)
1490 LET LP=LP+VN
1500 IF V$="A"THEN A=A-VN
1510 IF V$="W"THEN W=W-VN
1520 IF V$="K"THEN K=K-VN
1530 IF V$="R"THEN R=R-VN
1540 IF V$="E"THEN E=E-VN
1550 IF G>=800000 THEN 5130
1560 GOTO 310
1570 WINDOW
1580 WINDOW 15,21,1,15:CLS
1590 PRINT "DU HAST KEINE "
1600 PRINT " AN BORD ! "
1610 WINDOW
1620 WINDOW 15,21,1,15
1630 PRINT AT(16,2);VN
1640 FOR X=0 TO 1500:NEXT
1650 GOTO 1350
1660 LET RU=RU+1
1670 LET XG=0
1680 WINDOW
1690 WINDOW 15,22,1,15:CLS
1700 PRINT "STAEDTE:"
1710 PRINT:PRINT "1.SWANSEA"
1720 PRINT "2.LIVERPOOL"
1730 PRINT "3.LONDON"
1740 PRINT "4.NEWCASTLE"
1750 PRINT "5.SOUTHAMPTON"
1770 SE$=INKEY$
1780 IF SE$<"1"OR SE$>"5"THEN 1770
1790 IF S$=" SWANSEA"AND SE$="1"THEN 1770
1800 GOSUB 5450
1810 IF RU=5 OR RU=10 OR RU=15 THEN 4870
1820 IF RND(1)>.22 AND RND(1)<.3 THEN 3520
1830 IF RND(1)<.15 THEN 4250
1840 IF RND(1)>.55 AND RND(1)<.65 THEN 4480
1850 IF RND(1)>.45 AND RND(1)<.55 THEN 2530
1860 IF RND(1)>.35 AND RND(1)<.45 THEN 3290
1870 IF RND(1)>.80 AND SC>0 THEN 4710:ELSE 1810
1880 GOSUB 5540
1890 LET SC=INT(1.12*SC)
1900 IF SC>=25000 THEN 5650
1910 GOTO 300
1920 WINDOW
1930 WINDOW 15,21,1,15:CLS
1940 PRINT "WILLST DU GELD "
1950 PRINT "(L)EIHEN ODER "
1960 PRINT
1970 PRINT "(Z)URUECKZAHLEN"
2010 LZ$=INKEY$
2020 IF LZ$<>"L"AND LZ$<>"Z"THEN 2010
2030 IF LZ$="L"AND XG>0 THEN 2160
2040 IF LZ$="L"THEN 2260
2050 WINDOW
2060 WINDOW 15,21,1,15:CLS
2070 PRINT "WIEVIEL WILLST "
2080 PRINT "DU ZURUECKZAH- "
2090 PRINT "LEN ?";
2110 INPUT "";ZU
2120 IF ZU>G OR ZU>SC THEN 2050
2130 LET SC=SC-ZU
2140 LET G=G-ZU
2150 GOTO 310
2160 WINDOW
2170 WINDOW 15,21,1,15:CLS
2180 PRINT "DU KANNST PRO "
2190 PRINT "FAHRT NUR EIN-"
2200 PRINT "MAL LEIHEN ! "
2210 PRINT " "
2240 FOR X=0 TO 2000:NEXT
2250 GOTO 310
2260 WINDOW
2270 WINDOW 15,21,1,15:CLS
2280 PRINT "WIEVIEL WILLST "
2290 PRINT "DU LEIHEN ?"
2300 PRINT
2320 LET XG=XG+1
2330 INPUT LE
2340 LET LI=100*INT(RND(1)*50)+1000
2350 IF LI<1000 THEN 2340
2360 IF LE>LI THEN 2400
2370 LET SC=SC+LE
2380 LET G=G+LE
2390 GOTO 310
2400 WINDOW
2410 WINDOW 15,21,1,15:CLS
2430 PRINT "DAS LIMIT IST "
2440 PRINT "$ ! "
2450 WINDOW
2460 WINDOW 15,21,1,15
2480 PRINT AT(16,3);LI:WINDOW
2490 LET SC=SC+LI
2500 LET G=G+LI
2510 FOR X=0 TO 1700:NEXT
2520 GOTO 310
2530 WINDOW 3,12,1,38:CLS
2550 PRINT AT(5,10);"*** P I R A T E N ***"
2560 A$=INKEY$:IF A$=""THEN 2560
2570 IF KE=1 THEN 2850
2580 IF RND(1)>.5 THEN 3210
2590 IF LP=50 THEN 2730
2600 CLS
2620 PRINT AT(4,10);"PIRATEN HABEN UNS"
2630 PRINT AT(5,10);"UEBERFALLEN UND DIE"
2640 PRINT AT(6,10);"GANZE LADUNG AN SICH"
2650 PRINT AT(7,10);"GENOMMEN."
2660 A$=INKEY$:IF A$=""THEN 2660
2670 LET LP=50
2680 LET A=0
2690 LET W=0
2700 LET K=0
2710 LET R=0
2720 LET E=0
2730 CLS
2740 LET X=INT(RND(1)*10)+3
2750 PRINT AT(4,10);"WAEHREND DER SCHLACHT"
2760 PRINT AT(5,10);"SIND",X,"DEINER MANN-"
2770 PRINT AT(6,10);"SCHAFT VERWUNDET WOR-"
2780 PRINT AT(7,10);"DEN.DIE HEILUNG DURCH"
2790 PRINT AT(8,10);"EINEN DOKTOR KOSTET"
2800 PRINT AT(9,10);"DICH JE VERLETZTEN $75."
2810 A$=INKEY$:IF A$=""THEN 2810
2820 LET G=G-75*X
2830 IF G<0 THEN 3070
2840 GOTO 1880
2850 CLS
2870 PRINT AT(4,10);"DEINE MANNSCHAFT BE-"
2880 PRINT AT(5,10);"NUTZT DIE KANONE VOM"
2890 PRINT AT(6,10);"SCHWARZEN JACK."
2900 A$=INKEY$:IF A$=""THEN 2900
2910 CLS
2920 IF RND(1)>.3 THEN 3000
2940 PRINT AT(4,10);"DIE KANONE IST LEIDER"
2950 PRINT AT(6,10);"KAPUTT !"
2960 A$=INKEY$:IF A$=""THEN 2960
2970 CLS
2980 LET KE=0
2990 GOTO 2600
3000!
3010 PRINT AT(4,10);"DIE KANONE HAT DAS"
3020 PRINT AT(5,10);"PIRATENSCHIFF VER-"
3030 PRINT AT(6,10);"SENKT !"
3040 PRINT AT(8,10);"(GUT GEMACHT,JUNGS!)"
3050 A$=INKEY$:IF A$=""THEN 3050
3060 GOTO 1880
3070 CLS
3080 PRINT AT(4,10);"DA DU NICHT GENUEGEND"
3090 PRINT AT(5,10);"GELD HATTEST,DEN DOK-"
3100 PRINT AT(6,10);"TOR ZU BEZAHLEN,HAT"
3110 PRINT AT(7,10);"DEINE MANNSCHAFT GE-"
3120 PRINT AT(8,10);"MEUTERT UND DAS SCHIFF"
3130 PRINT AT(9,10);"VERKAUFT,UM DIE RECH-"
3140 PRINT AT(10,10);"NUNG BEZAHLEN ZU KOEN-"
3150 PRINT AT(11,10);"NEN "
3160 PRINT AT(12,10);" NIMM'S LEICHT! "
3170 A$=INKEY$:IF A$=""THEN 3170
3180 CLS
3190 PRINT AT(7,15);"E N D E"
3200 GOTO 5260
3210 CLS
3230 PRINT AT(4,10);"DIE PIRATEN HABEN"
3240 PRINT AT(5,10);"NICHT ANGEGRIFFEN,"
3250 PRINT AT(6,10);"UND DU KANNST WEI-"
3260 PRINT AT(7,10);"FAHREN !"
3270 A$=INKEY$:IF A$=""THEN 3270
3280 GOTO 1880
3290 WINDOW 3,12,1,38:CLS
3310 PRINT AT(7,10);"*** S T U R M ***"
3320 A$=INKEY$:IF A$=""THEN 3320
3330 IF RND(1)>.5 OR LP=50 THEN 3450
3340 CLS
3360 PRINT AT(4,10);"EIN STURM IST AUFGE-"
3370 PRINT AT(5,10);"KOMMEN,UND WIR MUES-"
3380 PRINT AT(6,10);"SEN UEBER DIE HAELFTE"
3390 PRINT AT(7,10);"DER LADUNG UEBER BORD"
3400 PRINT AT(8,10);"WERFEN ! (SCHADE DRUM)"
3410 LP=LP+(A-INT(A/2))+(W-INT(W/2))+(K-INT(K/2))+(R-INT(R/2))+(E-INT(E/2))
3420 A$=INKEY$:IF A$=""THEN 3420
3430 A=INT(A/2):W=INT(W/2):K=INT(K/2):R=INT(R/2):E=INT(E/2)
3440 GOTO 1880
3450 CLS
3470 PRINT AT(5,10);"DER STURM HAT SOFORT"
3480 PRINT AT(6,10);"AUFGEHOERT,UND DU"
3490 PRINT AT(7,10);"KANNST WEITERFAHREN."
3500 A$=INKEY$:IF A$=""THEN 3500
3510 GOTO 1880
3520 WINDOW 3,12,1,38:CLS
3540 PRINT AT(7,7);"*** L A N D A U S F L U G ***"
3550 A$=INKEY$:IF A$=""THEN 3550
3560 IF RND(1)>.5 THEN 3840
3570 IF R>0 THEN 3750
3580 TR=INT(RND(1)*3100)
3590 IF TR<500 THEN 3580
3600 CLS
3610 PRINT AT(4,10);"WAEHREND EINES LAND-"
3620 PRINT AT(5,10);"AUSFLUGS HABEN DIR"
3630 PRINT AT(6,10);"TRICKBETRUEGER $",TR
3640 PRINT AT(7,10);"ABGENOMMEN !"
3650 A$=INKEY$:IF A$=""THEN 3650
3660 G=G-TR
3670 IF G<0 THEN 3690
3680 GOTO 1880
3690 CLS
3700 PRINT AT(4,10);"DU BIST JETZT PLEITE"
3710 PRINT AT(6,10);"UND MUSST DIE REISE"
3720 PRINT AT(8,10);"BEENDEN !!!"
3730 A$=INKEY$:IF A$=""THEN 3730
3740 GOTO 3160
3750 CLS:PRINT AT(4,10);"WAEHREND DU EINEN"
3760 PRINT AT(5,10);"LANDAUSFLUG GEMACHT"
3770 PRINT AT(6,10);"HAST , HABEN DEINE"
3780 PRINT AT(7,10);"MATROSEN DEN GANZEN"
3790 PRINT AT(8,10);"RUM AUSGETRUNKEN !"
3800 A$=INKEY$:IF A$=""THEN 3800
3810 LP=LP+R
3820 R=0
3830 GOTO 1880
3840 CLS
3850 PRINT AT(4,10);"WAEHREND EINES LAND-"
3860 PRINT AT(5,10);"AUSFLUGS KOMMST DU"
3870 PRINT AT(6,10);"AN EINER KNEIPE VOR-"
3880 PRINT AT(7,10);"BEI UND GEHST HINEIN."
3890 A$=INKEY$:IF A$=""THEN 3890
3900 CLS
3910 PRINT AT(4,10);"DU WIRST ZU EINEM"
3920 PRINT AT(5,10);"GLUECKSSPIEL AUFGE-"
3930 PRINT AT(6,10);"FORDERT."
3940 PRINT AT(8,10);"MACHST DU MIT ?"
3950 MM$=INKEY$
3960 IF MM$<>"J"AND MM$<>"N"THEN 3950
3970 IF MM$="N"THEN 1880
3980 GV=INT(RND(1)*10100)
3990 IF GV<1000 THEN 3980
4000 GZ=INT(RND(1)+1.5)
4010 CLS
4020 PRINT AT(5,10);"WAEHLE ZWISCHEN DEN"
4030 PRINT AT(6,10);"ZAHLEN '1' UND '2' !"
4040 PRINT AT(7,10);"IST ES DIE RICHTIGE"
4050 PRINT AT(8,10);"ZAHL , GEWINNST DU ;"
4060 PRINT AT(9,10);"IST ES DIE FALSCHE ,"
4070 PRINT AT(10,10);"VERLIERST DU."
4080 WN$=INKEY$:WN=VAL(WN$)
4090 IF WN<>1 AND WN<>2 THEN 4080
4100 IF WN<>GZ THEN 4170
4110 CLS
4120 PRINT AT(5,10);"DU HAST RICHTIG GERA-"
4130 PRINT AT(6,10);"TEN UND SOMIT $",GV
4140 PRINT AT(7,10);"GEWONNEN !"
4150 A$=INKEY$:IF A$=""THEN 4150
4160 G=G+GV:GOTO 1880
4170 CLS
4180 PRINT AT(5,10);"DU HAST FALSCH GERA-"
4190 PRINT AT(6,10);"TEN UND SOMIT $",GV
4200 PRINT AT(7,10);"VERLOREN !"
4210 A$=INKEY$:IF A$=""THEN 4210
4220 G=G-GV
4230 IF G<0 THEN GOTO 3690
4240 GOTO 1880
4250 PK=INT(RND(1)*10100)
4260 IF PK<1000 THEN 4250
4270 WINDOW 3,12,1,38:CLS
4290 PRINT AT(7,7);"*** DER SCHWARZE JACK ***"
4300 A$=INKEY$:IF A$=""THEN 4300
4310 CLS
4320 PRINT AT(4,10);"'SCHWARZER JACK' BIE-"
4330 PRINT AT(5,10);"TET DIR EINE KANONE"
4340 PRINT AT(6,10);"ZUM SCHUTZ VOR PIRA-"
4350 PRINT AT(7,10);"TEN AN."
4360 PRINT AT(8,10);"SIE KOSTET $",PK,"."
4370 PRINT AT(9,10);"WILLST DU EINE ?"
4380 KK$=INKEY$
4390 IF KK$<>"J"AND KK$<>"N"THEN 4380
4400 IF KK$="J"AND G<PK THEN 4450
4410 IF KK$="N"THEN 1880
4420 KE=1
4430 G=G-PK
4440 GOTO 1880
4450 PRINT AT(12,10);"DU HAST ZUWENIG GELD !"
4460 A$=INKEY$:IF A$=""THEN 4460
4470 GOTO 1880
4480 WINDOW 3,12,1,38:CLS
4490 PRINT AT(7,7);"*** SCHIFF IN SICHT ***"
4500 A$=INKEY$:IF A$=""THEN 4500
4510 CLS
4520 PRINT AT(4,10);"WILLST DU NAEHER AN"
4530 PRINT AT(5,10);"DAS GESICHTETE SCHIFF"
4540 PRINT AT(6,10);"HERANFAHREN ?"
4550 HF$=INKEY$
4560 IF HF$<>"J"AND HF$<>"N"THEN 4550
4570 IF HF$="N"THEN 1880
4580 IF RND(1)>.5 THEN 2530
4590 VD=INT(RND(1)*10100)
4600 IF VD<1000 THEN 4590
4610 CLS
4620 PRINT AT(4,10);"ES IST EIN ENGLISCHES"
4630 PRINT AT(5,10);"HANDELSSCHIFF."
4640 PRINT AT(6,10);"DU MACHST MIT DEM KA-"
4650 PRINT AT(7,10);"PITAEN EIN GESCHAEFT"
4660 PRINT AT(8,10);"UND VERDIENST DABEI"
4670 PRINT AT(9,10);"$",VD
4680 A$=INKEY$:IF A$=""THEN 4680
4690 G=G+VD
4700 GOTO 1880
4710 WINDOW 3,12,1,38:CLS
4720 PRINT AT(7,7);"*** EIN GOENNER ***"
4730 A$=INKEY$:IF A$=""THEN 4730
4740 GR=100*INT(RND(1)*101)
4750 IF GR<1000 THEN 4740
4760 IF GR>SC THEN GR=SC
4770 CLS
4780 PRINT AT(4,10);"EIN UNBEKANNTER GOEN-"
4790 PRINT AT(5,10);"NER HAT $",GR,"VON"
4800 PRINT AT(6,10);"DEINEN SCHULDEN ABBE-"
4810 PRINT AT(7,10);"ZAHLT !"
4820 A$=INKEY$:IF A$=""THEN 4820
4830 IF SC<GR THEN 4850
4840 SC=SC-GR:GOTO 1880
4850 SC=0
4860 GOTO 1880
4870 LET MR=INT(RND(1)*5100)
4880 IF MR<500 OR MR>2000 THEN 4870
4890 LET SR=INT(RND(1)*5100)
4900 IF SR<500 OR SR>2000 THEN 4890
4910 LET RR=INT(RND(1)*5100)
4920 IF RR<200 OR RR>2000 THEN 4910
4930 GR=MR+SR+RR
4940 WINDOW 3,12,1,38:CLS
4950 PRINT AT(4,4);"DEIN SCHIFF MUSS REPARIERT WERDEN !"
4960 PRINT AT(6,10);"KOSTEN :"
4970 PRINT AT(7,10);"LAST $",MR
4980 PRINT AT(8,10);"SEGEL $",SR
4990 PRINT AT(9,10);"RUMPF $",RR
5000 PRINT AT(10,10);"--------"
5010 PRINT AT(11,10);"GESAMT $",GR
5020 A$=INKEY$:IF A$=""THEN 5020
5030 G=G-GR
5040 IF G<0 THEN 5060
5050 GOTO 1880
5060 CLS
5070 PRINT AT(4,10);"DA DU ZUWENIG GELD"
5080 PRINT AT(5,10);"HAST , DIE RECHNUNG"
5090 PRINT AT(6,10);"ZU BEZAHLEN , MUSST"
5100 PRINT AT(7,10);"DU DIE REISE BEEN-"
5110 PRINT AT(8,10);"DEN !!!"
5120 GOTO 3160
5130 WINDOW:CLS
5140 PRINT TAB(125)""
5150 PRINT TAB(5)" "
5160 PRINT TAB(5)" H E R Z L I C H E N "
5170 PRINT TAB(5)" "
5180 PRINT TAB(5)" G L U E C K W";
5190 PRINT " U N S C H "
5200 PRINT TAB(5)" "
5210 PRINT TAB(5)""
5220 PRINT TAB(204)"DU HAST UEBER $ 800000 VERDIENT"
5230 PRINT TAB(44)"UND KANNST DICH JETZT ZUR RUHE"
5240 PRINT TAB(44)"SETZEN !!!"
5250 PRINT TAB(120)"GENAUER SPIELSTAND : $";G
5260 A$=INKEY$:IF A$=""THEN 5260
5270 CLS
5280 PRINT AT(7,10);"NOCH EIN SPIEL ?"
5290 NS$=INKEY$
5300 IF NS$<>"J"AND NS$<>"N"THEN 5290
5310 IF NS$="J"THEN RUN
5320 PRINT AT(7,7);"S C H U E S S ...! "
5330 END
5340 LET P(1)=INT(RND(1)*16)
5350 IF P(1)<1 THEN 5340
5360 LET P(2)=10*INT(RND(1)*19)
5370 IF P(2)<50 THEN 5360
5380 LET P(3)=10*INT(RND(1)*100)
5390 IF P(3)<300 THEN 5380
5400 LET P(4)=100*INT(RND(1)*31)
5410 IF P(4)<500 THEN 5400
5420 LET P(5)=100*INT(RND(1)*101)
5430 IF P(5)<1000 THEN 5420
5440 RETURN
5450 IF SE$="1"THEN LET S$=" SWANSEA"
5460 IF SE$="2"THEN LET S$=" LIVERPOOL"
5470 IF SE$="3"THEN LET S$=" LONDON"
5480 IF SE$="4"THEN LET S$=" NEWCASTLE"
5490 IF SE$="5"THEN LET S$=" SOUTHAMPTON"
5500 RETURN
5510 PRINT AT(20,2);" "
5520!PRINT" "
5530 GOTO 670
5540 CLS:PO=10-LEN(NE$)
5550 PRINT AT(0,PO);" ",NE$," SCHIFFAHRTSGESELLSCHAFT"
5560 PRINT AT(2,0);""
5570 PRINT AT(5,2);"STANDORT:"
5580 PRINT AT(7,2);"GUTHABEN $ ALLGEMEINES"
5590 PRINT AT(8,22);"WAFFEN"
5600 PRINT AT(9,2);"SCHULDEN $ KOHLE"
5610 PRINT AT(10,22);"RUM"
5620 PRINT AT(11,2);"LADEPLATZ : t EDELSTEINE"
5630 PRINT AT(13,0);""
5635 FOR I=3 TO 12:PRINT AT(I,0);"":PRINT AT(I,39);"":NEXT
5640 GOTO 6000
5650 WINDOW 3,12,1,38:CLS
5660 PRINT AT(4,10);"WEIL DU UEBER $ 25000"
5670 PRINT AT(5,10);"SCHULDEN HAST , PFAEN-
5680 PRINT AT(6,10);"DEN DEINE GLAEUBIGER"
5690 PRINT AT(7,10);"DAS SCHIFF , UND DEINE"
5700 PRINT AT(8,10);"REISE IST ZU ENDE !!!"
5710 GOTO 3160
5720 FOR I=1 TO ZZ:PRINT AT(4,6+I);XX$:NEXT:RETURN
5730 REM NACHSPANN ===========
5740 REM FARBCODES/STEUERCODES
5750 C4$=CHR$(10):RN$=CHR$(22)
5760 FL$=CHR$(6):!HE$
5770 FO$=CHR$(22):RF$=" "
5780 C1$=CHR$(8)
5790 REM ZEICHENSATZ/GRAPHIK
5800 S2$=CHR$(32):ZN$=CHR$(182)
5810 RETURN
5820 REM =====================
5830 REM 60671 BYTES MEMORY
5840 REM 12881 BYTES PROGRAM
5850 REM 00329 BYTES VARIABLES
5860 REM 00062 BYTES ARRAYS
5870 REM 00421 BYTES STRINGS
5880 REM 46978 BYTES FRE(0)
5890 REM =====================
5900 REM ERSETZEN SIE BITTE
5910 REM IN DEN PRINT-ANWEI-
5920 REM SUNGEN DIE PUNKTE
5930 REM DURCH BLANKS.
5940 REM =====================
5950 END
6000 PRINT AT(14,0);""
6010 FOR I=15 TO 22:PRINT AT(I,0);"":PRINT AT(I,16);""
6020 PRINT AT(I,39);"":NEXT
6030 PRINT AT(23,0);""
6040 RETURN