Zeichensatz UTF-8+Z1013()+CTRL()-ohne Umlaute(äöüß)
0!*** NIEMANDSLAND *** ADAPTION AUS 'HAPPY COMPUTER' A. SCHROETER
1!ORIGINAL FUER COMMODORE C64 VON A. HAGESTEDT BREMERHAVEN
2 WINDOW:PAPER 1:INK 2:CLS:PRINT AT(0,0);" "
3 PRINT AT(1,2);" "
4 PRINT AT(2,2);" "
5 PRINT AT(3,2);" "
6 PRINT AT(4,2);" "
7 PRINT AT(7,10);" ":PRINT AT(8,10);" "
8 PRINT AT(9,10);" ":PRINT AT(10,10);" "
9 PRINT AT(11,10);" ":INK 7
10 DIM C(5),O(11),S(10),A$(54),M$(33),O$(11),P$(2),V$(58),C$(11):GOSUB 10000
15 PRINT AT(17,6);"PHANTASTISCHES ABENTEUER"
16 PRINT AT(19,11);"IM ZAUBERREICH"
20 PRINT INK 4;AT(23,20);"WEITER MIT >ENTER<"
22 IF PEEK(36)<>0 THEN 22
23 IF PEEK(36)<>13 THEN 23
25 IF WF=0 THEN GOSUB 12000:GOTO 30
26 N$="":FOR I=529 TO 542:N$=N$+CHR$(PEEK(I)):NEXT
30 R=1:O=11:AA=54:CC=11:V=58:TI=PEEK(29)*60+PEEK(30)
45 DATA-1,0,0,0,0,0,0,0,0,0,0
50 RESTORE 45:FOR X=1 TO O:READ O(X):NEXT:X=RND(-ABS(DEEK(30))/3600):GOTO 200
100 REM GRUNDRAUM
101 FOR A=0 TO 3:PRINT AT(A,A);"":NEXT:C=20:FOR A=0 TO 3:PRINT AT(C,A);"":C=C-1:NEXT
102 C=38:FOR A=0 TO 3:PRINT AT(A,C);"":C=C-1:NEXT:C=17:FOR A=35 TO 38:PRINT AT(C,A);""
103 C=C+1:NEXT:FOR A=4 TO 34:PRINT AT(3,A);"":NEXT:FOR A=4 TO 16:PRINT AT(A,4);"":NEXT
104 FOR A=4 TO 16:PRINT AT(A,34);"":NEXT:FOR A=4 TO 34:PRINT AT(17,A);"":NEXT:RETURN
110 REM LOCH IN DER DECKE
111 FOR A=15 TO 23:PRINT AT(0,A);"":NEXT:PRINT AT(1,15);"":RETURN
120 REM LOCH IM BODEN
121 FOR A=15 TO 23:PRINT AT(20,A);"":NEXT:PRINT AT(19,15);"":RETURN
130 REM LEITER
131 FOR A=1 TO 19 STEP 2:PRINT AT(A,18);"":NEXT:FOR A=2 TO 18 STEP 2:PRINT AT(A,18);" "
132 NEXT:RETURN
140 REM TUER LINKS
141 PRINT AT(5,0);"":PRINT AT(6,0);" ":PRINT AT(7,0);"":FOR A=8 TO 16:PRINT AT(A,0);" "
142 NEXT:PRINT AT(17,0);"":PRINT AT(18,0);" ":PRINT AT(19,0);" ":RETURN
150 REM TUER RECHTS
151 PRINT AT(5,37);"":PRINT AT(6,36);" ":PRINT AT(7,36);"":FOR A=8 TO 16:PRINT AT(A,36);" "
152 NEXT:PRINT AT(17,36);"":PRINT AT(18,36);" ":PRINT AT(19,37);" ":RETURN
160 REM TUER IM HINTERGRUND
161 FOR A=16 TO 22:PRINT AT(6,A);"":NEXT:PRINT AT(7,15);" ":PRINT AT(8,15);" "
162 FOR A=9 TO 15:PRINT AT(A,15);" ":NEXT:PRINT AT(14,17);""
163 PRINT AT(16,15);" ":FOR A=16 TO 22:PRINT AT(17,A);" ":NEXT:RETURN
200 REM RAUMBESCHREIBUNG
205 IF R<>1 THEN S(1)=0
210 WINDOW:CALL 550
220 ON R GOSUB 8050,8100,8150,8200,8250,8300,8350,8400,8450,8500,8550,8600
222 IF R>12 THEN ON R-12 GOSUB 8650,8700,8750,8800,8850,8900,8950,9000,9050
224 IF R>21 THEN ON R-21 GOSUB 9100,9150,9200,9250,9300,9350,9400,9450,9500
226 IF R>30 THEN ON R-30 GOSUB 9550,9600,9650
1000 REM BEFEHLSVERARBEITUNG
1010 T=1
1020 GOTO 2000
1100 FOR A=1 TO 5:IF C(A)<>0 THEN C(A)=C(A)-1:NEXT
1120 IF PEEK(36)<>0 THEN 1120:ELSE A$=INKEY$
1130 WINDOW 21,21,0,39:CLS:INK 2:INPUT "WAS NUN?";Y$:INK 7
1150 Y=0
1170 P$(2)="00"
1200 FOR W=1 TO 2
1210 GOSUB 6000
1220 IF Y>=LEN(Y$)THEN 1300
1230 IF P$(W)="00"THEN 1210
1240 NEXT W
1300 IF P$(1)<>"00"THEN 1600
1310 CLS:PRINT AT(21,0);"SO GEHT DAS NICHT !!":PAUSE 20
1320 GOTO 1000
1600 REM FESTSTELLEN OB STANDORTS-
1610 Z=1:IF P$(2)<>"00"AND P$(1)>P$(2)THEN NN$=P$(1):P$(1)=P$(2):P$(2)=NN$
1620 T$=MID$(M$(R),Z,2)
1630 IF T$="00"THEN 1900
1640 IF T$<>P$(1)THEN 1700
1650 R=VAL(MID$(M$(R),Z+2,2))
1660 GOTO 200
1700 Z=Z+4
1710 GOTO 1620
1900 T=0
1910 M=0
2000 REM FESTSTELLEN OB BDDINGUNGEN ERFUELLT WERDEN MUESSEN
2010 C=0
2100 C=C+1
2110 IF T=0 THEN 2300
2120 E$=C$(C)
2130 GOTO 2600
2300 IF AA>=C THEN 2400
2310 IF M<>0 THEN 1000
2320 CLS:PRINT AT(21,0);"DAS GEHT NICHT !!":PAUSE 20
2350 GOTO 1000
2400 IF LEFT$(A$(C),2)<>P$(1)THEN 2100
2410 Y$=MID$(A$(C),3,2)
2420 IF Y$<>"00"AND Y$<>P$(2)THEN 2100
2430 E$=MID$(A$(C),5)
2600 REM ABFRAGEN DER BEDINGUNGSTABELLE
2610 E=1
2700 IF MID$(E$,E,1)="."THEN 3000
2710 P=ASC(MID$(E$,E,1))-64
2720 N=VAL(MID$(E$,E+1,2))
2800 ON P GOSUB 2900,2910,2920,2930,2940,2950,2960,2970
2810 IF K=0 THEN 2100
2820 E=E+3
2830 GOTO 2700
2900 K=-(N=R):RETURN
2910 K=-(O(N)=R OR O(N)<0):RETURN
2920 K=-(O(N)<>R AND O(N)>=0):RETURN
2930 K=-(O(N)<0):RETURN
2940 K=S(N):RETURN
2950 K=-(S(N)=0):RETURN
2960 K=-(C(N)=1):RETURN
2970 K=-(INT(RND(1)*100+1<=N)):RETURN
3000 REM DURCHFUEHREN DER AKTIONEN
3010 M=1
3020 E=E+1
3100 IF MID$(E$,E,1)="."THEN 2100
3110 P=ASC(MID$(E$,E,1))-64
3120 IF MID$(E$,E+1,1)<>"."THEN N=VAL(MID$(E$,E+1,2))
3200 B=0
3210 ON P GOSUB 4000,4100,4200,4300,4400,4500,4600,4700,4800,4900,5000,5100
3215 IF P>12 THEN ON P-12 GOSUB 5200,5300,5400,5500,5600
3220 ON B GOTO 200,1000,1100
3230 E=E+3
3240 GOTO 3100
4000 WINDOW:CALL 550:INK 2:PAPER 1
4010 PRINT " DEINE BESITZTUEMER:"
4020 PRINT:PRINT:INK 3
4030 FOR X=1 TO O
4040 IF O(X)>=0 THEN 4070
4050 PRINT " ";O$(X):PRINT
4070 NEXT X
4075 PRINT AT(22,30);">ENTER<"
4080 IF PEEK(36)<>13 THEN 4080
4090 G$=INKEY$:INK 7:B=1:RETURN
4100 REM
4140 IF O(N)=-1 THEN 4180
4150 O(N)=-1
4170 RETURN
4180 PRINT "SIE HABEN ES BEREITS."
4190 B=1:RETURN
4200 RETURN
4300 WINDOW 21,23,0,39:CLS:WINDOW 22,23,0,39:CLS
4310 ON N GOSUB 7010,7020,7030,7040,7050,7060,7070,7080,7090,7100,7110,7120
4320 IF N>12 THEN ON N-12 GOSUB 7130,7140,7150,7160,7170,7180,7190,7200,7210,7220
4321 IF N>22 THEN ON N-22 GOSUB 7230,7240,7250,7260,7270,7280,7290,7300,7310,7320
4322 IF N>32 THEN ON N-32 GOSUB 7330,7340,7350,7360,7370,7380
4325 IF N<>4 AND N<>19 AND N<>25 THEN PAUSE 50:CLS
4330 RETURN
4400 S(N)=1:RETURN
4500 S(N)=0:RETURN
4600 C(N)=VAL(MID$(E$,E+3,2))
4610 E=E+2
4620 RETURN
4700 X=O(N):O(N)=O(N+1):O(N+1)=X:RETURN
4800 O(N)=R:RETURN
4900 O(N)=0:RETURN
5000 R=N:RETURN
5100 WINDOW 21,21,0,39:CLS:PRINT AT(21,0);"OKEY.":PAUSE 30:CLS:B=2:RETURN
5200 B=2:RETURN
5300 B=3:RETURN
5400 B=1:RETURN
5500 WINDOW 21,23,0,39:CLS:WINDOW 22,22,19,39:CLS
5510 PRINT AT(22,0);"SIE WOLLEN AUFGEBEN":INPUT W$
5520 IF LEFT$(W$,1)<>"J"THEN 5400
5600 GOTO 9999
6000 REM SCHLUESSELWORT ABTRENNEN
6010 W$=""
6015 P$(W)="00"
6020 GOSUB 6600
6025 IF D=1 THEN RETURN
6030 FOR Q=1 TO 4
6040 W$=W$+MID$(Y$,Y,1)
6050 GOSUB 6500
6060 IF D=1 THEN 6100
6070 NEXT Q
6080 GOSUB 6500
6090 IF D=0 THEN 6080
6100 W$=W$+STRING$(4-LEN(W$)," "):IF W$=" "THEN RETURN
6110 FOR Q=1 TO V
6120 IF W$=MID$(V$(Q),3)THEN 6200
6130 NEXT Q
6140 RETURN
6200 P$(W)=LEFT$(V$(Q),2)
6210 RETURN
6500 Y=Y+1
6510 D=-(Y>LEN(Y$))
6520 IF D=1 THEN RETURN
6530 D=-(MID$(Y$,Y,1)=" ")
6540 RETURN
6600 Y=Y+1
6610 D=-(Y>LEN(Y$))
6620 IF D=1 THEN RETURN
6630 IF MID$(Y$,Y,1)=" "THEN 6600
6640 RETURN
6700 CLS
6710 FOR N=1 TO 50
6720 PRINT N;V$(N)
6730 NEXT N
6740 END
7000 REM AKTIONSMELDUNGEN
7010 PRINT AT(11,16);"":PRINT AT(12,15);" ":PRINT AT(13,15);" "
7011 PRINT AT(14,15);" ":PRINT AT(15,15);"":PRINT AT(16,15);" "
7012 PRINT AT(17,13);" ":PRINT AT(18,13);""
7013 PRINT AT(19,12);"":PRINT AT(20,12);""
7014 PRINT AT(22,0);"AUF MAGISCHE WEISE HAT SICH DIE"
7015 PRINT AT(23,0);"ZUGBRUECKE GEOEFFNET !":RETURN
7020 PRINT AT(22,0);"DORT IST EINE STEILE FELSWAND!":RETURN
7030 PRINT AT(22,0);"DU BIST IN DEN WASSERGRABEN GEFALLEN"
7035 PRINT AT(23,0);"UND JAEMMERLICH ERSOFFEN!":RETURN
7040 WINDOW:CLS:INK 4:FOR A=1 TO 8:PRINT AT(A,18);"":NEXT
7041 FOR A=3 TO 4:PRINT AT(A,14);"":NEXT:INK 5:PRINT AT(8,15);""
7042 PRINT AT(8,20);"":B=14:C=23:FOR A=8 TO 17:PRINT AT(A,B);""
7043 PRINT AT(A,C);"":B=B-1:C=C+1:NEXT:FOR A=18 TO 21
7044 PRINT AT(A,5);"":NEXT
7045 PRINT AT(10,14);"HIER LIEGT":PRINT AT(12,11);N$:PRINT AT(14,12);"GESTORBEN NACH"
7046 PRINT AT(16,13);PEEK(29)*60+PEEK(30)-TI,"MINUTEN"
7047 PRINT AT(23,30);">ENTER<"
7048 IF PEEK(36)<>13 THEN 7048
7049 RETURN
7050 PRINT AT(22,0);"DU BEFINDEST DICH IM 'TAL DER ANTWORT'."
7051 PRINT AT(23,0);"PROBIERE DEINE STIMME AUS !!!":RETURN
7060 PRINT AT(21,0);"DU WURDEST IN DEM DICHTEN WALD VON DEN"
7061 PRINT AT(22,0);"KOBOLDEN DES ZAUBERERS ERWARTET UND IN"
7062 PRINT AT(23,0);"EINEN STEINBLOCK VERWANDELT !":RETURN
7070 PRINT AT(22,0);"EIN RIESE HAT DICH GEMOPST UND GEFRESSEN":RETURN
7080 PRINT AT(21,0);"PLOETZLICH TAUCHT EIN GEIST AUF UND"
7081 PRINT AT(22,0);"GIBT DIR EINE ROLLE MIT EINEM SPRUCH."
7082 PRINT AT(23,0);"DAFUER BRINGE IHM SEIN AMULETT WIEDER !":PAUSE 30:RETURN
7090 PRINT AT(22,0);"DER GUTE GEIST HAT SCHON AUF DICH UND"
7091 PRINT AT(23,0);"SEIN AMULETT GEWARTET !":RETURN
7100 PRINT AT(22,0);"DER GEIST WIRD DIR NUN BEI DER ERFUEL-"
7101 PRINT AT(23,0);"LUNG DEINER AUFGABE BEHILFLICH SEIN !":RETURN
7110 PRINT AT(22,0);"DER WIND HAT DIE FACKEL AUSGEBLASEN !":RETURN
7120 PRINT AT(21,0);"UNTER DIR OEFFNETE SICH EINE FALLTUER,"
7121 PRINT AT(22,0);"DU BIST IN EINE GRUBE GEFALLEN UND"
7122 PRINT AT(23,0);"VON KROKODILEN GEFRESSEN WORDEN !!!":RETURN
7130 PRINT AT(22,0);"DU HAST KEINE STREICHHOELZER !":RETURN
7140 PRINT AT(22,0);"BIST DU BLIND? DIE FACKEL BRENNT DOCH !":RETURN
7150 PRINT AT(22,0);"WO SIEHST DU HIER EINE FACKEL?":RETURN
7160 PRINT AT(22,0);"IN DEN DUNKLEN KELLER KANNST DU NUR"
7161 PRINT AT(23,0);"MIT LICHT HINUNTERSTEIGEN !":RETURN
7170 PRINT AT(22,0);"IN DER WAND STECKT EINE FACKEL !":RETURN
7180 PRINT AT(22,0);"DAS LOCH IST VIEL ZU HOCH !":RETURN
7190 PRINT AT(14,25);" ":PRINT AT(15,25);" ":RETURN
7200 PRINT AT(22,0);"DORT LIEGT DAS WUNDERSCHWERT, NUR EIN"
7201 PRINT AT(23,0);"WESEN MIT REINEM HERZEN DARF ES TRAGEN.":RETURN
7210 PRINT AT(22,0);"DAS WUNDERSCHWERT KANN NUR MIT DEM"
7211 PRINT AT(23,0);"SIEGELRING AKTIVIERT WERDEN !!":RETURN
7220 PRINT AT(22,0);"IN DER WAND IST EIN LOCH !":RETURN
7230 PRINT AT(22,0);"IN DEM LOCH LIEGT EIN GOLDNER SCHLUESSEL":RETURN
7240 PRINT AT(22,0);"DIE PRINZESSIN SITZT AUF DEM TRON !":RETURN
7250 WINDOW:CLS:PRINT AT(5,1);"DIE PRINZESSIN ERWACHT UND IST UEBER="
7251 PRINT AT(7,1);"GLUECKLICH OB DER RETTUNG IHRER SELBST"
7252 PRINT AT(9,1);"UND DER IHRES LANDES. NUN IST NIEMANDS-"
7253 PRINT AT(11,1);"LAND VON DEM TYRANNISCHEN ZAUBERER BE-"
7254 PRINT AT(13,1);"FREIT UND KANN WIEDER IN FRIEDEN LEBEN."
7255 PRINT AT(16,1);"OFFENBAR HAT DIE PRINZESSIN EIN AUGE"
7256 PRINT AT(18,1);"AUF DICH GEWORFEN. NUN LIEGT ES AN DIR"
7257 PRINT AT(20,1);"IHR DEN HOF ZU MACHEN, DENN DAS ABEN-"
7258 PRINT AT(22,1);"TEUER IST HIER ZU ENDE !":PRINT AT(23,30);">ENTER<"
7259 IF PEEK(36)<>13 THEN 7259:ELSE RETURN
7260 PRINT AT(22,0);"DIESE TUER FUEHRTE IN DEN BURGGRABEN,"
7261 PRINT AT(23,0);"DU BIST ABGESOFFEN !":RETURN
7270 PRINT AT(22,0);"IM SCHRANK LIEGEN STREICHHOELZER !":RETURN
7280 PRINT AT(22,0);"DU HATTEST GAR NICHTS UM SIE ZU TOETEN,"
7281 PRINT AT(23,0);"DAFUER HAT SIE DICH VERSPEIST !!":RETURN
7290 PRINT AT(22,0);"IM NETZ LIEGT DER SIEGELRING !":RETURN
7300 PRINT AT(22,0);"DIE SPINNE IST IM WEGE !":RETURN
7310 PRINT AT(21,0);"DER SIEGELRING VERSETZT DICH DURCH SEINE"
7311 PRINT AT(22,0);"MAGISCHEN KRAEFTE AUF DEN TURM UND"
7312 PRINT AT(23,0);"AKTIVIERT GLEICHZEITIG DAS WUNDERSCHWERT":RETURN
7320 PRINT AT(21,0);"DIE KOBOLDE HABEN DICH UEBERFALLEN UND"
7321 PRINT AT(22,0);"ABGEMURKST. BEDENKE DAS NAECHSTE MAL,"
7322 PRINT AT(23,0);"DASS SIE KEIN LICHT MOEGEN !":RETURN
7330 PRINT AT(22,0);"DER GEIST LOEST DEN FLUCH AUF, DEN DER"
7331 PRINT AT(23,0);"ZAUBERER AUF DAS ZIMMER GELEGT HATTE !":RETURN
7340 PRINT AT(22,0);"AUF DIESEM ZIMMER LIEGT EIN FLUCH, DER"
7341 PRINT AT(23,0);"ERST AUFGELOEST WERDEN MUSS !!":RETURN
7350 PRINT AT(21,0);"DER ZAUBERER IST NUR MIT DEM AKTIVIER-"
7351 PRINT AT(22,0);"TEN WUNDERSCHWERT ZU TOETEN."
7352 PRINT AT(23,0);"SO GING ES DIR AN DEN KRAGEN !!":RETURN
7360 PRINT AT(22,0);"AKRAN TRAEGT EIN AMULETT BEI SICH !":RETURN
7370 PRINT AT(22,0);"DU SPUERST DIE FORM EINES KOERPERS !":RETURN
7380 PRINT AT(22,0);"IN EINER FELSSPALTE LIEGT EIN"
7382 PRINT AT(23,0);"ALTER SCHLUESSEL!":RETURN
7999 RETURN
8000 REM STANDORT BESCHREIBUNGEN
8050 PRINT AT(0,0);" ",CHR$(142)," ",CHR$(191),""
8052 FOR A=1 TO 17:PRINT AT(A,5);" ":PRINT AT(A,24);" ":NEXT
8053 PRINT AT(7,0);"":PRINT AT(7,13);"":PRINT AT(7,33);""
8054 FOR A=8 TO 18:PRINT AT(A,24);" ":NEXT
8055 PRINT AT(18,0);""
8056 PRINT AT(5,8);"":FOR A=6 TO 8:PRINT AT(A,7);"":NEXT:PRINT AT(5,29);"":FOR A=6 TO 8
8057 PRINT AT(A,28);"":NEXT:PRINT AT(10,17);"":PRINT AT(11,16);""
8058 PRINT AT(12,15);"":FOR A=13 TO 17:PRINT AT(A,15);"":NEXT
8059 PRINT AT(19,13);"":PRINT AT(20,0);""
8060 PRINT AT(20,35);"":PRINT AT(22,0);"ICH SEHE EINE BURG MIT GESCHLOSSENER"
8061 PRINT AT(23,0);"ZUGBRUECKE,UND DAVOR EINEN WASSERGRABEN"
8062 RETURN
8100 WINDOW:CLS:INK 5:PRINT AT(0,0);" ":PRINT AT(0,22);"":PRINT AT(1,22);""
8101 INK 7:FOR A=3 TO 18 STEP 5:PRINT AT(2,A);"":NEXT:FOR C1=3 TO 4:FOR B=2 TO 17 STEP 5
8102 PRINT AT(C1,B);"":NEXT:NEXT:INK 5:FOR A=2 TO 6:PRINT AT(A,22);"":NEXT
8103 INK 7:FOR A=0 TO 22 STEP 2:PRINT AT(7,A);"":NEXT:PRINT INK 5;AT(7,24);""
8104 FOR A=8 TO 17:PRINT AT(A,23);"":NEXT:PRINT AT(6,29);""
8105 PRINT AT(7,29);"":FOR A=8 TO 10:PRINT AT(A,31);"":NEXT
8106 B=30:FOR C1=11 TO 17:PRINT AT(C1,B);"":B=B-1:NEXT:FOR A=0 TO 23
8107 PRINT AT(18,A);"":NEXT:PRINT AT(11,32);"":PRINT AT(12,31);""
8108 PRINT AT(13,30);"":PRINT AT(14,29);""
8109 PRINT AT(15,28);"":PRINT AT(16,27);""
8110 PRINT AT(17,26);"":PRINT AT(18,25);""
8111 PRINT AT(19,24);"":FOR A=0 TO 38:PRINT AT(20,A);"":NEXT
8112 PRINT AT(22,0);"DAS IST DER RECHTE TEIL DER BURG. SIE"
8113 PRINT AT(23,0);"STEHT DIREKT AM MEER, WIE DU SIEHST.":RETURN
8150 WINDOW:CLS:PRINT AT(0,0);" ":PRINT INK 5;AT(0,11);""
8151 PRINT INK 5;AT(1,10);"":FOR A=20 TO 35 STEP 5:PRINT AT(2,A);"":NEXT
8152 FOR C=3 TO 4:FOR B=19 TO 34 STEP 5:PRINT AT(C,B);"":NEXT:NEXT
8153 FOR B=2 TO 6:PRINT INK 5;AT(B,10);"":NEXT:FOR A=15 TO 37 STEP 2
8154 PRINT AT(7,A);"":NEXT:PRINT INK 5;AT(7,10);"":FOR A=8 TO 17:PRINT AT(A,15);""
8155 NEXT:PRINT AT(6,0);"":PRINT AT(7,0);"":FOR A=8 TO 10
8156 PRINT AT(A,0);"":NEXT:FOR A=8 TO 14:PRINT AT(A+3,A);"":NEXT
8157 FOR A=15 TO 38:PRINT AT(18,A);"":NEXT:PRINT AT(11,0);""
8158 PRINT AT(12,0);"":PRINT AT(13,0);"":PRINT AT(14,0);""
8159 PRINT AT(15,0);"":PRINT AT(16,0);""
8160 PRINT AT(17,0);"":PRINT AT(18,0);""
8161 PRINT AT(19,0);"":FOR A=0 TO 38:PRINT AT(20,A);"":NEXT
8162 PRINT AT(22,0);"DAS IST DER LINKE TEIL DER BURG. SIE"
8163 PRINT AT(23,0);"STEHT DIREKT AM MEER, WIE DU SIEHST.":RETURN
8200 FOR A=0 TO 22 STEP 11:PRINT AT(5,A);" ":PRINT AT(6,A);" "
8201 PRINT AT(7,A);" ":PRINT AT(8,A);" "
8202 PRINT AT(9,A);" ":PRINT AT(10,A);" "
8203 PRINT AT(11,A);"",CHR$(191)," ",CHR$(142)," "
8204 PRINT AT(12,A);" ",CHR$(191)," "
8205 PRINT AT(13,A);" ",CHR$(191),"",CHR$(142)," "
8206 PRINT AT(14,A);" ":PRINT AT(15,A);" "
8207 PRINT AT(16,A);" ":PRINT AT(17,A);" "
8208 PRINT AT(18,A);" ":NEXT
8209 PRINT AT(22,0);"DU BEFINDEST DICH IM 'TAL DER ANTWORT'.":RETURN
8250 FOR A=8 TO 30 STEP 11:PRINT AT(2,A);"":NEXT:FOR A=3 TO 5:FOR B=7 TO 29 STEP 11
8251 PRINT AT(A,B);"":NEXT:NEXT:PRINT AT(9,17);""
8252 PRINT AT(10,16);"":FOR A=11 TO 16:PRINT AT(A,16);"":NEXT
8253 FOR A=14 TO 25:PRINT AT(17,A);"":NEXT:FOR A=13 TO 26:PRINT AT(18,A);"":NEXT
8254 FOR A=0 TO 38:PRINT AT(19,A);"":NEXT:FOR A=12 TO 27:PRINT AT(19,A);"":NEXT
8255 PRINT AT(8,18);"":PRINT AT(22,0);"DU STEHST MITTEN IM BURGHOF.":RETURN
8300 FOR A=17 TO 28 STEP 11:PRINT AT(2,A);"":NEXT:FOR A=3 TO 5:FOR C=16 TO 27 STEP 11
8301 PRINT AT(A,C);"":NEXT:NEXT:FOR A=3 TO 7:PRINT AT(A,4);"":NEXT:PRINT AT(6,0);""
8302 FOR A=0 TO 6:PRINT AT(A,3);"":NEXT:PRINT AT(3,2);"":PRINT AT(4,1);""
8303 PRINT AT(5,0);"":PRINT AT(7,3);"":PRINT AT(8,2);"":PRINT AT(9,1);""
8304 PRINT AT(10,0);"":PRINT AT(11,0);"":PRINT AT(12,0);""
8305 PRINT AT(13,0);"":PRINT AT(14,0);"":A=7:FOR C=11 TO 17:PRINT AT(C,A);CHR$(191),""
8306 A=A+1:NEXT:PRINT AT(18,14);CHR$(191),"":FOR A=12 TO 18:PRINT AT(A,3);"":NEXT
8307 A=2:FOR C=19 TO 21:PRINT AT(C,A);"":A=A-1:NEXT:FOR A=3 TO 38:PRINT AT(19,A);"":NEXT
8308 PRINT AT(19,15);CHR$(191),"":PRINT INK 3;AT(14,5);"":PRINT INK 2;AT(15,4);""
8309 PRINT AT(15,5);"":PRINT INK 2;AT(15,7);"":PRINT INK 2;AT(16,4);" "
8310 PRINT AT(22,0);"LINKER TEIL DES BURGHOFES. UNTER DER"
8311 PRINT AT(23,0);"TREPPE IST EIN HEBEL ANGEBRACHT.":RETURN
8350 GOSUB 100:GOSUB 110:GOSUB 120:GOSUB 130:GOSUB 150
8351 PRINT AT(22,0);"DU BIST IM TURM !":RETURN
8400 FOR A=0 TO 35:PRINT AT(19,A);"":NEXT:C=19:FOR A=36 TO 38:PRINT AT(C,A);"":C=C+1:NEXT
8401 FOR A=0 TO 18:PRINT AT(A,35);"":NEXT:FOR A=9 TO 23 STEP 14:PRINT AT(2,A);"":NEXT
8402 FOR A=3 TO 5:FOR C=8 TO 22 STEP 14:PRINT AT(A,C);"":NEXT:NEXT:PRINT AT(3,36);""
8403 PRINT AT(4,36);"":PRINT AT(5,37);"":PRINT AT(6,38);"":PRINT AT(7,32);"":C=32
8404 FOR A=8 TO 10:PRINT AT(A,C);"":C=C+1:NEXT:PRINT AT(11,35);"":PRINT AT(12,36);""
8405 PRINT AT(13,37);"":PRINT AT(14,38);"":FOR A=11 TO 18:PRINT AT(A,15);"":NEXT
8406 PRINT AT(10,15);"":PRINT INK 2;AT(13,22);"":PRINT AT(14,22);"":PRINT AT(15,22);""
8407 IF O(5)=-1 OR O(6)=-1 THEN FOR A=13 TO 15:PRINT AT(A,22);" ":NEXT
8408 PRINT AT(22,0);"RECHTER TEIL DES BURGHOFES !":RETURN
8450 GOSUB 100:GOSUB 110:GOSUB 150
8451 PRINT AT(22,0);"DIES IST DER KELLERRAUM IM TURM !":RETURN
8500 GOSUB 100:GOSUB 140:GOSUB 150:GOSUB 160
8501 PRINT AT(22,0);"DU BIST IM VORDEREN KELLERGANG !":RETURN
8550 GOSUB 100:GOSUB 140:GOSUB 150:GOSUB 160
8551 IF O(9)=-1 THEN 8554:ELSE PRINT AT(5,1);"":PRINT AT(6,1);""
8552 FOR A=7 TO 17:PRINT AT(A,1);"":NEXT:PRINT AT(18,1);"",CHR$(142)
8553 PRINT AT(19,1);CHR$(142)
8554 IF O(2)<>-1 THEN FOR A=7 TO 16:PRINT AT(A,16);"":NEXT
8555 PRINT AT(22,0);"DER HINTERE KELLERGANG !":RETURN
8600 GOSUB 100:GOSUB 140:GOSUB 160
8601 PRINT AT(13,23);"":PRINT AT(14,22);" "
8602 PRINT AT(15,22);" ":PRINT AT(16,25);""
8603 PRINT AT(17,23);" ":PRINT AT(18,24);""
8604 IF O(7)=-1 THEN RETURN
8605 PRINT INK 5;AT(14,26);"":PRINT INK 2;AT(14,32);""
8606 PRINT INK 5;AT(15,26);" ":PRINT INK 2;AT(15,32);""
8607 PRINT AT(22,0);"DORT LIEGT DAS WUNDERSCHWERT, NUR EIN"
8608 PRINT AT(23,0);"WESEN MIT REINEM HERZEN DARF ES TRAGEN.":RETURN
8650 GOSUB 100:GOSUB 150
8651 PRINT AT(6,17);"":PRINT AT(7,17);"":PRINT AT(8,17);""
8652 PRINT AT(9,17);CHR$(142),"",CHR$(191):PRINT AT(10,17);""
8653 PRINT AT(15,22);"":PRINT AT(16,12);" "
8654 PRINT AT(17,11);" ":PRINT AT(18,11);""
8655 PRINT AT(19,11);"":PRINT AT(8,10);""
8656 PRINT AT(22,0);"DAS VERLIES !":RETURN
8700 GOSUB 100:GOSUB 140
8701 PRINT INK 6;AT(6,15);"",CHR$(142),"":PRINT INK 6;AT(7,15);""
8702 FOR A=8 TO 18:PRINT INK 2;AT(A,16);" ":NEXT:PRINT INK 5;AT(8,17);"",CHR$(142)
8703 PRINT INK 5;AT(9,17);"",CHR$(142):PRINT INK 5;AT(10,17);"",CHR$(142)
8704 PRINT INK 5;AT(11,17);CHR$(142):PRINT INK 6;AT(16,17);" "
8705 PRINT INK 6;AT(17,17);"":PRINT INK 6;AT(18,17);""
8706 PRINT INK 6;AT(18,15);"":PRINT INK 6;AT(17,23);"":PRINT INK 2;AT(18,22);CHR$(142)
8707 PRINT INK 6;AT(18,23);"":PRINT INK 6;AT(19,14);""
8708 PRINT AT(22,0);"IN DIESER FOLTERKAMMER STEHT EINE"
8709 PRINT AT(23,0);"GILLOUTINE !!":RETURN
8750 GOSUB 100:GOSUB 150:GOSUB 110:GOSUB 120:GOSUB 130
8751 PRINT AT(22,0);"DIESER RAUM BEFINDET SICH IM ERSTEN"
8752 PRINT AT(23,0);"STOCKWERK DES TURMES !":RETURN
8800 PRINT AT(5,6);"",CHR$(142),"",CHR$(191),"",CHR$(142),"",CHR$(191)
8801 PRINT AT(5,21);"",CHR$(142),"",CHR$(191),""
8802 PRINT AT(6,5);"",CHR$(142)," ",CHR$(191),""
8803 PRINT AT(7,4);"",CHR$(142)," ",CHR$(191),""
8804 PRINT AT(8,4);" ":FOR A=9 TO 13:FOR C=7 TO 31
8805 PRINT AT(A,C);"":NEXT:NEXT:PRINT AT(9,4);"":PRINT AT(9,34);""
8806 PRINT AT(10,1);"",CHR$(142),"":PRINT AT(10,34);"",CHR$(191),""
8807 PRINT AT(11,0);"",CHR$(142),"":PRINT AT(11,35);"",CHR$(191),""
8808 PRINT AT(12,0);"":PRINT AT(12,38);"":PRINT AT(13,0);"":PRINT AT(13,38);""
8809 PRINT AT(14,0);"":PRINT AT(14,38);"":B=6:C=32:FOR A=14 TO 20:PRINT AT(A,B);""
8810 PRINT AT(A,C);"":B=B-1:C=C+1:NEXT:GOSUB 120
8811 PRINT AT(22,0);"DU BIST GANZ OBEN AUF DEM TURM !":RETURN
8850 GOSUB 100:GOSUB 140:GOSUB 150:GOSUB 160
8851 PRINT AT(16,13);"":PRINT AT(17,12);""
8852 FOR A=12 TO 26:PRINT AT(18,A);"":NEXT:PRINT AT(19,13);"":PRINT AT(19,24);""
8853 PRINT AT(20,13);"":PRINT AT(20,25);""
8854 PRINT AT(22,0);"DER WARTESAAL !":RETURN
8900 GOSUB 100:GOSUB 140
8901 PRINT INK 2;AT(7,15);" ":PRINT INK 2;AT(8,15);""
8902 PRINT INK 2;AT(9,15);CHR$(191),"",CHR$(142):PRINT INK 2;AT(10,16);""
8903 PRINT INK 2;AT(11,16);"":PRINT INK 2;AT(12,14);""
8904 PRINT INK 4;AT(13,14);"":PRINT INK 2;AT(13,15);"":PRINT INK 4;AT(13,24);""
8905 PRINT INK 2;AT(14,15);"":PRINT INK 2;AT(15,15);""
8906 PRINT INK 3;AT(16,14);"":PRINT INK 3;AT(17,13);""
8907 PRINT INK 3;AT(18,12);""
8908 PRINT INK 3;AT(19,12);""
8909 PRINT AT(22,0);"DIES IST DER TRONSAAL !":RETURN
8950 GOSUB 100:GOSUB 140:GOSUB 150:GOSUB 160
8951 PRINT AT(14,1);"":PRINT AT(15,1);CHR$(142),"":PRINT AT(16,1);"",CHR$(142),""
8952 PRINT AT(17,1);CHR$(142),"",CHR$(142),"":PRINT AT(18,1);"",CHR$(142),""
8953 PRINT AT(19,1);"":PRINT AT(22,0);"VORDERER FLUR IM ERDGESCHOSS !":RETURN
9000 GOSUB 100:GOSUB 120:GOSUB 140:GOSUB 150:GOSUB 160
9001 PRINT AT(22,0);"DIES IST EIN DURCHGANGSZIMMER !":RETURN
9050 GOSUB 100:GOSUB 140:GOSUB 150
9051 PRINT AT(22,0);"HINTERER FLUR IM ERDGESCHOSS !":RETURN
9100 GOSUB 100:GOSUB 150
9101 INK 3:PRINT AT(10,1);"",CHR$(142),"":PRINT AT(11,0);"",CHR$(142),""
9102 PRINT AT(12,0);"":PRINT AT(13,0);"":PRINT AT(14,0);"":PRINT AT(15,0);""
9103 PRINT AT(16,0);"":PRINT AT(17,0);" ":PRINT AT(18,0);"":PRINT AT(19,0);" "
9104 PRINT AT(20,0);"":INK 2:FOR A=4 TO 29:PRINT AT(14,A);"":NEXT:FOR A=4 TO 30
9105 PRINT AT(15,A);"":NEXT:PRINT AT(14,30);"":PRINT AT(15,31);"":FOR A=4 TO 31
9106 PRINT AT(16,A);"":NEXT:PRINT AT(17,7);"":PRINT AT(17,27);"":PRINT AT(18,7);""
9107 PRINT AT(18,27);"":PRINT AT(17,8);"":PRINT AT(17,26);"":INK 7
9108 PRINT AT(22,0);"DIES IST DIE KUECHE !":RETURN
9150 GOSUB 100:GOSUB 110:GOSUB 130
9151 PRINT AT(22,0);"DIE LEITER FUEHRT IN DAS ERDGESCHOSS !":RETURN
9200 GOSUB 100:GOSUB 140:GOSUB 120
9201 PRINT AT(22,0);"DAS LOCH FUEHRT IN DEN KELLER !":RETURN
9250 GOSUB 100:GOSUB 110
9251 C=38:FOR A=0 TO 20:PRINT AT(A,C);"":C=C-1:NEXT:C=38:FOR A=4 TO 20:PRINT AT(A,C);""
9252 C=C-1:NEXT:C=38:FOR A=8 TO 20:PRINT AT(A,C);"":C=C-1:NEXT:C=38:FOR A=12 TO 20
9253 PRINT AT(A,C);"":C=C-1:NEXT:C=38:FOR A=16 TO 20:PRINT AT(A,C);"":C=C-1:NEXT
9254 PRINT AT(20,38);"":C=29:FOR A=10 TO 19:PRINT AT(A,C);"":C=C+1:NEXT
9255 IF S(7)THEN RETURN
9256 FOR A=0 TO 5:PRINT AT(A,14);"":NEXT:PRINT AT(5,5);"":PRINT AT(5,21);""
9257 PRINT AT(6,4);" ":PRINT AT(7,3);" "
9258 PRINT AT(8,5);" ":PRINT AT(9,4);" "
9259 PRINT AT(10,6);" ",CHR$(191),"",CHR$(142)," "
9260 PRINT AT(11,5);" ",CHR$(191),"",CHR$(142)," "
9261 PRINT AT(12,11);"":PRINT AT(13,11);CHR$(191),"",CHR$(142)
9262 PRINT AT(14,12);"",CHR$(142),CHR$(191),"":PRINT AT(15,12);" "
9263 PRINT AT(22,0);"DU BIST INS NETZ EINER RIESIGEN SPINNE"
9264 PRINT AT(23,0);"GEFALLEN !!!":RETURN
9300 GOSUB 100:GOSUB 140:GOSUB 150:GOSUB 160
9301 PRINT AT(22,0);"DER VORDERE FLUR IM ERSTEN STOCK !":RETURN
9350 GOSUB 100:GOSUB 140
9351 PRINT INK 3;AT(10,14);" ":PRINT INK 2;AT(10,30);""
9352 PRINT INK 3;AT(11,13);" ",CHR$(191),"":PRINT INK 2;AT(11,30);"
9353 PRINT INK 2;AT(12,12);"":PRINT INK 3;AT(12,13);" ",CHR$(191),""
9354 PRINT INK 2;AT(12,26);" ":PRINT INK 2;AT(13,12);" "
9355 PRINT INK 3;AT(13,33);CHR$(191),"":PRINT INK 2;AT(14,12);" "
9356 PRINT INK 3;AT(14,34);CHR$(191),"":PRINT INK 2;AT(15,12);" "
9357 PRINT INK 3;AT(15,35);CHR$(191),"":PRINT INK 2;AT(16,12);""
9358 PRINT INK 3;AT(16,14);" ":PRINT INK 2;AT(16,26);" "
9359 PRINT INK 2;AT(16,36);"":PRINT INK 2;AT(17,12);"":PRINT INK 3;AT(17,13);""
9360 PRINT INK 2;AT(17,26);"":PRINT INK 3;AT(17,27);" ":PRINT INK 2;AT(17,36);""
9361 PRINT INK 2;AT(18,12);"":PRINT INK 3;AT(18,13);"":PRINT INK 2;AT(18,26);""
9362 PRINT INK 3;AT(18,31);CHR$(191)," ":PRINT INK 2;AT(18,36);""
9363 PRINT INK 2;AT(19,14);"":PRINT INK 2;AT(19,24);"":PRINT INK 3;AT(19,33);CHR$(191)," "
9364 PRINT INK 2;AT(19,36);"":PRINT INK 3;AT(20,34);CHR$(191)," ":PRINT INK 2;AT(20,36);""
9365 PRINT INK 3;AT(21,35);""
9366 PRINT AT(22,0);"DAS IST DER SCHLAFRAUM DER KOBOLDE !":RETURN
9400 GOSUB 100:GOSUB 150:GOSUB 160
9401 PRINT AT(22,0);"DIES IST DER MITTLERE FLUR !":RETURN
9450 GOSUB 100:GOSUB 140:GOSUB 150
9451 PRINT AT(22,0);"DU BIST IM HINTEREN FLUR !":RETURN
9500 GOSUB 100:GOSUB 140
9501 PRINT INK 2;AT(9,15);"":PRINT INK 2;AT(10,14);""
9502 PRINT INK 2;AT(11,13);"":PRINT INK 2;AT(12,13);""
9503 PRINT INK 2;AT(13,13);" ":PRINT INK 2;AT(14,13);" "
9504 PRINT INK 2;AT(15,13);" ":PRINT INK 3;AT(15,17);""
9505 PRINT INK 2;AT(16,13);" ":PRINT INK 3;AT(16,17);""
9506 PRINT INK 2;AT(17,13);" ":PRINT INK 3;AT(17,16);""
9507 PRINT INK 2;AT(18,13);" ":PRINT INK 3;AT(18,15);""
9508 PRINT INK 2;AT(19,13);" ":PRINT INK 3;AT(19,14);""
9509 PRINT INK 2;AT(20,13);" ":IF S(9)THEN 9515
9510 PRINT AT(7,31);"":PRINT AT(8,34);"":PRINT INK 2;AT(9,30);"":PRINT AT(9,35);""
9511 PRINT AT(10,30);" ":PRINT AT(11,31);" ":PRINT AT(12,29);""
9512 PRINT AT(13,28);" ":PRINT AT(14,28);" ":PRINT AT(15,29);""
9513 PRINT AT(16,29);" ":PRINT AT(17,29);" ":PRINT AT(18,29);" "
9514 PRINT AT(19,28);" "
9515 PRINT AT(22,0);"DIES IST DER SCHLAFRAUM DES ZAUBERERS !"
9516 IF S(9)THEN PRINT AT(23,0);"AUF DEM BODEN LIEGT DER TOTE ZAUBERER !":RETURN
9517 PRINT AT(23,0);"UND DER ZAUBERER IST AUCH HIER !":RETURN
9550 GOSUB 100:GOSUB 150
9551 PRINT AT(6,19);"":PRINT AT(7,19);" ":PRINT AT(8,19);" ":PRINT AT(9,19);" "
9552 PRINT AT(10,19);"":PRINT AT(11,20);"":PRINT AT(12,6);"":PRINT AT(12,19);""
9553 PRINT AT(13,6);"":PRINT AT(13,18);"":PRINT AT(14,6);CHR$(191),"",CHR$(142)
9554 PRINT AT(14,18);"":PRINT AT(15,6);"":PRINT AT(15,18);""
9555 PRINT AT(16,6);"":PRINT AT(17,6);""
9556 PRINT AT(22,0);"DAS WC !":RETURN
9600 GOSUB 100:GOSUB 160
9601 PRINT AT(16,14);"":PRINT AT(17,13);""
9602 PRINT AT(18,12);" ":PRINT AT(19,12);""
9603 PRINT AT(20,12);""
9604 PRINT AT(22,0);"DU BIST IM BADERAUM !":RETURN
9650 GOSUB 100:GOSUB 140
9651 INK 2:PRINT AT(9,15);"":PRINT AT(10,14);""
9652 PRINT AT(11,13);"":PRINT AT(12,13);""
9653 PRINT AT(13,13);" ":PRINT AT(14,13);" "
9654 FOR A=15 TO 19:PRINT AT(A,13);"":PRINT AT(A,26);"":NEXT
9655 INK 3:PRINT AT(15,17);"":PRINT AT(16,17);"":PRINT AT(17,16);""
9656 PRINT AT(18,15);"":PRINT AT(19,14);""
9657 PRINT INK 2;AT(20,13);" ":INK 7
9658 PRINT AT(22,0);"DU BIST IM SCHLAFRAUM DER PRINZESSIN !"
9659 IF O(11)=-1 OR S(2)THEN RETURN
9660 PRINT AT(23,0);"SELTSAM - SIE IST NICHT ZU SEHEN !!!":RETURN
9900 RETURN
9999 FOR I=529 TO 542:POKE I,ASC(MID$(N$,I-528,1)):NEXT:CLEAR:WF=1:GOTO 1
10000 PAPER 1:INK 7
10010 RESTORE 10020
10020 DATA "DEIN LEBEN"
10030 DATA "EIN GOLDENER SCHLUESSEL"
10040 DATA "EINE MAGISCHE SPRUCHROLLE"
10050 DATA "EIN AMULETT"
10060 DATA "EINE BRENNENDE FACKEL"
10070 DATA "EINE FACKEL"
10080 DATA "EIN WUNDERSCHWERT"
10090 DATA "EIN SIEGELRING"
10100 DATA "EIN ALTER SCHLUESSEL"
10110 DATA "STREICHHOELZER"
10120 DATA "DIE SCHLAFENDE PRINZESSIN"
10130 DATA "01N ","01NORD","02O ","02OSTE","03S ","03SUED"
10140 DATA "04W ","04WEST","05H ","05HOCH","06R ","06RUNT"
10150 DATA "13RUFE","13SAGE","14SEHE","14SCHA","14BLIC","14BETR"
10160 DATA "15NEHM","16GEBE","17BEWE","17DREH","18GEHE","18STEI"
10170 DATA "19BREN","19ZUEN","20SETZ","21TOET","21ERSC","22TAST"
10180 DATA "22FUEH","23I ","23INVE","24L ","24LIST","25LUST"
10190 DATA "25AUFH","26SPRU","27FELS","27WAND","28SCHL","29AMUL","30HEBE"
10191 DATA "31TREP","32FACK","33SCHW","33WUND","34LOCH","35PRIN","36SIEG"
10192 DATA "36RING","37SCHR","38STRE","39SPIN","40NETZ","41ZAUB","42BETT"
10193 DATA "43KOER"
10200 DATA "0202040300"
10202 DATA "040100"
10204 DATA "0201040400"
10206 DATA "020300"
10208 DATA "03010406020800"
10210 DATA "0205050700"
10212 DATA "03060515021700"
10214 DATA "040500"
10216 DATA "021000"
10218 DATA "04090111021200"
10220 DATA "03100214012300"
10222 DATA "0410011400"
10224 DATA "021100"
10226 DATA "0312041100"
10228 DATA "06070516022600"
10230 DATA "061500"
10232 DATA "040702180119030500"
10234 DATA "0417030800"
10236 DATA "031702200121042900"
10238 DATA "04190124062500"
10240 DATA "03190422022400"
10242 DATA "022100"
10244 DATA "052400"
10246 DATA "03200623042100"
10248 DATA "00"
10249 DATA "04150227012800"
10250 DATA "042600"
10251 DATA "03260129023000"
10252 DATA "0328043100"
10253 DATA "042800"
10254 DATA "0229033200"
10255 DATA "013100"
10256 DATA "042900"
10390 DATA "A01E01.D01N."
10400 DATA "E04.D04Q."
10410 DATA "A04C03.D05N."
10420 DATA "A06D05.H05D11N."
10430 DATA "A12D07.D19N."
10440 DATA "A12C07.D20N."
10450 DATA "A16D05.H05D11N."
10460 DATA "E06.D25Q."
10470 DATA "A27D05.D32E04M."
10480 DATA "A29E05F03.E03D33N."
10490 DATA ".N."
10500 DATA "0300A01.D02N."
10510 DATA "0100A01F01.D03E04M."
10520 DATA "2300.AN."
10530 DATA "1326A01D03.E01M."
10540 DATA "0100A01E01.K05O."
10550 DATA "0100A02.D03E04M."
10560 DATA "0300A02.D02N."
10570 DATA "0200A02.D02N."
10580 DATA "1427A02C09.D38N."
10585 DATA "1528A02C09.I09B09L."
10590 DATA "0100A03.D03E04M."
10600 DATA "0300A03.D02N."
10610 DATA "0300A04.D02N."
10620 DATA "0100A04.D06E04M."
10630 DATA "0400A04.D07E04M."
10640 DATA "1300A04C03.D08I03B03N."
10650 DATA "1300A04D04.D09N."
10660 DATA "1629A04D04.H05D10E05N."
10670 DATA "1730A06.D12E04M."
10680 DATA "1831A06.K07O."
10690 DATA "1932D06D10.H05L."
10700 DATA "1932D06C10.D13N."
10710 DATA "1932D05.D14N."
10720 DATA "1932C06.D15N."
10730 DATA "0600A07D05.K09O."
10740 DATA "0600A07.D16N."
10750 DATA "1427A08C05C06.D17N."
10760 DATA "1532A08C05C06.I06B06L."
10770 DATA "0500A09.D18N."
10780 DATA "0400A11D09.K13O."
10790 DATA "1533A12C07.D19D21I07B07N."
10800 DATA "1427A13.D22N."
10810 DATA "1434A13C02.D23N."
10820 DATA "1528A13C02.I02B02L."
10830 DATA "2035A18D11.J11D24E02N."
10840 DATA "1736A18D08E02.E06M."
10850 DATA "0200A20.D26E04M."
10860 DATA "1437A22C10.D27N."
10870 DATA "1538A22C10.I10B10L."
10880 DATA "0300A23D02.K11O."
10890 DATA "2139A25C07.D28E04M."
10900 DATA "2139A25D07.E07O."
10910 DATA "1440A25C08.D29N."
10920 DATA "1536A25F07.D30N."
10930 DATA "1536A25C08.I08B08L."
10940 DATA "1736A25D08.E08D31K16O."
10950 DATA "0200A29F03.D34N."
10960 DATA "0200A29.K33O."
10962 DATA "2141A30D07E08.E09O."
10964 DATA "2141A30.D35E04M."
10966 DATA "1441A30E09.D36N."
10968 DATA "1529A30E09C04.I04B04L."
10970 DATA "2242A33C11.D37E10N."
10972 DATA "1543A33E10.I11B11N."
11000 FOR N=1 TO 11:READ O$(N):NEXT N
11010 FOR N=1 TO 58:READ V$(N):NEXT N
11020 FOR N=1 TO 33:READ M$(N):NEXT N
11030 FOR N=1 TO 11:READ C$(N):NEXT N
11040 FOR N=1 TO 54:READ A$(N):NEXT N
11050 DATA 62,32,33,0,236,119,17,1,236,1,191,3,237,176,201
11060 RESTORE 11050:FOR I=550 TO 564:READ A:POKE I,A:NEXT:RETURN
12000 CLS:INK 3
12010 PRINT "Am 'MEER DER EWIGEN TRAEUME' steht die"
12020 PRINT "Burg TATUM .In ihr leben der boese Zau-"
12030 PRINT "berer AKRAN und seine Kobolde. Der Zau-"
12040 PRINT "berer hat vor etwa 99 Jahren die Prin-"
12050 PRINT "zessin LAILA WANDA entfuehrt und in"
12060 PRINT "Tiefschlaf versetzt und noch Niemandem"
12070 PRINT "ist es gelungen,bis zu ihr vorzudringen.";
12080 PRINT "Alle,die es versuchten,mussten sterben,"
12090 PRINT "denn ausser dem boesen Zauberer und"
12100 PRINT "seinen Kobolden gibt es auch noch viele"
12110 PRINT "Fallen und Orte, die mit einem Zauber"
12120 PRINT "belegt wurden. Aber es gibt auch gute"
12130 PRINT "Geister und das Wunderschwert, und wenn"
12140 PRINT "es Dir gelingt, dem guten Geist sein"
12150 PRINT "Amulett zurueckzubringen, dann wird er"
12160 PRINT "Dir hilfreich zur Seite stehen."
12170 PRINT:PRINT "Uebrigens wird NIEMANDSLAND von den"
12180 PRINT "Menschen auch 'Reich der Phantasie '"
12190 PRINT "genannt !!!"
12200 PRINT:PRINT:PRINT:PRINT TAB(20);"weiter mit >ENTER<";:PRINT AT(23,38);" "
12210 IF PEEK(36)<>0 THEN 12210
12220 IF PEEK(36)<>13 THEN 12220
12230 CLS:PRINT " Deine Unternehmungen im Niemandsland"
12240 PRINT "musst Du mit Eingabe von Handlungen auf"
12250 PRINT "meine Frage 'WAS NUN?' steuern."
12260 PRINT:PRINT "Welche Worte und Saetze wirksam sind,"
12270 PRINT "sollst Du selbst herausfinden."
12280 PRINT:PRINT "Einige Beispiele als Hilfe:":PRINT:PRINT "ICH GEHE NACH NORDEN"
12290 PRINT "ICH SEHE ZUR WAND"
12300 PRINT "ICH NEHME ..... 'I'=INVENTUR"
12310 PRINT:PRINT "Richtungs-Angaben auch abgekuerzt:"
12320 PRINT:PRINT " 'N'=NORDEN 'S'=SUEDEN 'W'=WESTEN"
12330 PRINT " 'O'=OSTEN 'H'=HOCH 'R'=RUNTER"
12335 IF PEEK(36)<>0 THEN 12335:ELSE A$=INKEY$
12340 PRINT:PRINT:INPUT "Wie heisst Du, mutiger Recke?";N$
12342 IF N$=""THEN N$="Unbekannter"
12345 PRINT:PRINT "Glueck auf den Weg, ";N$;" !"
12350 IF LEN(N$)>=14 THEN N$=LEFT$(N$,14)
12360 X=LEN(N$)/2:N$=MID$(" "+N$+" ",X,14)
12380 PRINT:PRINT TAB(20);"weiter mit >ENTER<";:PRINT AT(23,38);" "
12390 IF PEEK(36)<>0 THEN 12390
12400 IF PEEK(36)<>13 THEN 12400
12500 RETURN
12999 RETURN