Zeichensatz UTF-8+Z1013()+CTRL()-ohne Umlaute(äöüß)

   10 REM JAGD
   20 WINDOW:CLS
   30 PRINT AT(2,10);"ENTENJAGD"
   40 PRINT AT(10,6);"Die Schusstaste ist die":PRINT AT(12,10);"> U < - Taste !"
   50 PRINT AT(0,0);" ":PAUSE 20
   60 CLS:LET P=0:LET D=1:PRINT AT(0,0);" "
   70 REM TEXT u.JAEGER DARSTELLEN
   80 PRINT AT(28,15);D:PRINT AT(28,18);". DURCHLAUF"
   90 PRINT AT(30,17);P:PRINT AT(30,20);" TREFFER"             
  100 PRINT AT(28,2);CHR$(204)
  110 PRINT AT(29,1);CHR$(153)+CHR$(255)+CHR$(155)
  120 PRINT AT(30,2);CHR$(255)
  130 PRINT AT(31,1);CHR$(192):PRINT AT(31,3);CHR$(159)
  140 REM AKTION
  150 LET Y=INT(RND(1)*22):LET Z=27:LET F=0
  160 PRINT AT(29,3);CHR$(155):PRINT AT(28,3);" "
  170 PRINT AT(Y,30);CHR$(156)+CHR$(146):PRINT AT(Y+1,30);CHR$(238)+CHR$(238)
  180 FOR I=30 TO 1 STEP -1
  190 PRINT AT(Y,I+1);" ":PRINT AT(Y+1,I+1);" "                    
  200 PRINT AT(Y,I-1);CHR$(156)+CHR$(146)
  210 PRINT AT(Y+1,I-1);CHR$(238)+CHR$(238)
  220 REM ABFRAGE DER SCHUSS-TASTE
  230 IF Z=27 AND INKEY$=CHR$(85) THEN LET F=1:GOTO 240:ELSE GOTO 260
  240 PRINT AT(29,3);" "
  250 PRINT AT(28,3);CHR$(152):PRINT AT(27,3);CHR$(209)
  260 IF F<>1 THEN FOR ZV=1 TO 15:NEXT ZV:GOTO 310:REM ZEITVERZOEGERUNG
  270 PRINT AT(Z,3);" ":PRINT AT(Z-1,3);CHR$(209)   
  280 IF Z-1=Y+1 AND (I-1=3 OR I=3) THEN GOSUB 500:GOTO 330   
  290 IF Z=1 THEN LET F=0:PRINT AT (Z-1,3);" ":GOTO 310
  300 LET Z=Z-1
  310 NEXT I
  320 PRINT AT(Y,0);"  ":PRINT AT(Y+1,0);"  ":PRINT AT(Z,3);" " 
  330 IF D=10 THEN POKE 113,5:POKE 112,5:INPUT " NOCH MAL   J/N ?";A$:GOTO 360
  340 LET D=D+1
  350 PRINT AT(28,17-LEN(STR$(D)));D:GOTO 150
  360 IF A$="J" THEN GOTO 60
  370 CLS:END
  500 REM UP TREFFER
  510 LET P=P+1
  520 PRINT AT(30,19-LEN(STR$(P)));P
  530 PRINT AT(Y,I-1);"**":PRINT AT(Y+1,I-1);"**"
  540 PAUSE 20
  550 PRINT AT(Y,I-1);"  ":PRINT AT(Y+1,I-1);"  "
  560 RETURN