Zeichensatz UTF-8+Z1013()+CTRL()-ohne Umlaute(äöüß)
1 REM***********************************
2 REM********* (c) COPRIGHT BY *********
3 REM************* DORNACK *************
4 REM*********** HOHENTHURM ************
5 REM************** 4104 ***************
6 REM********** GARTENSTR.14 ***********
7 REM*********** (29.11.86) ************
8 REM***********************************
10!============================
20 V=0:N=.5:Y=0:ZK=2:SK=1:RK=1
30 CLS:R=0
40 PRINT " L E I T E R (VERSION 2) "
50 PRINT:PRINT "DU HAST 60 SEKUNDEN ZEIT, DAS ZIEL (*) ZU ERREICHEN!":PRINT
55 PRINT:PRINT "VERMEIDE BEGEGNUNGEN MIT DER KUGEL!!!!!":PRINT:PRINT
60 PRINT "BEWEGUNGEN: <- = LINKS"
70 PRINT " -> = RECHTS"
80 PRINT " PFEIL HOCH = SPRUNG"
90 PRINT " PFEIL RUNTER = STOP":PRINT:PRINT
110 PRINT "SCHWIERIGKEITSSTUFE (1,2,3)"
120 A$=INKEY$:IF A$<>"1"AND A$<>"2"AND A$<>"3"GOTO 120
130 IF A$="1"THEN N=1:GOTO 160
140 IF A$="2"THEN N=.5:GOTO 160
150 N=.3
160 CLS:FOR I=3 TO 23 STEP 4
170 FOR J=0 TO 39
180 IF RND(1)>0.17-N/10 OR I=23 THEN PRINT AT(I,J);"="
190 NEXT J:IF I>20 THEN 220
200 JJ=INT(38*RND(1))+1:FOR II=I TO I+2
210 PRINT AT(II,JJ);"H":NEXT II
220 NEXT I
230 PRINT AT(1,0);"*":PRINT AT(2,0);"*"
240 POKE 31,0:I=22:J=39:GOSUB 460
250!===================================
260 PRINT AT(0,0);PEEK(31)+1
270 IF PEEK(31)=59 GOTO 580
280 A$=INKEY$
290 POKE-5120+I*40+J,32
300 IF A$=CHR$(8)THEN R=-1
310 IF A$=CHR$(9)THEN R=1
320 IF A$=CHR$(10)THEN R=0
330 J=J+R
340 IF A$<>CHR$(11)THEN 400
350 I=I-1:GOSUB 520:GOSUB 460:GOSUB 760
360 POKE-5120+40*I+J,32:J=J+R:I=I-1:GOSUB 520:GOSUB 460:GOSUB 760
370 POKE-5120+40*I+J,32:J=J+R:GOSUB 520:GOSUB 460:GOSUB 760
380 POKE-5120+40*I+J,32:J=J+R:I=I+1:GOSUB 520:GOSUB 460:GOSUB 760
390 POKE-5120+40*I+J,32:J=J+R:I=I+1
400 GOSUB 460
410 IF PEEK(-5080+40*I+J)=61 GOTO 260
420 IF PEEK(-5080+40*I+J)=72 GOTO 260
430 POKE-5120+40*I+J,32:I=I+4:GOSUB 460
440 GOTO 260
450!===============================
460 IF J>-1 AND J<40 GOTO 490
470 IF J<0 THEN J=0:R=0
480 IF J>39 THEN J=39:R=0
490 POKE-5120+I*40+J,196:GOSUB 1000
500 IF J=0 AND I<3 GOTO 550
510 RETURN
520 IF PEEK(-5120+40*I+J)<>72 THEN RETURN
530 I=I-1:IF PEEK(-5120+40*I+J)=72 THEN 530
540 GOTO 400
550 P=60-PEEK(31):PRINT AT(0,6);"HURRA!!! - ",P," PUNKTE"
560 FOR B=1 TO 50:BEEP:NEXT:CLS
570 V=V+P:GOTO 610
580 PRINT AT(0,6);"DIE ZEIT IST ABGELAUFEN!"
590 FOR B=1 TO 50:BEEP:NEXT
600 CLS
610 PRINT "BIS JETZT HAST DU ";V;" PUNKTE":PRINT
620 Y=Y+1:PRINT "IN ";Y;" SPIELEN ERREICHT":PRINT
630 DS=INT(V/Y+.5)
640 PRINT "DURCHSCHNITT: PRO SPIEL ";DS;" PUNKTE":PRINT
650 IF DS>=40 THEN PRINT "ICH KANN ES NICHT GLAUBEN!!!!!!!!!!!!":GOTO 730
660 IF DS>=30 THEN PRINT "GIB ZU,DASS DU HEIMLICH GEUEBT HAST!!!!":GOTO 730
670 IF DS>=20 THEN PRINT "FUER EINEN ANFAENGER GANZ GUT!":GOTO 730
680 IF DS>=10 THEN PRINT "ICH GLAUBE,DU MUSST MAL DIE"
690 IF DS>=10 THEN PRINT "SCHWIERIGKEITSSTUFE AENDERN!!!!!!":GOTO 730
700 IF DS>0 THEN PRINT "NICHT AUFGEBEN!WAS NICHT IST,"
710 IF DS>0 THEN PRINT "KANN JA NOCH WERDEN!!!!!":GOTO 730
720 IF DS=0 THEN PRINT "G I B ' S A U F ! ! ! ! ! ! ! ! ! ! !"
730 PRINT:PRINT:PRINT "NOCH EIN SPIEL?"
740 A$=INKEY$:IF A$<>"J"AND A$<>"N"GOTO 740
750 IF A$="N" THEN CLS:END:ELSE ZK=2:GOTO 160
760!=========================
770 A$=INKEY$
780 IF A$=CHR$(8)THEN R=-1
790 IF A$=CHR$(9) THEN R=1
800 IF A$=CHR$(10)THEN R=0
810 RETURN
1000!==================
1010 KAS=SK:KZZ=ZK:SK=SK+RK:IF SK>38 OR SK<1 THEN RK=-RK
1020 POKE-5120+40*ZK+SK,207:POKE-5120+40*KZZ+KAS,32
1030 IF PEEK(-5120+40*(ZK+1)+SK)=32 THEN POKE-5120+40*ZK+SK,32:GOTO 1400
1040 IF ZK=I AND(SK=J OR KAS=J)THEN 2000
1050 IF ZK<20 THEN RETURN
1060 IF SK>0 AND SK<39 THEN RETURN
1070 POKE-5120+ZK*40+SK,32:ZK=2:SK=INT(RND(1)*37)+1:RETURN
1400 IF SK>38 THEN RK=-1:GOTO 1500
1410 IF SK<1 THEN RK=+1:GOTO 1500
1450 IF RND(1)>.5 THEN RK=-RK
1500 ZK=ZK+4:POKE-5120+40*ZK+SK,207:IF ZK=I AND SK=J THEN 2000
1520 RETURN
2000 PRINT AT(0,1);"DU BIST IN DIE KUGEL GELAUFEN!!!":FOR I=1 TO 50:BEEP:NEXT
2010 P=0:CLS:GOTO 570