Zeichensatz UTF-8+Z1013()+CTRL()-ohne Umlaute(äöüß)

   10 A1$="HEIMCOMPUTER robotron Z9001"
   20 A2$="SPIEL":A9=2
   30 A3$="R+SKEET"
   40 A4$=" S K E E T"
   50 A5$="WURFTAUBENSCHIESSEN"       
   60 REM VERFASSER:D. Neumann
   70 REM ANSCHRIFT:RED/EC8 
   80 REM DATUM 13.08.1984 VERSION 1.0 
   90 WINDOW:BORDER A9:INK 8:PAPER 1:CLS      
  100 PRINT INK 1;AT(0,0);" ":!WINDOW23,23,39,39:INK1:CLS:INK8
  110 PRINT AT(2,2);A1$:PRINT AT(4,2);"",STRING$(34,""),"" 
  120 PRINT AT(5,2);"":PRINT AT(5,37);"" 
  130 PRINT AT(6,2);"",STRING$(34,""),"" 
  140 PRINT AT(5,3);A2$:PRINT INK 3;AT(5,29);A3$ 
  150 INK A9:PRINT AT(8,2);STRING$(36,"") 
  160 FOR I=9 TO 13:PRINT AT(I,2);"":PRINT AT(I,37);"":NEXT I 
  170 PRINT AT(14,2);STRING$(36,"") 
  180 INK 8:PRINT AT(10,36-LEN(A4$));A4$:PRINT AT(12,36-LEN(A5$));A5$ 
  190 INK 3:PRINT AT(18,2);"VEB ROBOTRON-MESSELEKTRONIK"
  195 PRINT AT(19,8);">OTTO SCHOEN< DRESDEN":INK 8
  200 PRINT INK 4;AT(22,31);">ENTER<" 
  210 T$=INKEY$:IF T$=""THEN 210
  211 BORDER 2
  220 O(0)=201:O(1)=207:O(2)=195:O(3)=166:O(4)=140
  230 S(0)=116:S(1)=20:S(2)=36:S(3)=52:S(4)=84:S(5)=100         
  235 WINDOW:PAPER 1:CLS:PRINT INK 1;AT(0,0);" "
  240 INK 7:M$="N"
  250 PRINT AT(3,3);"DURCH DRUECKEN DER TASTE >SPACE<"
  260 PRINT AT(5,3);"MUESSEN SIE DIE ANFLIEGENDEN"
  270 PRINT AT(7,3);"WURFTAUBEN ABSCHIESSEN."
  290 BORDER 2:PRINT AT(10,3);"WAEHLEN SIE BITTE SCHWIERIGKEITS-"
  291 PRINT AT(12,3);"STUFE 1 ODER 2 UND WARTEN SIE"
  292 PRINT AT(14,3);"EINIGE SEKUNDEN.":PRINT AT(22,3);"STUFE: (1)/2":M$="1"
  300 WINDOW 22,22,18,39:INPUT "";M$
  301 IF M$="1"OR M$="2"THEN PAUSE 10:WINDOW:CLS:PRINT INK 1;AT(0,0);" ":GOTO 310
  302 PRINT INK 2;AT(20,3);"WIE BITTE ?":GOTO 300
  310 PRINT AT(8,3);"ACHTUNG...":FOR I=1 TO 350:NEXT:PRINT AT(10,3);"FERTIG..."
  320 FOR I=1 TO 200:NEXT:PRINT AT(12,3);"LOS!!!":FOR I=1 TO 80:NEXT
  450 INK 5:PAPER 5:BORDER 5:CLS:PRINT INK 5;AT(0,0);" ":A=0:B=0
  460 PRINT INK 8; AT(8,1);"TAUBEN :",A
  470 PRINT INK 8; AT(10,1);"TREFFER:",B
  490 N=INT(RND(1)*6.8):IF(N=C)OR(N=0)GOTO 490 ELSE C=N
  510 IF M$="1"GOTO 570
  520 L=INT(RND(1)*5.8)+1:ON L GOTO 530,540,550,560,565,570
  530 Z=-4216:GOTO 580
  540 Z=-4218:GOTO 580
  550 Z=-4222:GOTO 580
  560 Z=-4224:GOTO 580
  565 Z=-4226:GOTO 580
  570 Z=-4220
  580 V=INT(RND(1)*4.9):P=INT(RND(1)*5.9)
  600 ON C GOTO 660,670,680,690,700,710
  660 E=-4560:F=E+39:G=1:GOTO 720
  670 E=-4601:F=E-39:G=-1:GOTO 720
  680 E=-4841:F=E-39:G=-1:GOTO 720
  690 E=-4960:F=E+39:G=1:GOTO 720
  700 E=-5116:F=E+943:G=41:GOTO 720
  710 E=-5086:F=E+936:G=39:GOTO 720
  720 FOR I=-4190 TO-4170:POKE I,32:NEXT I:FOR I=1 TO 200:NEXT I
  760 FZ=Z:A=A+1:X=0:POKE FZ- 984,36:POKE FZ+40,204
  770 FOR K=E TO F STEP G
  790 POKE K-G,32:POKE K-1024,S(P):POKE K,O(V):IF K=F THEN POKE K,32
  800 IF K=Z GOTO 930
  810 IF X<>0 GOTO 840
  820 FOR I=1 TO 5:NEXT:IF INKEY$<>" "THEN 880 ELSE X=1
  840 IF Z<-5040 THEN POKE Z,32:GOTO 880
  850 Z=Z-80:POKE Z-1024,52:POKE Z,58:POKE Z+80,32:IF Z=K GOTO 930
  880 NEXT K
  890 POKE Z,32:IF A=50 THEN 1110 ELSE 460
  930 B=B+1
  940 POKE K-1024,20:POKE K-1022,52
  950 POKE K,202:POKE K+2,42:BORDER 1
  960 POKE K-1026,52:POKE K-944,52:BORDER 7
  970 POKE K-2,42:POKE K+80,42:BORDER 2
  980 POKE K-1104,52:POKE K-942,52:BORDER 8
  990 POKE K-80,42:POKE K+82,42:BORDER 3
 1000 POKE K-1106,52:POKE K-1110,52:BORDER 5
 1010 POKE K-82,42:POKE K-86,42:BORDER 4
 1020 POKE K-1030,52:POKE K-938,52:BORDER 1
 1030 POKE K- 6,42:POKE K+86,42:BORDER 6
 1040 FOR I=1 TO 10:NEXT I:BORDER 5
 1050 POKE K,32:POKE K+2,32:POKE K-2,32
 1060 POKE K+2,32:POKE K+80,32
 1070 POKE K-80,32:POKE K+82,32
 1080 POKE K+86,32:POKE K-82,32
 1090 POKE K-86,32:POKE K- 6,32
 1100 IF A<50 GOTO 460
 1110 FOR I=-4190 TO-4170:POKE I,32:NEXT I
 1120 PAPER 1:INK 4:BORDER 1:CLS:PRINT INK 1;AT(0,0);" "
 1130 PRINT AT(3,5);"SIE HABEN BEI"
 1140 PRINT AT(5,4);A,"TAUBEN"
 1150 PRINT AT(7,4);B,"MAL GETROFFEN !"
 1160 IF B>12 GOTO 1270
 1170 IF M$="1"GOTO 1230
 1180 PRINT AT(10,5);"SIE HABEN SICH FUER DEN ANFANG"
 1190 PRINT AT(12,5);"ZUVIEL VORGENOMMEN, VERSUCHEN"
 1200 PRINT AT(14,5);"SIE ES DOCH EINMAL MIT DER"
 1210 PRINT AT(16,5);"EINFACHEN VARIANTE."
 1220 GOTO 1450
 1230 PRINT AT(10,5);"ES IST ZWECKLOS MIT IHNEN,"
 1240 PRINT AT(12,5);"SIE SOLLTEN LIEBER MIT"
 1250 PRINT AT(14,5);"MURMELN SPIELEN !"
 1260 GOTO 1450
 1270 IF B>18 GOTO 1320
 1280 PRINT AT(10,5);"SIE SOLLTEN WENIGER TRINKEN,"
 1290 PRINT AT(12,5);"BEVOR SIE SICH AN SOLCH EIN"
 1300 PRINT AT(14,5);"SCHWIERIGES SPIEL HERANWAGEN."
 1310 GOTO 1450
 1320 IF B>25 GOTO 1340
 1330 PRINT AT(10,5);"NA JA...!":GOTO 1450
 1340 IF B>35 GOTO 1380
 1350 PRINT AT(10,5);"NICHT SCHLECHT, SIE MACHEN"
 1360 PRINT AT(12,5);"SICH LANGSAM !"
 1370 GOTO 1450
 1380 FOR J=2 TO 38:PRINT INK 6;AT(0,J);CHR$(203):NEXT
 1390 FOR J=1 TO 16:PRINT INK 6;AT(J,38);CHR$(203):NEXT
 1400 FOR J=2 TO 38:PRINT INK 6;AT(16,40-J);CHR$(203):NEXT
 1410 FOR J= 8 TO 23:PRINT INK 6;AT(24-J,2);CHR$(203):NEXT
 1420 PRINT AT(10,5);"HERVORRAGEND, SIE SIND EIN"
 1430 PRINT AT(12,5);"MEISTERSCHUETZE, SIE KOENNEN"
 1440 PRINT AT(14,5);"EINEN AUSGEBEN !!!"
 1450 PRINT AT(22,3);"NOCH EINMAL: (J)/N "   
 1460 J$=INKEY$:IF J$=""GOTO 1460 
 1461 IF ASC(J$)=13 OR J$="J"THEN INK 7:CLS:GOTO 290
 1480 CLS:PRINT INK 1;AT(0,0);" ":PRINT INK 3;AT(12,10);"AUF WIEDERSEHEN !"
 1490 PAUSE 30:CLS 
 1500 END