Zeichensatz UTF-8+Z1013()+CTRL()-ohne Umlaute(äöüß)

   50 CLS
  100 DIM S(38),R(38),N(38),KE$(40),KO$(15)
  110 N1=31:N2=12  
  120 FOR X=1 TO N1
  130 READ S(X),L:R(X)=S(X):N(X)=S(X)+L-1
  140 NEXT X
  150 GOSUB 1900
  160 PRINT "  GUTEN TAG, ICH BIN ELIZA. BITTE         SCHILDERE DEIN PROBLEM."
  170 PRINT:INPUT I$
  180 I$=" "+I$+" "
  200 IF I$=P$ THEN PRINT "  SAGE NICHT IMMER DASSELBE!":GOTO 170
  210 S=0
  220 FOR K=1 TO N1
  230 IF S>0 THEN 290
  240 K$=KE$(K)
  250 LL=LEN(K$)
  260 FOR J=1 TO LEN(I$)-LL
  270 IF MID$(I$,J,LL)=K$ THEN A=J:S=K:T=A:F$=K$:GOTO 300
  280 NEXT J
  290 NEXT K
  300 IF S>0 THEN K=S:L=T:GOTO 400
  310 K=N1
  320 GOTO 570
  400 C$=" "+RIGHT$(I$,LEN(I$)-LEN(F$)-L+1)
  410 FOR X=2 TO N2/2
  420 S$=KO$(2*X-1)
  430 R$=KO$(2*X)
  440 FOR L=1 TO LEN(C$)
  450 IF L+LEN(S$)>LEN(C$) THEN 510
  460 IF MID$(C$,L,LEN(S$))<>S$ THEN 510
  470 C$=LEFT$(C$,L-1)+R$+RIGHT$(C$,LEN(C$)-LEN(S$)-L+1)
  480 L=L+LEN(R$)
  500 GOTO 540
  510 IF L+LEN(R$)>LEN(C$) THEN 540
  520 IF MID$(C$,L,LEN(R$))<>R$ THEN 540
  530 C$=LEFT$(C$,L-1)+S$+RIGHT$(C$,LEN(C$)-LEN(R$)-L+1)
  540 NEXT L
  550 NEXT X
  560 IF MID$(C$,2,1)=" " THEN C$=RIGHT$(C$,LEN(C$)-1)
  570 RESTORE 2100
  580 FOR X=1 TO R(K):READ F$:NEXT X
  590 R(K)=R(K)+1:IF R(K)>N(K) THEN R(K)=S(K)
  600 IF RIGHT$(F$,1)=" " THEN F$=LEFT$(F$,LEN(F$)-1):GOTO 600
  610 IF RIGHT$(F$,1)<>"*" THEN PRINT F$:P$=I$:GOTO 170
  620 F$=LEFT$(F$,LEN(F$)-1)
  630 PRINT F$;C$
  640 GOTO 170
 1900 NN=1
 1905 RESTORE 2050
 1910 READ X$
 1920 IF X$="###" THEN 1950
 1930 KE$(NN)=X$:NN=NN+1
 1940 GOTO 1910
 1950 NN=1
 1960 READ X$
 1970 IF X$="###" THEN RETURN
 1980 KO$(NN)=X$:NN=NN+1
 1990 GOTO 1960
 2000 DATA 1,2,3,2,5,2,7,2,9,1,10,2,12,2,14,1,15,2,17
 2010 DATA 4,17,4,17,4,17,4,17,4,17,4,21,1,22,1,23,2,25,1,25,1,26
 2020 DATA 2,28,2,30,2,32,2,34,2,36,2,38,3,41,3,44,2,46,2,48,4,52 
 2030 DATA 0,0,0,0,0,0,0,00,00,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
 2050 DATA KANNST DU,KANN ICH,DU BIST,ICH FUEHLE,BIST DU,ICH KANN NICHT
 2060 DATA ICH BIN,DU,ICH MOECHTE,WAS,WIE,WER,"WO ",WANN,WARUM,NAME,GRUND
 2070 DATA TRAUM,HALLO,GUTEN TAG,VIELLEICHT,NEIN,DEIN,IMMER,DENKE,JA
 2080 DATA FREUND,COMPUTER,GELD,ELIZA,NOKEYFOUND,###
 2090 DATA BIST,BIN,WARST,WAR,"DU ","ICH ",DEIN,MEIN,DIR,MIR,###
 2100 DATA "DENKST DU NICHT, DASS ICH ES KANN?"
 2110 DATA "WAERE ES DIR DENN REHT, WENN ICH ES     KOENNTE?"
 2120 DATA MOECHTEST DU DAS WIRKLICH KOENNEN?
 2130 DATA "WARE ES DENN GUT, WENN DU DAS KOENNTEST?"
 2150 DATA WUENSCHST DU DIR MANCHMAL DU WAERST     *
 2155 DATA WESHALB DENKST DU ICH BIN*
 2160 DATA FUEHLST DU DICH OFT SO?
 2170 DATA eRZAHLE MIR MEHR UEBER SOLCHE GEFUEHLE!
 2180 DATA WUERDE DIR DAS GEFALLEN?
 2190 DATA HAST DU ES DENN VERSUCHT?
 2200 DATA VERSUCHE ES DOCH NOCHMAL HEUTE ABEND    ZUHAUSE!
 2210 DATA WIE LANGE BIST DU SCHON*
 2220 DATA BIST DU GERN*
 2230 DATA "WIR SPRECHEN UEBER DICH, NICHT UEBER    MICH!
 2240 DATA WARUM MOECHTEST DU*
 2250 DATA MANCHMAL MOECHTE ICH AUCH*
 2260 DATA WARUM FRAGST DU?
 2270 DATA WELCHE ANTWORT WAERE DIR DENN AM        LIEBSTEN?
 2280 DATA iNTERESSIEREN DICH NOCH MEHR SOLCHE D   DINGE?
 2290 DATA FRAGST DU DAS AUCH NOCH ANDERE LEUTE?
 2300 DATA NAMEN SIND FUER MICH OHNE BEDUTUNG.
 2310 DATA GIBT ES NICHT NOCH EINEN ANDEREN GRUND?
 2320 DATA WAS SAGT DIR DIESER TRAUM?
 2330 DATA WAR ES EIN ALPTRAUM?
 2340 DATA SEI GEGRUESST! NUN ERZAHLE BITTE.
 2350 DATA DU SCHEINST DIR NICHT GANZ SICHER ZU SEIN.
 2360 DATA ODER VIELLEICHT AUCH NICHT?
 2370 DATA WARUM DENN NICHT?
 2380 DATA BIST DU SICHER?
 2390 DATA WARUM INTERESSIERST DU DICH FUER MEIN*
 2400 DATA HAST DU DENN EIN*
 2410 DATA "WIRKLICH, IMMER?"
 2420 DATA WANN?
 2430 DATA DENKST DU DAS WIRKLICH?
 2440 DATA DENKST DU WIRKLICH SO
 2450 DATA DAS IST ABER SCHOEN.
 2460 DATA DAS IST DOCH KLAR.
 2470 DATA HAST DU DENN UEBERHAUPT WAHRE FREUNDE?
 2480 DATA AERGERN DICH DEINE FREUNDE IMMER?
 2490 DATA DU MOECHTEST WOHL SEHR GERNE VIELE      FREUNDE HABEN.
 2510 DATA MEINST DU SPEZIELL MICH?
 2520 DATA "GLAUBST DU NICHT, DASS MASCHINEN DIR    HELFEN KOENNEN?"
 2525 DATA HAST DU ANGST VOR COMPUTERN?
 2530 DATA HAST DU FINANZIELLE PROBLEME?
 2540 DATA MIR SCHEINT DU DENKST OFT AN GELD.
 2550 DATA "ICH DENKE,WIR REDEN UEBER DICH UND      NICHT UBER MICH."
 2560 DATA WAS WILLST DU DENN IMMER VON MIR?
 2570 DATA HM.
 2575 DATA AHA.
 2580 DATA ICH VERSTEHE.
 2590 DATA BITTE ERKLAERE DAS ETWAS GENAUER.
 2610 DATA DAS IST JA INTERESSANT.
 2620 DATA ###
 3000 FOR K=10 TO 32
 3010 PRINT K;S(K);N(K);KE$(K)
 3030 NEXT K