Zeichensatz UTF-8+Z1013()+CTRL()-ohne Umlaute(äöüß)

   10!********************************
   20!*                              *
   30!*      *** ENTERPRISE ***      *
   40!*                              *
   50!* PROGRAM BY ANDREAS SCHROETER *
   60!*            8023 DRESDEN      *
   70!*            MOHNSTR. 36       *
   80!* INSPIRED BY COMMODORE 64     *
   90!********************************
  100 POKE 861,0:POKE 862,255:GOTO 10000  
  190 IF PEEK(36)<>13 THEN 190:ELSE RETURN
  191 WINDOW 19,23,0,39:CLS:WINDOW:PRINT AT(0,0);" "
  192 PRINT AT(18,22);STRING$(17," "):RETURN
  193 WINDOW 0,18,0,21:CLS:WINDOW:PRINT AT(0,0);" ":RETURN
  199 REM RAUMSEKTORKARTE -------------UP
  200 PRINT INK 2;AT(0,0);" RAUMSEKTOR":PRINT INK 4;AT(0,14);Z$(X),"  ",Y$(Y)
  201 FOR I=1 TO 8:PRINT AT(2,I*2+3);Y$(I):PRINT AT(I*2+2,3);Z$(I):NEXT I
  202 DOKE 294,F+512*X+64*Y+9:CALL 293:SB(X,Y)=1
  208 IF C<>7 THEN PRINT INK 6;AT(Z*2+2,S*2+3);"":RETURN:ELSE RETURN
  209 REM OBJEKTZAEHLUNG --------------UP
  210 B1=F+512*X+64*Y+9:DOKE 257,B1:CALL 256
  211 U=PEEK(8):W=PEEK(9):V=PEEK(10)
  213 K$(X,Y)=CHR$(U+48-7*(U>9))+CHR$(W+48-7*(W>9))+CHR$(V+48-7*(V>9))
  214 RETURN
  217 REM COMPUTER-REPORT -------------UP
  218 WINDOW 1,17,23,39:CLS:WINDOW:PRINT AT(0,0);" "
  219 IF AD=1 THEN PRINT INK 5;AT(10,26);"ANGEDOCKT!":P=8:E=5000
  220 PRINT AT(0,23);"",STRING$(15,""),"":FOR I=1 TO 15:PRINT AT(I,23);""
  221 PRINT AT(I,39);"":NEXT I:PRINT AT(2,23);"",STRING$(15,""),""
  222 PRINT AT(16,23);"",STRING$(15,""),""
  223 PRINT INK 2;AT(1,24);"COMPUTER-REPORT":PRINT INK 7;AT(4,25);"STERNENTAG"
  224 PRINT INK 6;AT(4,35);M:PRINT INK 7;AT(6,25);"ENERGIE"
  225 PRINT INK 6;AT(6,32);E:PRINT INK 7;AT(8,25);"TORPEDOS"
  226 PRINT INK 6;AT(8,33);P:PRINT INK 7;AT(12,25);"KLINGONEN"
  227 PRINT INK 2;AT(12,34);K:PRINT INK 7;AT(14,25);"BASISRAUMER"
  228 PRINT INK 6;AT(14,36);R:RETURN
  229 REM KLINGONEN-BESCHUSS ----------UP
  230 GOSUB 191:PRINT INK 2;AT(21,3);"KLINGONEN-BESCHUSS !!!":BEEP
  231 IF E>=300*W THEN 235
  232 PAUSE 40:GOSUB 191:PRINT INK 2;AT(21,3);"SCHUTZSCHILD AUSGEFALLEN !!!"
  233 PRINT INK 4;AT(23,3);"ENTERPRISE GETROFFEN !!!":BEEP:FOR I=1 TO W
  234 A=INT(6*RND(1)+1):R(A)=R(A)+INT(5*RND(1)+4):NEXT I:GOTO 237
  235 PRINT INK 4;AT(23,3);"ENERGIESCHILD AUFGEBAUT:",300*W,"ERG"
  236 E=E-300*W
  237 PAUSE 50:GOSUB 191:RETURN
  239 INK 7:PRINT AT(20,0);"->  NTRIEB          ->  YPERANTRIEB"
  240 PRINT AT(21,0);"->  ORPEDO          ->  LASMAWOLKE":C$=INKEY$
  241 PRINT AT(22,0);"->  MKREISSENSOREN  ->  TERNENKARTE"
  242 PRINT AT(23,0);"->  AUMSEKTORBILD   ->  HECK ENTERPRISE":INK 2
  243 PRINT AT(20,3);"A":PRINT AT(20,23);"H":PRINT AT(21,3);"T":PRINT AT(21,23);"P"
  244 PRINT AT(22,3);"U":PRINT AT(22,23);"S":PRINT AT(23,3);"R":PRINT AT(23,23);"C"
  245 INK 3:PRINT INK 4;AT(18,23);"KOMMANDO-EINGABE":C$=INKEY$:IF C$=""THEN C$=" "
  246 C=INSTR(C$,D$):IF C=0 THEN PAUSE 1:PRINT AT(18,23);STRING$(16," "):PAUSE 1:GOTO 245
  247 GOSUB 191:RETURN
  249 GOSUB 320:IF D=5 THEN GOSUB 191:RETURN:ELSE GOSUB 330:IF G=0 THEN RETURN
  250 A=Z+G*(D<4)-G*(D>6):B=S+G*(D=1 OR D=4 OR D=7)-G*(D=3 OR D=6 OR D=9)
  251 PAUSE 1:PRINT INK 5;AT(2*Z+2,2*S+3);"":Z=Z+SGN(A-Z):S=S+SGN(B-S):E=E-5
  252 IF E<=0 THEN L=3:RETURN
  253 IF Z>0 AND Z<9 AND S>0 AND S<9 THEN 257
  254 IF Z=0 OR Z=9 THEN X=X+(A<1)-(A>8):Z=Z+8*(Z=9)-8*(Z=0):A=A+8*(A>8)-8*(A<1)
  255 IF S=0 OR S=9 THEN Y=Y+(B<1)-(B>8):S=S+8*(S=9)-8*(S=0):B=B+8*(B>8)-8*(B<1)
  256 IF X=0 OR X=9 OR Y=0 OR Y=9 THEN L=1:RETURN:ELSE GOSUB 193:GOSUB 200:GOSUB 210
  257 H=PEEK(F+512*X+64*Y+8*Z+S):IF H<>166 THEN GOSUB 340:RETURN
  258 PRINT INK 6;AT(2*Z+2,2*S+3);"":IF A<>Z OR B<>S THEN 251:ELSE GOSUB 191:RETURN
  259 REM HYPERANTRIEB ----------------UP
  260 GOSUB 320:IF D=5 THEN GOSUB 191:RETURN:ELSE GOSUB 330:IF G=0 THEN RETURN
  261 X=X+G*(D<4)-G*(D>6):Y=Y+G*(D=1 OR D=4 OR D=7)-G*(D=3 OR D=6 OR D=9)
  262 IF X<1 OR X>8 OR Y<1 OR Y>8 THEN L=1:RETURN
  263 E=E-100*G*(1-(D=1 OR D=3 OR D=7 OR D=9)):IF E<0 THEN E=0:L=2:RETURN
  264 GOSUB 191:GOSUB 193:GOSUB 200:GOSUB 210
  265 H=PEEK(F+512*X+64*Y+8*Z+S):IF H<>166 THEN GOSUB 340
  266 RETURN
  269 REM TORPEDO ---------------------UP
  270 GOSUB 191:IF P=0 THEN PRINT INK 2;AT(22,1);"KEIN TORPEDO AN BORD!":BEEP:GOTO 279
  271 GOSUB 320:IF D=5 THEN 271:ELSE P=P-1
  272 A=Z:B=S:FOR I=1 TO 7:A=A+(D<4)-(D>6):B=B+(D=1 OR D=4 OR D=7)-(D=3 OR D=6 OR D=9)
  273 IF A=0 OR A=9 OR B=0 OR B=9 THEN I=8:GOTO 278:ELSE PRINT INK 2;AT(2*A+2,2*B+3);""
  274 PAUSE 2:PRINT INK 5;AT(2*A+2,2*B+3);"":H=PEEK(F+512*X+64*Y+8*A+B)
  275 IF H=166 THEN 278:ELSE POKE F+512*X+64*Y+8*A+B,166:I=9:BEEP
  276 IF H=75 THEN K=K-1:PRINT INK 2;AT(22,2);"KLINGONE VERNICHTET!!!"
  277 IF H=66 THEN R=R-1:PRINT INK 2;AT(22,2);"BASISRAUMER ZERSTOERT - AUSGEZEICHNET!"
  278 NEXT I:IF I=9 THEN PRINT INK 4;AT(22,2);"VERSCHWENDUNG!
  279 PAUSE 50:GOSUB 210:GOSUB 191:RETURN
  280 GOSUB 191:PRINT INK 4;AT(21,2);"ENERGIE-MENGE":WINDOW 23,23,2,17:CLS:C$=INKEY$
  281 INPUT "->";A:IF A<0 OR A>E THEN 281
  282 E=E-A:IF W=0 THEN GOSUB 191:PRINT AT(21,2);"VERSCHWENDUNG!":RETURN
  283 B=0:FOR I=1 TO 8:FOR J=1 TO 8:H=PEEK(F+512*X+64*Y+8*I+J)
  284 IF H=75 THEN B=B+ABS(I-Z)+ABS(J-S)
  285 NEXT J:NEXT I:B=A-100*B:IF B<0 THEN GOSUB 191:PRINT INK 2;AT(21,2);ABS(B)
  286 IF B<0 THEN PRINT AT(21,8);"ERG ZU WENIG !!!":PAUSE 40:GOSUB 191:RETURN
  287 PRINT AT(21,2);"PLASMAWOLKE VERNICHTET KLINGONEN !!!":FOR I=1 TO 8:FOR J=1 TO 8
  288 H=F+512*X+64*Y+8*I+J:IF PEEK(H)=75 THEN POKE H,166:PRINT INK 5;AT(2*I+2,2*J+3);"":K=K-1
  289 NEXT J:NEXT I:GOSUB 191:GOSUB 210:RETURN
  290 FOR I=X-1 TO X+1:FOR J=Y-1 TO Y+1:IF I=0 OR I=9 OR J=0 OR J=9 THEN 293
  291 IF K$(I,J)<>" "THEN 293
  292 O=X:Q=Y:X=I:Y=J:GOSUB 210:X=O:Y=Q
  293 NEXT J:NEXT I:PRINT INK 4;AT(21,1);"UMKREIS-SENSORENBILD"
  294 O=19:FOR I=X-1 TO X+1:Q=25:FOR J=Y-1 TO Y+1:IF I=0 OR I=9 OR J=0 OR J=9 THEN 297
  295 IF I=X AND J=Y THEN PRINT INK 6;AT(O,Q);"*KB":GOTO 297
  296 PRINT AT(O,Q);K$(I,J)
  297 Q=Q+5:NEXT J:O=O+2:NEXT I:AX$=INKEY$
  298 IF INKEY$=""THEN 298:ELSE GOSUB 191:RETURN
  299 WINDOW:CLS:PRINT AT(0,0);" ":PRINT INK 5;AT(0,1);"",STRING$(33,""),""
  300 INK 5:FOR I=1 TO 21:PRINT AT(I,1);"":PRINT AT(I,5);"":PRINT AT(I,39);"":NEXT I
  301 FOR I=2 TO 20 STEP 18:PRINT AT(I,1);"",STRING$(33,""),"":NEXT I
  302 PRINT AT(22,1);"",STRING$(37,""),"":PRINT INK 2;AT(21,2);"STERNEN-KARTE"
  303 PRINT AT(20,5);"":PRINT INK 2;AT(1,2);"*KB":FOR I=1 TO 8
  304 PRINT INK 4;AT(1,4*I+4);Y$(I):PRINT INK 4;AT(2*I+2,3);Z$(I):NEXT I
  305 FOR I=1 TO 8:FOR J=1 TO 8:IF K$(I,J)=" "THEN PRINT INK 5;AT(2*I+2,4*J+3);"XXX":GOTO 308
  306 INK 3:IF X=I AND Y=J THEN INK 2:PRINT AT(I*2+1,J*4+2);"":PRINT AT(I*2+2,J*4+2);"   
  307 PRINT AT(2*I+2,4*J+3);K$(I,J):IF X=I AND Y=J THEN PRINT AT(I*2+3,J*4+2);""
  308 NEXT J:NEXT I:PRINT INK 2;AT(21,31);">ENTER<":GOSUB 190:CLS:INK 3:GOSUB 200:RETURN
  309 INK 2:GOSUB 191:IF C=1 THEN PRINT AT(21,2);"ANTRIEBS-SYSTEME AUSGEFALLEN !!!"
  310 IF C=2 THEN PRINT AT(21,2);"HYPERRAUM-ANTRIEB DEFEKT !!!"
  311 IF C=3 THEN PRINT AT(21,2);"ZIELCOMPUTER ARBEITET NICHT !!!"
  312 IF C=4 THEN PRINT AT(21,2);"PLASMA-ERZEUGER INAKTIV !!!"
  313 IF C=5 THEN PRINT AT(21,2);"UMKREIS-SENSOREN BESCHAEDIGT !!!"
  314 IF C=6 THEN PRINT AT(21,2);"NAVIGATION-COMPUTER UNBRAUCHBAR !!!"
  315 IF C=7 THEN PRINT AT(21,2);"DATENSPEICHER GESPERRT !!!"
  316 IF R(C)=1 THEN C$="":ELSE C$="E"
  317 INK 3:PRINT AT(23,2);"REPARATUR-DAUER",R(C),"STERNENTAG",C$:BEEP:PAUSE 60
  318 GOSUB 191:RETURN
  319 REM RICHTUNGSWAHL ---------------UP
  320 GOSUB 191:PRINT AT(19,29);"Q W E":PRINT INK 2;AT(20,30);""
  321 PRINT AT(21,29);"A   D":PRINT INK 2;AT(21,30);" ":PRINT INK 6;AT(21,31);""
  322 PRINT INK 2;AT(22,30);"":PRINT AT(23,29);"Y X C"
  323 C$=INKEY$:PRINT INK 4;AT(21,3);"RICHTUNGS-EINGABE!"
  324 C$=INKEY$:IF C$=""THEN C$=" "
  325 D=INSTR(C$,E$):IF D=0 THEN 324:ELSE GOSUB 191:RETURN
  329 REM ENTFERNUNGSWAHL -------------UP
  330 GOSUB 191:C$=INKEY$:PRINT INK 4;AT(21,3);"ENTFERNUNGS-EINGABE (0...7)!"
  331 C$=INKEY$:IF C$=""THEN C$=" "
  332 G=ASC(C$)-48:IF G<0 OR G>7 THEN 331:ELSE GOSUB 191:RETURN
  339 REM KOLLISION -------------------UP
  340 GOSUB 191:INK 2:PRINT AT(10,26);"ALARMSTUFE":PRINT AT(21,3);"KOLLISION MIT ":BEEP
  341 IF H=42 THEN PRINT AT(10,37);"1":PRINT AT(21,17);"STERN":A=.3:B=3
  342 IF H=75 THEN PRINT AT(10,37);"2":PRINT AT(21,17);"KLINGONEN":A=.5:B=5:K=K-1
  343 IF H=66 THEN PRINT AT(10,37);"3":PRINT AT(21,17);"BASISRAUMER":A=.7:B=6:R=R-1
  344 POKE F+512*X+64*Y+8*Z+S,166:FOR I=1 TO 7:R(I)=R(I)-(A>RND(1))*INT(B*RND(1)+B)
  345 PRINT AT(2*Z+2,2*S+3);"":BEEP:PAUSE 2:PRINT INK 6;AT(2*Z+2,2*S+3);"":PAUSE 2
  347 NEXT I:GOSUB 210:PRINT AT(21,3);"HINDERNIS VERNICHTET!      ":BEEP:INK 3
  348 PRINT INK 4;AT(23,3);"ENTERPRISE BESCHAEDIGT!!!":PAUSE 50:GOSUB 191:RETURN
  349 REM ANDOCK-KONTROLLE ------------UP
  350 A=0:FOR I=Z-1 TO Z+1:FOR J=S-1 TO S+1:IF I=0 OR I=9 OR J=0 OR J=9 THEN 352 
  351 IF PEEK(F+512*X+64*Y+8*I+J)=66 THEN A=1
  352 NEXT J:NEXT I:IF A=1 THEN E=5000:P=8:FOR I=1 TO 6:R(I)=0:NEXT I:AD=1:ELSE AD=0
  353 IF AD=1 THEN PRINT INK 6;AT(Z*2+2,S*2+3);"":RETURN:ELSE RETURN
  359 REM RAUMSEKTOR-BILD -------------UP
  360 GOSUB 191:PRINT INK 4;AT(20,2);"SEKTOR-KOORDINATEN ?":WINDOW 22,22,2,30
  361 INPUT "--> ";A$:IF LEN(A$)<>2 THEN 361
  362 X1=INSTR(LEFT$(A$,1),X$):Y1=INSTR(RIGHT$(A$,1),S$):IF X1=0 OR Y1=0 THEN 361
  363 IF SB(X1,Y1)=1 THEN 365:ELSE GOSUB 191
  364 PRINT INK 2;AT(21,2);"SEKTOR NICHT ERFORSCHT!":BEEP:PAUSE 30:GOSUB 191:RETURN
  365 X2=X:Y2=Y:X=X1:Y=Y1:GOSUB 200:X=X2:Y=Y2:GOSUB 190:C=0:GOSUB 200:C=7
  366 RETURN
  369 REM CHECK ENTERPRISE ------------UP
  370 CLS:PRINT AT(0,0);" ":PRINT INK 2;AT(1,3);"SYSTEM-CHECK ENTERPRISE"
  371 PRINT INK 4;AT(4,3);"BORDSYSTEM       ZUSTAND    TAGE"
  372 INK 3:PRINT AT(7,0);"ANTRIEB":PRINT AT(9,0);"HYPERANTRIEB"
  373 PRINT AT(11,0);"TORPEDO":PRINT AT(13,0);"PLASMAWOLKE"
  374 PRINT AT(15,0);"UMKREIS-SENSOREN":PRINT AT(17,0);"STERNENKARTE"
  375 PRINT AT(19,0);"RAUMSEKTOR-BILD":FOR I=1 TO 7
  376 IF R(I)=0 THEN PRINT AT(I*2+5,21);"BEREIT":ELSE PRINT INK 2;AT(I*2+5,21);"DEFEKT    ",R(I)
  377 NEXT I:PRINT INK 4;AT(22,32);">ENTER<":GOSUB 190:CLS:GOSUB 200:RETURN
 2000 CLEAR 6144:WINDOW:BORDER 1:PAPER 1:CLS:PRINT AT(0,0);" ":INK 2
 2005 I=RND(-ABS(DEEK(30)/65536))
 2010 DATA "          "   
 2020 DATA "             "    
 2030 DATA "                 "   
 2040 DATA "            "   
 2045 GOSUB 2050:GOTO 2130
 2050 RESTORE 2010:FOR I=15 TO 18:READ A$:PRINT AT(I,5);A$:NEXT I
 2060 PRINT AT(14,27);"":PRINT AT(19,21);"":INK 5   
 2070 PRINT AT(13,3);"",STRING$(32,""),""
 2080 FOR I=14 TO 19:PRINT AT(I,3);"":PRINT AT(I,36);"":NEXT I
 2090 PRINT AT(20,3);"",STRING$(32,""),""
 2100 FOR I=1 TO 100:X=INT(RND(1)*24):Y=INT(RND(1)*40):Z=INT(RND(1)*20+208)
 2105 IF Z>223 THEN A$="*":ELSE A$=CHR$(Z)
 2110 IF X<12 OR X>21 OR Y<2 OR Y>37 THEN PRINT INK 8;AT(X,Y);A$
 2120 NEXT I:INK 3:RETURN
 2130 DIM Y$(8),Z$(8)
 2132 GOSUB 2232
 2135 DATA A,1,B,2,C,3,D,4,E,5,F,6,G,7,H,8
 2145 RESTORE 2135:FOR I=1 TO 8:READ Y$(I),Z$(I):NEXT I:X$="12345678":S$="ABCDEFGH"
 2150 DEF FN T(I)=INT(RND(1)*I+1)
 2160 D$="AHTPUSRC":E$="QWEASDYXC"
 2170 DIM K$(8,8),R(8),SB(8,8):FOR I=1 TO 8:FOR J=1 TO 8:K$(I,J)=" ":NEXT J:NEXT I
 2175 F=DEEK(854):FOR I=F TO F+4096:POKE I,166:IF KK=800 THEN KK=0:GOSUB 2232
 2177 KK=KK+1:NEXT I:F=F-1
 2180 FOR I=1 TO 4
 2190 A=FN T(4096):IF PEEK(F+A)<>166 THEN 2190
 2200 POKE F+A,66:NEXT I
 2210 FOR I=1 TO 30
 2220 A=FN T(4096):IF PEEK(F+A)<>166 THEN 2220
 2230 POKE F+A,75:NEXT I
 2231 GOTO 2240
 2232 OUT 129,1:POKE 666,32:POKE 667,139:POKE 668,3:RESTORE 2238
 2234 FOR II=669 TO 759 STEP 9:POKE II,63:POKE II+3,103:POKE II+6,143
 2236 FOR J=2 TO 8 STEP 3:READ A:POKE II+J,A:NEXT J:NEXT II:DOKE 514,603:OUT 129,183
 2237 OUT 129,50:RETURN
 2238 DATA 32,160,32,32,160,32,32,207,32,134,180,133,135,181,132,32,197,32
 2239 DATA 32,197,32,32,197,32,144,197,145,137,197,200,179,161,176
 2240 FOR I=1 TO 500:IF I/150=INT(I/150)THEN GOSUB 2232
 2250 A=FN T(4096):IF PEEK(F+A)<>166 THEN 2250
 2260 POKE F+A,42:NEXT I
 2265 F=F-584:OUT 129,1
 2270 X=FN T(8):Y=FN T(8):Z=FN T(8):S=FN T(8)
 2275 IF PEEK(F+512*X+64*Y+8*Z+S)<>166 THEN 2270
 2278 WINDOW 14,19,4,35:CLS:INK 3:PRINT AT(14,8);"FUER WIEVIELE STERNENTAGE"
 2280 PRINT AT(16,6);"MOECHTEN SIE VORRAETE LADEN ?":WINDOW 18,18,10,18:A=0
 2282 INPUT "-->";M:IF M>60 AND M<100 AND M=INT(M)THEN 2288
 2284 IF M<>INT(M)THEN PRINT AT(17,5);"  ES GIBT NUR GANZE RATIONEN!  ":BEEP:GOTO
 2285 IF M<=50 AND A=0 THEN PRINT AT(17,5);"   DAMIT KOMMEN SIE KAUM AUS!  ":A=1:GOT
 2286 IF M<=60 THEN PRINT AT(18,8);"WENN SIE UNBEDINGT WOLLEN!":PAUSE 30:GOTO 2288
 2287 IF M>99 THEN PRINT AT(17,5);"SOVIEL TRAEGT ENTERPRISE NICHT!":GOTO 2282
 2288 WINDOW:CLS:PRINT AT(0,0);" ":P=8:E=5000:K=30:R=4
 2290 GOSUB 200:GOSUB 210:GOSUB 218
 2300 IF W<>0 THEN GOSUB 230:GOSUB 218
 2310 GOSUB 239:IF C<>6 AND C<>7 AND C<>3 THEN M=M-1:FOR I=1 TO 8:R(I)=R(I)+(R(I)<>0):NEXT
 2320 L=0:ON-C*(R(C)=0)-9*(R(C)<>0)GOSUB 249,260,270,280,290,299,360,370,309
 2325 IF L<>1 AND V<>0 THEN GOSUB 350:L=0:ELSE AD=0
 2327 IF R(1)>9 AND R(2)>9 AND R(3)>9 AND R(4)>9 AND R(5)>9 AND R(6)>9 AND R(7)>9 THEN L=4
 2330 IF L=0 AND M<>0 AND K<>0 AND E<>0 THEN GOSUB 210:GOSUB 218:GOTO 2300
 2340 GOSUB 218:BEEP:PAUSE 50:CLS:PRINT AT(0,0);" ":GOSUB 2050:PAUSE 40
 2350 WINDOW 14,19,4,35:CLS:PRINT AT(14,4);" ":INK 2:BEEP:IF K<>0 THEN 2380
 2360 PRINT AT(15,5);"SIE HABEN DIE GALAXIS BEFREIT!"
 2370 PRINT AT(18,5);"DIE ERDE IST STOLZ AUF SIE !!!":WINDOW:END
 2380 IF M<>0 THEN 2410
 2390 PRINT AT(15,5);"IHRE VORRAETE SIND ERSCHOEPFT!"
 2400 PRINT AT(18,5);"DIE MISSION IST GESCHEITERT !!":WINDOW:END
 2410 IF L<>1 THEN 2440:ELSE PRINT AT(14,6);"SIE MISERABLER FEIGLING SIND"
 2420 PRINT AT(16,7);"AUS DER GALAXIS GEFLOHEN !"
 2430 PRINT AT(18,7);"DIE ERDE VERACHTET SIE !!!":WINDOW:END
 2440 IF L<>2 THEN 2460:ELSE PRINT AT(15,5);"DIE ENERGIE REICHTE NICHT AUS!"
 2450 PRINT AT(18,6);"IM HYPERRAUM VERSCHOLLEN !!!":WINDOW:END
 2460 IF L<>3 THEN 2480:ELSE PRINT AT(15,5);"SIE DRIFTEN ANTRIEBSLOS IM ALL"
 2470 PRINT AT(18,6);"KEINE RETTUNG MEHR MOEGLICH!":WINDOW:END
 2480 IF L<>4 THEN 2500:ELSE PRINT AT(15,5);"SAEMTLICHE BORDSYSTEME DEFEKT!"
 2490 PRINT AT(18,6);"SIE HABEN KEINE CHANCE MEHR!":WINDOW:END
 2500 PRINT AT(15,5);"ENERGIE RESTLOS VERBRAUCHT !!!"
 2510 PRINT AT(18,5);"AUSFALL LEBENSERHALTUNGSSYSTEME":WINDOW:END
10000 REM BALA51
10010 DATA 197,213,229,245,33,154,2,78,13,113,32,99,54,16,35,78,35,70,0,120
10020 DATA 183,40,96,205,143,2,35,94,53,35,22,237,126,18
10030 DATA 62,112,22,233,18,35,16,240,46,155,78,35,70,203,121,40,10
10040 DATA 62,33,184,40,11,4,4,4,24,3,5,5,5,112,40,52,12,12,12,43,113,24,10
10050 DATA 197,213,229,245,33,17,2,34,2,2,33,155,2,78,35,70,35,205,143,2
10060 DATA 94,35,22,237,26,119,35,126,18,22,233,62,96,18
10070 DATA 35,16,239,62,183,211,129,62,50,211,129,241,225,209,193,251,237,77
10080 DATA 175,129,200,248,35,35,35,13,32,250,201
10090 DATA 33,0,0,175,79,87,95,6,64,126,254,42,32,1,20,254,66,32,1,12
10100 DATA 254,75,32,1,28,35,16,237,33,8,0,114,35,115,35,113,201
10110 DATA 33,0,0,17,165,236,14,8,6,8,126,35,18,203,146,254,42,32,2,62,112
10120 DATA 254,66,32,2,62,48,254,75,32,2,62,16,254,166,32,2,62,64,254,207
10130 DATA 32,2,62,80,18,19,62,64,18,203,210,16,2,24,6,62,160,18,19,24,204
10140 DATA 13,200,229,33,25,0,25,6,8,54,161,203,148,54,64,203,212
10150 DATA 35,35,16,244,17,24,0,25,235,225,24,173
10500 S=0:C=529:RESTORE 10010:FOR I=C TO C+136:READ B:POKE I,B:S=S+B:NEXT I
10510 C=256:FOR I=C TO C+127:READ B:POKE I,B:S=S+B:NEXT I
10520 IF S<>22575 THEN PRINT "LADEFEHLER!";S:END
10530!CLS:PRINT"BITTE MIT >RUN< STARTEN":DELETE10010,10530
10540 GOTO 2000